Creating progress bar in oracle forms 6i

Question

Hii
I have a push-button (pb_submit)
when when_button_pressed trigger fired...I have a database main procedure to be called.
inside that procedure i am calling 25 procedures.
and all 25 Procedures will be executed sequencially.
I want to use a Progress bar...
so that user will get to know hw much % completed
if main procedure(total 25 procedures inside) is completed successfully then progress bar should show 100%
like wise if 1 procedure completed then 4 %
             if 2 procedure completed then 8 %
total 25 procedure completed then 100%
how to implement this logic.
and if in between 1 procedure failed then progress bar should stop at that incident.
and it should start from dat instant only if again that failed procedure run successfully.
should i post my codes here.ok...here is the codes written in the button(when_button_pressed trigger)
DECLARE
  l_Last_Record      NUMBER  := 0  ;
  l_Prg_Process_Id    NUMBER     ;
  l_Prg_Process_Id_1  NUMBER     ;
  l_Prg_Id       VARCHAR2(15)  ;
  l_Alert_Result    VARCHAR2(1)   ;
  l_Validation_Msg   VARCHAR2(500) ;
  l_Path        VARCHAR2(240) ;
  File_Name       VARCHAR2(250) ;
  l_file_exists     BOOLEAN       ;
  l_file_len        NUMBER     ;
  l_blocksize       BINARY_INTEGER;
  o_Status       VARCHAR2(1)  ;
  o_User_Selection_Ca1 VARCHAR2(1)  ;
  o_User_Selection_Ca2 VARCHAR2(1)  ;
  o_User_Selection_Ca3 VARCHAR2(1)  ;
  CURSOR C_Validation IS
  SELECT Cpv_Validation_Type     ,
         Cpv_Validation_Input    ,
         Cpv_Validation_Action  ,
         Cpv_Validation_Active_Flag
  FROM   Config_Process_Validation
  WHERE  Cpv_Program_Id = l_Prg_Id
  AND   Nvl(Cpv_Validation_Active_Flag, 'N') = 'Y'
  ORDER BY Cpv_Validation_Sequence;
