Calling Report from Menu (Oracle Forms 10g)

Question

We have the applications in Forms6i & Reports 6i (Client Server) and migrating to Forms 10g and Reports 10g. We have the menu, from that menu we are calling all the forms and Reports. For especially Reports earlier we user RUN_PRODUCT but now 10g it is not working. How can call the report using RUN_REPORT_OBJECT
Important things we have some dynamic parameters (input) to the each report. That means when i called the report from the menu i need to get first parameter form to take the parameters and then can be run the report.

Answer 1

Here is the code to call report from menu in 10g
DECLARE
pl_id ParamList;
repid REPORT_OBJECT;
v_rep varchar2(100);
v_server VARCHAR2(100);
rep_status varchar2(100);
v_host VARCHAR2(100);
BEGIN
     select rep_server into v_server from reports_data;
     select machine into v_host from reports_data;
pl_id := Get_Parameter_List('tmpdata');
     IF NOT Id_Null(pl_id) THEN
     Destroy_Parameter_List( pl_id );
     END IF;
     pl_id := Create_Parameter_List('tmpdata');           
Add_Parameter(pl_id,'P_C_CODE',TEXT_PARAMETER,:GLOBAL.COMPANY);
Add_Parameter(pl_id,'P_B_CODE',TEXT_PARAMETER,:GLOBAL.BRANCH);
     repid := find_report_object('REPORTOBJ');
     SET_REPORT_OBJECT_PROPERTY(repid,REPORT_FILENAME,getpath||'E_VOUCHER_ENTRY.RDF');
          SET_REPORT_OBJECT_PROPERTY(repid,REPORT_COMM_MODE,SYNCHRONOUS);
          SET_REPORT_OBJECT_PROPERTY(repid,REPORT_DESFORMAT,'htmlcss');
          SET_REPORT_OBJECT_PROPERTY(repid,REPORT_SERVER,v_server);
          v_rep := RUN_REPORT_OBJECT(repid, pl_id);
          rep_status := REPORT_OBJECT_STATUS(v_rep);
          WHILE rep_status in ('RUNNING','OPENING_REPORT','ENQUEUED')
               LOOP
                    rep_status := report_object_status(v_rep);
                         message('Running');
               END LOOP;
          IF rep_status = 'FINISHED' or rep_status is NULL THEN
               --Display report in the browser
               WEB.SHOW_DOCUMENT('http://'||v_host||'/reports/rwservlet/getjobid'||substr(v_rep,instr(v_rep,'_',-1)+1)||'?'||'server='||v_server,'_blank');
          ELSE
               null;
     END IF;
END;