Dumping at the select because of the IN operator

Question

Types:  BEGIN OF t_rsml,
         rsml  TYPE eban-zzrsmlind,
       END   OF t_rsml.
DATA: r_rsml TYPE RANGE OF t_rsml,
      wa_rsml LIKE LINE OF r_rsml.
  IF p_rsml EQ 'Y'.
    wa_rsml-sign   = 'I'.
    wa_rsml-option = 'EQ'.
    wa_rsml-low    = 'X'.
    APPEND wa_rsml TO r_rsml.
    CLEAR: wa_rsml.
  ELSEIF p_rsml EQ 'N'.
    wa_rsml-sign   = 'I'.
    wa_rsml-option = 'EQ'.
    wa_rsml-low    = ' '.
    APPEND wa_rsml TO r_rsml.
    CLEAR: wa_rsml.
  ELSEIF p_rsml EQ 'B'.
    wa_rsml-sign   = 'I'.
    wa_rsml-option = 'EQ'.
    wa_rsml-low    = ' '.
    APPEND wa_rsml TO r_rsml.
    CLEAR: wa_rsml.
    wa_rsml-sign   = 'I'.
    wa_rsml-option = 'EQ'.
    wa_rsml-low    = 'X'.
    APPEND wa_rsml TO r_rsml.
    CLEAR: wa_rsml.
  ENDIF.
  SELECT banfn
         bnfpo
         ekgrp
         txz01
         matkl
         menge
         meins
         badat
         frgdt
         preis
         lifnr
         bsmng
         zzattind
         zzcoind
         zzppoind
         zzrsmlind
         zzmm_reqstat
         FROM eban
         INTO TABLE i_item
        WHERE loekz        NE 'X'        " Deletion Indicator
          AND ekgrp        IN s_ekgrp    " Purchasing Group
          AND frgdt        IN s_frgdt    " release date
          AND ebakz        EQ ' '        " PR Closed Indicator
          AND memory       EQ ' '        " PR Incomplete Indicator
          AND ( banpr      EQ '02'       " 02 = Active
          OR    banpr      EQ '05' )     " 05 = Release Completed
          AND zzrsmlind    IN r_rsml     " RSML Indicator
          AND zzmm_reqstat IN s_prstat.  " PR Status
What could be the reasons.
Thanks,
Kiran

Answer 1

Hi Kiran,
<li>Instead of below declaration,
Types: BEGIN OF t_rsml,
rsml TYPE eban-zzrsmlind,
END OF t_rsml.
DATA: r_rsml  TYPE RANGE OF t_rsml,
      wa_rsml LIKE LINE OF r_rsml.
<li>Use below declaration
DATA: R_RSML TYPE RANGE OF EBAN-ZZRSMLIND,
      WA_RSML LIKE LINE OF R_RSML.
<li>I tried to replicate the same.Check the error one.
DATA: SPFLI_WA TYPE SPFLI.
TYPES:BEGIN OF T_CARRID,
        CARRID TYPE SPFLI-CARRID,
      END OF T_CARRID.
DATA: R_CARRID TYPE RANGE OF T_CARRID,
      R_CARRID_LINE LIKE LINE OF R_CARRID.
R_CARRID_LINE-SIGN   = 'I'.
R_CARRID_LINE-OPTION = 'EQ'.
R_CARRID_LINE-LOW    = ''.
APPEND R_CARRID_LINE TO R_CARRID.
R_CARRID_LINE-SIGN   = 'I'.
R_CARRID_LINE-OPTION = 'EQ'.
R_CARRID_LINE-LOW    = 'AA'.
APPEND R_CARRID_LINE TO R_CARRID.
SELECT  *
       FROM SPFLI
       INTO SPFLI_WA
       WHERE CARRID IN R_CARRID.
  WRITE / SPFLI_WA-CARRID.
ENDSELECT
<li>Corrected one
REPORT  ZTEST_NOTEPAD.
DATA: SPFLI_WA TYPE SPFLI.
DATA: R_CARRID TYPE RANGE OF SPFLI-CARRID,
      R_CARRID_LINE LIKE LINE OF R_CARRID.
R_CARRID_LINE-SIGN   = 'I'.
R_CARRID_LINE-OPTION = 'EQ'.
R_CARRID_LINE-LOW    = ''.
APPEND R_CARRID_LINE TO R_CARRID.
R_CARRID_LINE-SIGN   = 'I'.
R_CARRID_LINE-OPTION = 'EQ'.
R_CARRID_LINE-LOW    = 'AA'.
APPEND R_CARRID_LINE TO R_CARRID.
SELECT  *
       FROM SPFLI
       INTO SPFLI_WA
       WHERE CARRID IN R_CARRID.
  WRITE / SPFLI_WA-CARRID.
ENDSELECT.
Thanks
Venkat.O