BEGIN
SELECT RV_HIGH_VALUE
INTO   l_Path
FROM   CG_REF_CODES
WHERE  Rv_Domain    = 'DERV_DATA_FILES'
AND   Rv_Low_Value = 'DRV_FILES';
Go_Block('Process');
  Last_Record;
  l_Last_Record := :System.Cursor_Record; 
  First_Record;
  FOR i IN 1 .. l_Last_Record
  LOOP
  Go_Record(i);
  l_Prg_Id := :Prog_Id;
  IF NVL(:Process.Cb_Select,'N') = 'Y' THEN
   :Query.Current_Status := 'Current Process: ' || :Process.Prog_Desc;
   Synchronize;
   --Validate if program is already in running mode or already completed
   SELECT NVL(MAX(DECODE(Prg_Status, 'R', 999999999, 'C', Prg_Process_Id)), 0)
   INTO   l_Prg_Process_Id
   FROM   Program_Status,
       Parameter_Master
   WHERE  Prg_Dt      = Pam_Curr_Dt
   AND    Prg_Cmp_Id  = l_Prg_Id
   AND    Prg_Exm_Id  IN ('ALL', :Query.Exchange)
   AND    Prg_Status  IN ('R', 'C');
   IF l_Prg_Process_Id = 999999999 THEN
     P_Show_Alert(l_Prg_Id||' Process is already running.','A',l_Alert_Result);
    --RAISE Form_Trigger_Failure;
   ELSIF l_Prg_Process_Id > 0 AND :Execution_Flag <> 'M' THEN
    P_Show_Alert(l_Prg_Id||' Process already run. It can not run twice. ','A',l_Alert_Result);
    RAISE Form_Trigger_Failure;
   END IF;
   --Validate mandataory process, process specific validation and message
   FOR i IN C_Validation
   LOOP
    IF i.Cpv_Validation_Type = 'MANDATORY' AND i.Cpv_Validation_Active_Flag = 'Y' THEN
       SELECT Count(1)
       INTO   l_Prg_Process_Id_1
       FROM   Program_Status,
           Parameter_Master
     WHERE  Prg_Dt      = Pam_Curr_Dt
     AND    Prg_Cmp_Id  = i.Cpv_Validation_Input
     AND    Prg_Exm_Id  IN ('ALL', :Query.Exchange)
     AND    Prg_Status  = 'C'
     AND    Prg_Process_Id IN (SELECT MAX(Prg_Process_Id)
                  FROM   Program_Status,
                      Parameter_Master
                  WHERE  Prg_Dt      = Pam_Curr_Dt
                  AND    Prg_Cmp_Id  = i.Cpv_Validation_Input
                  AND    Prg_Exm_Id  IN ('ALL',:Query.Exchange)
                  AND    Prg_Status  = 'C');
     IF l_Prg_Process_Id_1 = 0 THEN
      P_Show_Alert(i.Cpv_Validation_Input||' Mandatory Process NOT completed successfully.','A',l_Alert_Result);
      RAISE Form_Trigger_Failure;
     END IF;
    ELSIF i.Cpv_Validation_Type = 'MESSAGE' THEN
     P_Show_Alert(i.Cpv_Validation_Input, i.Cpv_Validation_Action, l_Alert_Result);
     IF l_Alert_Result = 'N' THEN
      RAISE Form_Trigger_Failure;
     END IF;
    ELSE   
     --- OTHER PROCESS SPECIFIC VALIDATION
     l_Validation_Msg := Null;
     Pkg_Process_Automation.P_Pre_Process_Validation(l_Prg_Id,
                             :Query.Exchange,
                             :Query.Segment,
                             i.Cpv_Validation_Type,
                             l_Validation_Msg);
     IF l_Validation_Msg IS NOT NULL THEN
      P_Show_Alert(l_Validation_Msg,i.Cpv_Validation_Action,l_Alert_Result);
      IF l_Alert_Result = 'N' THEN
       RAISE Form_Trigger_Failure;
      END IF;
     END IF;  
    END IF; 
   END LOOP;
   --Validating whether file exists or not
   IF :Process.File_Input_Format IS NOT NULL THEN
    Pkg_Process_Automation.P_Gen_File_Name(:Process.File_Input_Format,
                        :Query.Exchange,
                        :Query.Segment,
                        File_Name);
    Utl_File.FGetAttr(
     location    => l_Path,
     filename    => File_Name,
     fexists     => l_file_exists,
     file_length => l_file_len,
     block_size  => l_blocksize);
    IF NOT l_File_Exists THEN
     --MESSAGE('The file does not exist.');
     P_Show_Alert('The file does not exist.','A',l_Alert_Result);
     RAISE Form_Trigger_Failure;
    END IF;
   END IF;
   Set_Application_Property(Cursor_Style, 'BUSY');
   SET_ITEM_INSTANCE_PROPERTY('Process.Status', CURRENT_RECORD, VISUAL_ATTRIBUTE, 'VA_YELLOW');
   :Process.Status := 'R';
   Synchronize;
   IF l_Prg_Id = 'DTMBCORP' THEN
    P_Show_Alert('Do you want to do Final Settlement Corporate Action ?(Y/N)','I',l_Alert_Result);
    o_User_Selection_Ca1 := l_Alert_Result;
    P_Show_Alert('Enable Round-To-Tick ? (Y/N)','I',l_Alert_Result);
    o_User_Selection_Ca2 := l_Alert_Result;
    --P_Show_Alert('Do you want to Rollback ? (Y/N)','I',l_Alert_Result);
    --o_User_Selection_Ca3 := l_Alert_Result;
   END IF;
   ----   Calling of Main Procedure
   Pkg_Process_Automation.P_Run_Process(l_Prg_Id,
                      :Query.Exchange,
                      :Query.Segment,
                      :Query.Entity_Id,
                      File_Name,
                      o_User_Selection_Ca1,
                      o_User_Selection_Ca2,
                      o_User_Selection_Ca3,
                      o_Status);
   IF l_Prg_Id = 'DTMBCORP' THEN
    P_Show_Alert('Do you want to Rollback (Y/N)','I',l_Alert_Result);
    o_User_Selection_Ca3 := l_Alert_Result;
    Pkg_Process_Automation.P_Run_Process(l_Prg_Id,
                        :Query.Exchange,
                        :Query.Segment,
                        :Query.Entity_Id,
                        File_Name,
                        o_User_Selection_Ca1,
                        o_User_Selection_Ca2,
                        o_User_Selection_Ca3,
                        o_Status);
   END IF;                 
   Set_Application_Property(Cursor_Style, 'DEFAULT');                  
   Message(o_Status);
   Message(o_Status);
   IF o_Status = 'Y' THEN
    :Process.Status := 'C';
    SET_ITEM_INSTANCE_PROPERTY('Process.Status', CURRENT_RECORD, VISUAL_ATTRIBUTE, 'VA_GREEN');
   ELSE
    :Process.Status := 'E';
    SET_ITEM_INSTANCE_PROPERTY('Process.Status', CURRENT_RECORD, VISUAL_ATTRIBUTE, 'VA_RED');
   END IF;
   SELECT Prg_Log_File
   INTO   :Process.Log_File
   FROM   Program_Status ,
          Parameter_Master
     WHERE  Prg_cmp_id = l_Prg_Id
     AND    Prg_dt     = Pam_Curr_Dt
      AND   (Prg_Cmp_Id,Prg_Strt_Time)  IN (SELECT   Prg_Cmp_Id,max(Prg_Strt_Time) 
                               FROM   Program_Status b,
                                                    Parameter_Master
                                             WHERE  Prg_Cmp_Id =  l_Prg_Id
                               AND    Prg_Dt     =  Pam_Curr_Dt
                                              GROUP BY Prg_Cmp_Id);
   Synchronize;
   Set_Application_Property(Cursor_Style, 'DEFAULT');   
  END IF;
