Bdc in table control

Question

hi friends,
can any body plz send me one example in table contols in bdc.STEP BY STEP.
thanks & regards
ram

Answer 1

hi,
Here is the code.
report zmm_update_contracts_cpy no standard page heading
                                line-count 45
                                line-size  115
                                message-id zmm.
*                  Types Declarations                                 
types: begin of ty_ekko,
        ebeln type ekko-ebeln,
        bukrs type ekko-bukrs,
        kdate type ekko-kdate,
        kdatb type ekko-kdatb,
       end of   ty_ekko,
*-- Structure for success and failed records
       begin of ty_status,
        bukrs type ekko-bukrs,
        ebeln type ekko-ebeln,
        kdate type ekko-kdate,
        kdatb type ekko-kdatb,
       end   of ty_status.
*                  Internal Table Declarations                         *
data : it_ekko    type standard table of ty_ekko    with header line,
       it_ekpo    type standard table of ekpo       with header line,
       it_success type standard table of ty_status  with header line,
       it_fail    type standard table of ty_status  with header line,
       bdcdata    type standard table of bdcdata    with header line,
       msgtab     type standard table of bdcmsgcoll with header line.
*                  Structure  Declarations                             *
*-- Structure for Parameter string for runtime of CALL TRANSACTION
data : x_ctu_params type ctu_params.
*                  Data Declarations                                   *
data : v_bukrs      type ekko-bukrs, "Company code
       v_ebeln      type ekko-ebeln, "Contract no
       v_ekorg      type ekko-ekorg, "Purchasing Org
       v_bsart      type ekko-bsart, "Document Type
       v_kdatb      type ekko-kdatb,
       v_counter(2) type n ,"value '01',
       v_first(5)   type n,
       v_field      type string.
*                        Selection Screen                              *
*-- Selection screen Details
selection-screen begin of block b1 with frame title text-001.
select-options :
   s_bukrs for v_bukrs obligatory default '0111', "Company code
   s_ebeln for v_ebeln obligatory,                "Contract no
   s_ekorg for v_ekorg,
   s_bsart for v_bsart,
   s_dats  for v_kdatb.
selection-screen end of block b1.
*               Start-of-Selection                                     *
start-of-selection.
*-- Get data from DB table ekko based on selection-screen
  perform fetch_data.
*-- for each record found process BDC
  perform process_bdc.
  perform init_page_head.
*               End-of-Selection                                     *
end-of-selection.
*-- Display report
  perform display_report.
*                      Top-of-page
top-of-page.
*--  Subroutine to print header on top of the page
  perform print_header.
  skip.
  uline.
*&      Form  fetch_data
*       text
form fetch_data.
  select ebeln bukrs kdate kdatb
    from ekko
    into table it_ekko
    where ebeln in s_ebeln
      and bukrs in s_bukrs
      and bstyp = 'K'
      and bsart in s_bsart
      and ekorg in s_ekorg
      and kdatb in s_dats
      and kdate in s_dats.
  if sy-subrc <> 0.
    exit.
  else.
    select * from ekpo
      into table it_ekpo
      for all entries in it_ekko
      where ebeln = it_ekko-ebeln
        and bukrs = it_ekko-bukrs.
*        and loekz = ''.
  endif.
endform.                    " fetch_data
*&      Form  process_bdc
*       text
form process_bdc.
  sort it_ekko by ebeln.
  sort it_ekpo by ebeln ebelp.
  loop at it_ekko.
    clear   : bdcdata.
*              v_counter.
    refresh : bdcdata.
    perform fill_bdctable.
  endloop.
endform.                    " process_bdc
*        Start new screen                                              *
form bdc_dynpro using program dynpro.
  clear bdcdata.
  bdcdata-program  = program.
  bdcdata-dynpro   = dynpro.
  bdcdata-dynbegin = 'X'.
  append bdcdata.
endform.
*        Insert field                                                  *
form bdc_field using fnam fval.
  if fval <> ' '.
    clear bdcdata.
    bdcdata-fnam = fnam.
    bdcdata-fval = fval.
    append bdcdata.
  endif.
endform.
*&      Form  fill_bdctable
*       text
form fill_bdctable.
* To have default screen size, mode and update
  x_ctu_params-defsize = 'X'.
  x_ctu_params-dismode = 'E'.
  x_ctu_params-updmode = 'S'.
  v_first = 1.
  shift v_first left DELETING leading '0'.
  perform bdc_dynpro      using 'SAPMM06E' '0205'.
  perform bdc_field       using 'BDC_CURSOR'
                                'RM06E-EVRTN'.
  perform bdc_field       using 'BDC_OKCODE'
                                '/00'.
  perform bdc_field       using 'RM06E-EVRTN'
                                it_ekko-ebeln.
*reading item data table based on header data table
  loop at it_ekpo where ebeln = it_ekko-ebeln.
    clear v_field.
    v_counter = v_counter + 1.
