Adding numbers with a length of 50 digits.

Question

Hi folks,
Could any one please tell me how to add two numbers with 50 digits each.
What should be the datatype for each column, in a table, to hold the above said precision.
However, I know that NUMBER couldn't hold this b'coz its precision is upto 32 digits. Am I right?
What could be the solution?
Your favour would, indeed, be remembered and acknowledged, as well.
Cheers, PCZ.

Answer 1

you could write your own function if you need arbitrary precision
I tried (not very fast) :
SCOTT@LSC01> create or replace function bigadd(n1 varchar2,n2 varchar2)
  2      return varchar2
  3  is
  4      result varchar2(4000);
  5      s number:=0;
  6      i1 number;
  7      i2 number;
  8  begin
  9      if (n1 is null or n2 is null) then
10          return null;
11      end if;
12      if (translate(n1||n2,'x0123456789','x') is not null) then
13          raise_application_error(-20001,'parameter is not an integer');
14      end if;
15      for i in 0..greatest(length(n1),length(n2))-1 loop
16          if (i>=length(n1)) then
17              i1:=0;
18          else
19              i1:=substr(n1,length(n1)-i,1);
20          end if;
21          if (i>=length(n2)) then
22              i2:=0;
23          else
24              i2:=substr(n2,length(n2)-i,1);
25          end if;
26          s:=i1+i2+s;
27          result:=mod(s,10)||result;
28          s:=trunc(s/10);
29      end loop;
30      return nullif(s,0)||result;
31  end;
32  /
Function created.
SCOTT@LSC01> select bigadd('10000000000000000000000000000000000000000000000000','1') from dual;
BIGADD('10000000000000000000000000000000000000000000000000','1')
10000000000000000000000000000000000000000000000001Message was edited by:
Laurent Schneider
discovered one bug already... fixed
Message was edited by:
Laurent Schneider