END LOOP;
:Query.Current_Status := '';
Synchronize;
EXCEPTION
  WHEN OTHERS THEN
  :Query.Current_Status := 'Error found';
  Set_Application_Property(Cursor_Style, 'DEFAULT');
  MESSAGE(sqlerrm );
  --MESSAGE(sqlerrm );
  Synchronize;
END;
inside p_run_process there are other 25 database procedures.
help me !!!

Answer 1

Create a procedure as like,
PROCEDURE show_progress(x number) IS
y number;
BEGIN
  set_item_property('PART_DISP',VISIBLE,PROPERTY_TRUE);
  set_item_property('PART_DISP',WIDTH,x);
  set_item_property('PART_DISP',VISIBLE,PROPERTY_TRUE);
END;
PART_DISP is a display_item.
After completion of each procedures call the above procedure like,
cntr:=cntr+1;
show_progress(round(cntr/25*287,0));
synchronize;
where cntr is a counter it will be incremented 1 to 25, the constant value 287 is the maximum width of PART_DISP (you can change for your need).
The local variable cntr's initial value is 0 and maximum value is 25.    
cntr                   part_disp          % of progress
1
11.48
4
2
22.96
8
3
34.44
12
4
45.92
16
5
57.4
20
6
68.88
24
7
80.36
28
8
91.84
32
9
103.32
36
11
126.28
44
12
137.76
48
13
149.24
52
14
160.72
56
15
172.2
60
16
183.68
64
17
195.16
68
18
206.64
72
19
218.12
76
20
229.6
80
21
241.08
84
22
252.56
88
23
264.04
92
24
275.52
96
25
287
100
Hope this will help.