Display column value as column name

Question

Hi,
I have a requirement to display column names as column values and vice versa. Pls suggest how to do this.
Test data
create table oratest as select 'saurabh' "name",23 "age" from dual;
SQL> select * from oratest;
name           age
saurabh         23Expected output
saurabh         23
name           age

Answer 1

Ok, I've only got 10g here at the minute, so this is what I'd do...
SQL> ed
Wrote file afiedt.buf
  1  DECLARE
  2    v_v_val     VARCHAR2(4000);
  3    v_n_val     NUMBER;
  4    v_d_val     DATE;
  5    v_ret       NUMBER;
  6    c           NUMBER;
  7    d           NUMBER;
  8    col_cnt     INTEGER;
  9    f           BOOLEAN;
10    rec_tab     DBMS_SQL.DESC_TAB;
11    col_num     NUMBER;
12    v_rowcount  NUMBER := 0;
13    v_name      VARCHAR2(20);
14    v_age       NUMBER;
15    v_sql       VARCHAR2(4000);
16    v_str       VARCHAR2(250);
17    v_und       VARCHAR2(250);
18  BEGIN
19    select "name", "age"
20    into   v_name, v_age
21    from   oratest;
22    v_sql := 'SELECT ''name'' as "'||v_name||'", ''age'' as "'||v_age||'" from dual';
23    c := DBMS_SQL.OPEN_CURSOR;
24    DBMS_SQL.PARSE(c, v_sql, DBMS_SQL.NATIVE);
25    d := DBMS_SQL.EXECUTE(c);
26    DBMS_SQL.DESCRIBE_COLUMNS(c, col_cnt, rec_tab);
27    --
28    -- Bind local return variables to the various columns based on their types
29    FOR j in 1..col_cnt
30    LOOP
31      CASE rec_tab(j).col_type
32        WHEN 1 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000); -- Varchar2
33        WHEN 2 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_n_val);      -- Number
34        WHEN 12 THEN DBMS_SQL.DEFINE_COLUMN(c,j,v_d_val);     -- Date
35      ELSE
36        DBMS_SQL.DEFINE_COLUMN(c,j,v_v_val,2000);  -- Any other type return as varchar2
37      END CASE;
38    END LOOP;
39    -- Display the header
40    FOR j in 1..col_cnt
41    LOOP
42      v_str := v_str || rpad(rec_tab(j).col_name,30,' ')||' ';
43      v_und := v_und || rpad('-',30,'-')||' ';
44    END LOOP;
45    v_str := rtrim(v_str);
46    v_und := rtrim(v_und);
47    DBMS_OUTPUT.PUT_LINE(v_str);
48    DBMS_OUTPUT.PUT_LINE(v_und);
49    --
50    -- This part outputs the DATA
51    v_str := '';
52    LOOP
53      v_ret := DBMS_SQL.FETCH_ROWS(c);
54      EXIT WHEN v_ret = 0;
55      v_rowcount := v_rowcount + 1;
56      FOR j in 1..col_cnt
57      LOOP
58        CASE rec_tab(j).col_type
59          WHEN 1  THEN DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
60                       v_str := v_str||rpad(v_v_val,30,' ')||' ';
61          WHEN 2  THEN DBMS_SQL.COLUMN_VALUE(c,j,v_n_val);
62                       v_str := v_str||lpad(to_char(v_n_val,'fm999999999999'),30,' ')||' ';
63          WHEN 12 THEN DBMS_SQL.COLUMN_VALUE(c,j,v_d_val);
64                       v_str := v_str||rpad(to_char(v_d_val,'DD/MM/YYYY HH24:MI:SS'),30,' ')||' ';
65        ELSE
66          DBMS_SQL.COLUMN_VALUE(c,j,v_v_val);
67          v_str := v_str||rpad(v_v_val,30,' ')||' ';
68        END CASE;
69      END LOOP;
70      v_str := rtrim(v_str);
71      dbms_output.put_line(v_str);
72    END LOOP;
73    DBMS_SQL.CLOSE_CURSOR(c);
74* END;
SQL> /
saurabh                        23
name                           age
PL/SQL procedure successfully completed.
SQL>Now, with 11g you can actuall create the DBMS_SQL cursor from the top part of the code...
18  BEGIN
19    select "name", "age"
20    into   v_name, v_age
21    from   oratest;
22    v_sql := 'SELECT ''name'' as "'||v_name||'", ''age'' as "'||v_age||'" from dual';
23    c := DBMS_SQL.OPEN_CURSOR;
24    DBMS_SQL.PARSE(c, v_sql, DBMS_SQL.NATIVE);And using the new function in 11g's DBMS_SQL package called dbms_sql.to_refcursor and convert the DBMS_SQL cursor to a REF CURSOR which you can then use in your applications (if that's the way you need to go)...
http://www.oracle.com/technology/oramag/oracle/07-nov/o67asktom.html
Whatever route you take though, you won't do this simply in SQL as the column names of a query are required to be known before any data is retrieved when a query (cursor) executes. You can see that when you use the DBMS_SQL package, where the query has to be parsed and the column names and descriptions are determined before any fetching of data.