Dump during testing of ECC 6.0

Question

Dear All,
My client is upgrading from 4.7 to ECC 6.0. During testing of the new system dumps for some transactions have been arising.
For the transaction codes F-06, F-07, FBL5N and FB02 same kinds of errors have been found with similar program u201CSAPMF05Lu201D in the line no 1023. In the BSEG table the value of Docln is found out to be u201C#u201D for all the documents that have been imported from 4.7 to ECC 6.0.
Please note that these transactions are still working fine in the 4.7 system.
Below is the detail description of the error that we are receiving in ECC6.0 for the above mentioned transaction codes.
Steps to recreate the dump:
1.     Go to T-code FBL5N
2.     Provide the u201Ccustomer accountu201D, u201Ccompany codeu201D and u201Copen at key dateu201D. Then Execute.
3.     Double click on the Doc date and the dump occurs.
How do we go about it..
Regards,
Arvind

Answer 1

My issue has been resolved after running below program which SAP has recommended.
Run this report in the Dev --->ZF_DOCLN_UPDATE_YJ
*& Report ZF_DOCLN_UPDATE_YJ
*&Report to update the DOCLN field in BSEG, which has a hex value and is
*&shown as # to initial. Please note this report is not to be used for
*&FAGLFLEXA table problems.
REPORT zf_docln_update_yj.
TABLES: bseg.
DATA: BEGIN OF itab_bseg OCCURS 0,
bukrs LIKE bseg-bukrs,
belnr LIKE bseg-belnr,
gjahr LIKE bseg-gjahr,
buzei LIKE bseg-buzei,
docln LIKE bseg-docln,
END OF itab_bseg.
DATA: cnt TYPE i,
cnt_commit TYPE i.
FIELD-SYMBOLS: <docln>.
CONSTANTS: c_badchar(2) TYPE x VALUE '0000',
c_commit TYPE i value 10000.
SELECTION-SCREEN BEGIN OF BLOCK 001 WITH FRAME.
SELECT-OPTIONS: p_bukrs FOR bseg-bukrs,
p_gjahr FOR bseg-gjahr,
p_belnr FOR bseg-belnr,
p_buzei FOR bseg-buzei.
PARAMETERS: update AS CHECKBOX,
detail AS CHECKBOX.
SELECTION-SCREEN END OF BLOCK 001.
SELECT *
INTO CORRESPONDING FIELDS OF TABLE itab_bseg
FROM bseg
WHERE bukrs IN p_bukrs
AND belnr IN p_belnr
AND buzei IN p_buzei
AND gjahr IN p_gjahr.
ASSIGN itab_bseg-docln(1) TO <docln> CASTING TYPE x.
LOOP AT itab_bseg.
IF <docln> EQ c_badchar.
IF update = 'X'.
ADD 1 TO cnt_commit.
UPDATE BSEG SET docln = space
WHERE bukrs = itab_bseg-bukrs
AND belnr = itab_bseg-belnr
AND gjahr = itab_bseg-gjahr
AND buzei = itab_bseg-buzei.
IF cnt_commit GE c_commit.
COMMIT WORK.
CLEAR cnt_commit.
ENDIF.
ENDIF.
ADD 1 TO cnt.
ELSE.
DELETE itab_bseg.
ENDIF.
ENDLOOP.
IF update = 'X'.
COMMIT WORK.
FORMAT COLOR COL_NEGATIVE INTENSIFIED.
WRITE: /'Update Run'.
FORMAT COLOR COL_NEGATIVE INTENSIFIED OFF.
ELSE.
FORMAT COLOR COL_HEADING INTENSIFIED.
WRITE: /'Test Run'.
FORMAT COLOR COL_HEADING INTENSIFIED OFF.
ENDIF.
FORMAT COLOR COL_GROUP INTENSIFIED.
WRITE: /'Report run by ',sy-uname, 'at',sy-uzeit.
FORMAT COLOR COL_GROUP INTENSIFIED OFF.
ULINE.
SKIP 2.
ULINE.
FORMAT COLOR COL_GROUP INTENSIFIED.
WRITE: /'DOCLN changed for Documents'.
FORMAT COLOR COL_GROUP INTENSIFIED OFF.
ULINE.
WRITE: /5 'CoCode',
15 'Doc Num',
30 'Line no',
45 'Fiscal Year',
60 'Six-Figure Line Item for Ledger'.
ULINE.
IF detail EQ 'X'.
LOOP AT itab_bseg.
WRITE:/5 itab_bseg-bukrs,
15 itab_bseg-belnr,
30 itab_bseg-buzei,
45 itab_bseg-gjahr,
60 itab_bseg-docln.
ENDLOOP.
ENDIF.
WRITE: /1 'BSEG Line Item Update Count:', cnt.