*Page Down
    if v_counter = '15' .
      v_counter = '01'.
      concatenate 'RM06E-EVRTP('
                  v_counter
                  into v_field.
      perform bdc_dynpro      using 'SAPMM06E' '0220'.
      perform bdc_field       using 'BDC_CURSOR'
                                     v_field.
      perform bdc_field       using 'BDC_OKCODE'
                                    '=P+'.
      perform bdc_field       using 'RM06E-EBELP'
                                     v_first.
      v_first = v_first + 14.
*Compare first entry in table control with line item
*As there are some missing line items in Purchasing Document Item table
      IF V_FIRST <> IT_EKPO-EBELP.
        V_FIRST = IT_EKPO-EBELP.
      ENDIF.
    endif.
* Check for deletion indicator
    if it_ekpo-loekz is initial.
      concatenate 'RM06E-EVRTP('
                  v_counter
                  into v_field.
      perform bdc_dynpro      using 'SAPMM06E' '0220'.
      perform bdc_field       using 'BDC_CURSOR'
                                     v_field.
      perform bdc_field       using 'BDC_OKCODE'
                                    '=DETZ'.
      perform bdc_field       using 'RM06E-EBELP'
                                     v_first."it_ekpo-ebelp.
      clear v_field.
      concatenate 'RM06E-TCSELFLAG('
                  v_counter
                  into v_field.
      perform bdc_field       using v_field
                                    'X'.
      perform bdc_dynpro      using 'SAPMM06E' '0212'.
      perform bdc_field       using 'BDC_CURSOR'
                                    'EKPO-BRGEW'.
      perform bdc_field       using 'BDC_OKCODE'
                                    '=BACK'.
      perform bdc_field       using 'EKPO-NTGEW'    "netweight
                                    '0'.
      perform bdc_field       using 'EKPO-GEWEI'    "unit
                                    'LB'.
      perform bdc_field       using 'EKPO-BRGEW'    "gross weight
                                    '0'.
    endif.
  endloop.
  perform bdc_dynpro      using 'SAPMM06E' '0220'.
  concatenate 'RM06E-EVRTP('
              v_field
              into v_field.
  perform bdc_field       using 'BDC_CURSOR'
                                v_field.
  perform bdc_field       using 'BDC_OKCODE'
                                '=BU'.
  perform bdc_dynpro      using 'SAPLSPO1' '0300'.
  perform bdc_field       using 'BDC_OKCODE'
                                '=YES'.
*  PERFORM BDC_FIELD       USING 'RM06E-EBELP'
*                                '10'.
  call transaction 'ME32K' using bdcdata
                      options from x_ctu_params
                        messages into msgtab.
  clear v_counter.
  if sy-subrc = 0.
*-- populate the success records
    clear it_success.
    it_success-ebeln = it_ekko-ebeln.
    it_success-bukrs = it_ekko-bukrs.
    it_success-kdate = it_ekko-kdate.
    it_success-kdatb = it_ekko-kdatb.
    append it_success.
  else.
*-- populate the error records
    clear it_fail.
    it_fail-ebeln = it_ekko-ebeln.
    it_fail-bukrs = it_ekko-bukrs.
    it_fail-kdate = it_ekko-kdate.
    it_fail-kdatb = it_ekko-kdatb.
    append it_fail.
  endif.
endform.                    " fill_bdctable
*&      Form  display_report
*       text
form display_report.
  data : lv_success type i,
         lv_failure type i,
         lv_lines   type i.
  clear : lv_success,
          lv_failure,
          lv_lines.
  describe table it_success lines lv_success.
  describe table it_fail    lines lv_failure.
  lv_lines = lv_failure + lv_success.
  write : / 'Total no of records uploaded :'(002) .
  write : lv_lines.
  write : / 'Total no of successes        :'(003).
  write : lv_success.
  write : / 'Total no of errors           :'(004).
  write : lv_failure.
  if not it_success[] is initial.
    sort it_success by bukrs.
    skip 2.
    write : / 'Success Records'(005).
    loop at it_success.
      at new bukrs.
        write : /    'Company Code '(006) , it_success-bukrs.
        write : /1   'Contract'(007),
                 13  'Validity Dates'(008).
      endat.
      write : /1  it_success-ebeln,
               13 it_success-kdatb,
               26 it_success-kdate.
    endloop.
  endif.
  if not it_fail[] is initial.
    sort it_fail by bukrs.
    skip 2.
    write : / 'Error Records'(009).
    loop at it_fail.
      at new bukrs.
        write : /    'Company Code '(006) , it_fail-bukrs.
        write : /1   'Contract'(007),
                 13  'Validity Dates'(008).
      endat.
      write : /1  it_fail-ebeln,
               13 it_fail-kdatb,
               26 it_fail-kdate.
    endloop.
  endif.
endform.                    " display_report
Regards,
Richa