Changing font in Pages table

Question

I can change the font and size in the body of a Pages '09 document with the following script:
tell application "Pages"
tell document 1 to tell body text
set font name to "Times"
set font size to 14
end tell
end tell
But, it won't change the font inside a table, which is what I want.
I have tried this script:
tell application "Pages"
tell document 1 to tell table text
set font name to "Times"
set font size to 14
end tell
end tell
Which produces this: -- error "Pages got an error: Can’t make text into type integer." number -1700 from text to integer
Any help appreciated.

Answer 1

After many trials and errors, I didn't find any better way to open the "Blank" template than to open its file directly (/Applications/iWork '09/Numbers.app/Contents/Resources/Templates/Blank.nmbtemplate).
So here's an improved version of the script that should now work properly for anybody (at least I hope so):
--BEGINNING OF SCRIPT:
tell application "Pages"
launch
make new document at front
tell body text of front document
set alignment to center
add table
set shadow of table 1 to true
select table 1
end tell
activate
tell application "System Events" to keystroke "c" using command down -- copy to the clipboard with ⌘C
end tell
tell application "Numbers"
--Open the "Blank" template:
open POSIX file "/Applications/iWork '09/Numbers.app/Contents/Resources/Templates/Blank.nmbtemplate"
activate
--Paste table 1 into a new Numbers document:
tell application "System Events"
set theSheets to outline 1 of scroll area 1 of splitter group 1 of splitter group 1 of window 1 of process "Numbers"
select row 1 of theSheets -- sheet 1
select row 2 of theSheets -- table 1 of sheet 1
key code 51 -- delete key
keystroke "v" using command down -- paste the contents of the clipboard with ⌘V
select row 1 of theSheets
end tell
--Change the contents and format of the second row of the table:
tell table 1 of sheet 1 of front document
set value of cell 4 to "Isn't"
set value of cell 5 to "that"
set value of cell 6 to "nice?"
set font name of row 2 to "Times"
set font size of row 2 to "24"
set text color of row 2 to {65535, 0, 0} -- red
set alignment of row 2 to center
end tell
--Copy the modified table to the clipboard:
tell application "System Events"
select row 2 of theSheets -- table 1 of sheet 1
keystroke "c" using command down -- copy to the clipboard with ⌘C
end tell
quit without saving -- optional
end tell
tell application "Pages"
activate
tell application "System Events" to keystroke "v" using command down -- paste with ⌘V to change table 1
end tell
--END OF SCRIPT