Calling a member procedure??

Question

Ive got to write a member procedure for actioned_child but ive been banging my head against the wall when it comes to calling the procedure i was wondering how i would go about calling it.
CREATE OR REPLACE TYPE BODY child_objtyp AS
MEMBER PROCEDURE actioned_child (new_actioned in VARCHAR2, date_actioned in DATE) IS
BEGIN
self.actioned := new_actioned;
self.actioned_date := date_actioned;
IF actioned = 'N' THEN
SELF.actioned := 'Y';
SELF.actioned_date := SYSDATE;
COMMIT;
END IF;
END actioned_child;
END;
SHOW ERRORS;

Answer 1

Your code does not make sense. There is a default constructor that you are ignoring. This will typically be called to instantiate an object of the class you have defined. E.g.
declare
  --// define object variable
  obj child_objtyp;
begin
  --// construct the object and set the properties
  obj := new child_objtyp( 'Y', sysdate );
end;The question is now how does your member procedure actioned_child() impacts the constructed object. Simply overwriting the property values that it was constructed with, does not make much sense.
Instead the following approach makes more sense. And note no ugly and silly write-reserved-words-in-uppercase standard - instead apply the de facto standards used in all programming languages from Java to .Net:
SQL> create or replace type TChildObject is object(
  2          actioned        varchar2(1),
  3          created         date,
  4          action_date     date,
  5 
  6          constructor function TChildObject( createDate date default sysdate )
  7          return self as result,
  8 
  9          member procedure Action,
10          member procedure UnAction,
11          member function Display return varchar2
12  ) final;
13  /
Type created.
SQL>
SQL> create or replace type body TChildObject is
  2 
  3          constructor function TChildObject( createDate date default sysdate )
  4          return self as result is
  5          begin
  6                  self.created := createDate;
  7                  self.actioned := 'N';
  8                  return;
  9          end;
10 
11          member procedure Action is
12          begin
13                  self.actioned := 'Y';
14                  self.action_date := sysdate;
15          end;
16 
17          member procedure UnAction is
18          begin
19                  self.actioned := 'N';
20                  self.action_date := null;
21          end;
22 
23          member function Display return varchar2 is
24          begin
25                  return(
26                          'Created='||to_char(self.created,'hh24:mi:ss' ) ||
27                          ' Actioned='||self.Actioned||
28                          ' ActionedOn='||to_char(self.action_date,'hh24:mi:ss' )
29                  );
30          end;
31  end;
32  /
Type body created.
SQL>
SQL> declare
  2          obj     TChildObject;
  3  begin
  4          --// construct object
  5          obj := new TChildObject();
  6          DBMS_OUTPUT.put_line( obj.Display );
  7 
  8          --// action object
  9          obj.Action();
10          DBMS_OUTPUT.put_line( obj.Display );
11 
12          --/// unaction object
13          obj.UnAction();
14          DBMS_OUTPUT.put_line( obj.Display );
15 
16          --// no destructor can be called as
17          --// PL/SQL handles garbage collection for
18          --// out of scope objects automatically
19  end;
20  /
Created=18:15:33 Actioned=N ActionedOn=
Created=18:15:33 Actioned=Y ActionedOn=18:15:33
Created=18:15:33 Actioned=N ActionedOn=
PL/SQL procedure successfully completed.
SQL>