Doubts on user exits

Question

Hi, Could someone help me out with :
1) Specific user exits in SD and MM?
2) What mainly should we know for using user exits while working on SD , MM and FICO modules'?
3)How to find or search for BADI's

Answer 1

3) Goto SE18 and you will be able to get the available BADI's. or
You can debug the GET_CLASS_NAME_BY_INTERFACE method of CL_EXITHANDLER class at runtime.
1) The below program is obtained from some previous posts. You can get the list of exits for a particular transaction.
*& Report  ZKB_USER_EXIT_LIST
REPORT  zkb_user_exit_list NO STANDARD PAGE HEADING.
TABLES: tstc, tadir, modsapt, modact,
trdir, tfdir, enlfdir, tstct.
DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.
DATA : hotspot(30).
PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.
AT LINE-SELECTION.
  GET CURSOR FIELD hotspot.
  CHECK hotspot(4) EQ 'JTAB'.
  SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).
  CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.
START-OF-SELECTION.
  PERFORM get_data.
  PERFORM write_list.
* FORM get_data *
FORM get_data.
  SELECT SINGLE * FROM tstc
  WHERE tcode EQ p_tcode.
  CHECK sy-subrc EQ 0.
  SELECT SINGLE * FROM tadir
  WHERE pgmid = 'R3TR'
  AND object = 'PROG'
  AND obj_name = tstc-pgmna.
  IF sy-subrc NE 0.
    SELECT SINGLE * FROM trdir
    WHERE name = tstc-pgmna.
    IF trdir-subc EQ 'F'.
      SELECT SINGLE * FROM tfdir
      WHERE pname = tstc-pgmna.
      SELECT SINGLE * FROM enlfdir
      WHERE funcname = tfdir-funcname.
      SELECT SINGLE * FROM tadir
      WHERE pgmid = 'R3TR'
      AND object = 'FUGR'
      AND obj_name EQ enlfdir-area.
    ENDIF.
  ENDIF.
  SELECT * FROM tadir INTO TABLE jtab
  WHERE pgmid = 'R3TR'
  AND object = 'SMOD'
  AND devclass = tadir-devclass.
  SELECT SINGLE * FROM tstct
  WHERE sprsl EQ sy-langu
  AND tcode EQ p_tcode.
ENDFORM.                    "get_data
* FORM write_list *
FORM write_list.
  FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
  WRITE:/(19) 'Transaction Code - ',
  20(20) p_tcode,
  45(50) tstct-ttext.
  SKIP.
  IF NOT jtab[] IS INITIAL.
    WRITE:/(95) sy-uline.
    FORMAT COLOR COL_HEADING INTENSIFIED ON.
    WRITE:/1 sy-vline,
    2 'Exit Name',
    21 sy-vline ,
    22 'Description',
    95 sy-vline.
    WRITE:/(95) sy-uline.
    LOOP AT jtab.
      SELECT SINGLE * FROM modsapt
      WHERE sprsl = sy-langu AND
      name = jtab-obj_name.
      FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
      WRITE:/1 sy-vline,
      2 jtab-obj_name HOTSPOT ON,
      21 sy-vline ,
      22 modsapt-modtext,
      95 sy-vline.
    ENDLOOP.
    WRITE:/(95) sy-uline.
    DESCRIBE TABLE jtab.
    SKIP.
    FORMAT COLOR COL_TOTAL INTENSIFIED ON.
    WRITE:/ 'No of Exits:' , sy-tfill.
  ELSE.
    FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
    WRITE:/(95) 'No User Exit exists'.
  ENDIF.
ENDFORM.                    "write_list
Regards
Kathirvel