Excel 2010 - Userform - VBA How to stop 'Job No' from duplicating itself on next empty row

Question


Hi there
Thank you in advance for taking the time to check this out.
Objective:
To prevent duplication of incident numbers in the datasheet, and format the job number with a prefix of
Inc- at the beginning. I currently have the cell customization set to “Inc”General but that only inserts the prefix in the cells on the datasheet, but is not showing in the disabled textbox in the userform.
The Problem
I have a ‘Job Number’ that is generated each time the form is opened and when the ‘Save’ button is clicked the data from the form is transferred over
The job number is generated from the previous entry +1 (auto incrementing the old fashioned way).
The problem arises when the ‘Save’ button is pressed repeatedly, the same job number and data is duplicated on the datasheet.
Is there some way to ensure that the number generated is unique, and if the ‘Save’ button is repeatedly pressed that it will just over-ride the existing information?
The number format currently used is 20150003 (incremented by 1). But what I’d like to be displayed in the form is
Inc- 20150003
The following code is in the form_initialize procedure.
Me.txtSEC_INC_No.Enabled = True
Dim irow As Long
Dim ws As ws_Incident_Details
Set ws = ws_Incident_Details
'find last data row from database'
irow = ws.Cells(Rows.Count, 1) _
.End(xlUp).Row
If ws.[a2].Value = "" Then
Me.txtSEC_INC_No.Text = 0 ' If no value in Col A, it will return a 0
Else
Me.txtSEC_INC_No.Text = ws.Cells(irow, 1).Value + 1
End If
I’d be really grateful if someone could help me out, or perhaps direct me to where I might find some coding that will achieve the result I am seeking.
I have just uploaded the latest version
My Sample form is linked to my Dropbox so you can see how it currently works (or doesn't work)
With much gratitude,
TheShyButterfly
Hope you have a terrific day, theShyButterfly

Answer 1

I am striving to improve my VBA but ... I am far from anywhere near in understanding the code that you have in your file. I feel really bad in saying that, but I am not a pretender, and will acknowledge when I am over my head.
I was thinking "simplified" :) ...
Don't worry, also Rom wasn't build in a day. :-)
I already answered the question about the duplication of the Job number in this thread:
https://social.msdn.microsoft.com/Forums/de-DE/52f3c62f-b26e-4573-b7c2-8e7203786d7f/excel-2010-vba-userforms-vlookup-via-textbox-display-result-in-another-textbox?forum=exceldev
So let us talk a little about the TAG property, thinking "simplified" and how to save the data:
Most people start with code like this when they start there first Userform:
Cells(MyRowNumber, 1) = txtBoxA
Cells(MyRowNumber, 2) = txtBoxB
etc. many many lines till
Cells(MyRowNumber, 56) = txtBoxWhatEver
And then, after Version 1.0, they realize that they also want to load data from a row into the form. And they copy all the lines and exchange
the parts before and after the
"=" like this:
txtBoxA = Cells(MyRowNumber, 1)
txtBoxB = Cells(MyRowNumber, 2)
etc. many many lines till
txtBoxWhatEver = Cells(MyRowNumber, 56)
And maybe you have another 56 lines to "clear" the Userform, and maybe more lines... over 150 lines just for this... that is really tremendous.
I will not be
too harsh,
if it works, then
it's okay.
But often many people struggle when they look into the code because, which column in the sheet is written by this line?
  Cells(MyRowNumber, 56) = txtBoxWhatEver
I've often seen that people change the code to this:
  Range("A" & MyRowNumber) = txtBoxA
  Range("B" & MyRowNumber) = txtBoxB
etc.  till
  Range("BD" & MyRowNumber) = txtBoxWhatEver
which is more clearly, but you must revise
150 lines!
And that is the point for the TAG property, which is in fact just a string. So when we write the column name ("A", "B", etc.) into the TAG property of a control, you can change the code to this:
  Range(txtBoxA.Tag & MyRowNumber) = txtBoxA
  Range(txtBoxB.Tag & MyRowNumber) = txtBoxB
etc.
And now the 1st trick, we can use a loop and visit all controls at once:
  Dim C As MSForms.Control
  For Each C In Me.Controls
    If C.Tag <> "" Then
      Range(C.Tag & MyRowNumber) = C
    End If
  Next
And when we want to load data from a row into the form, it's the same, just the other direction:
  Dim C As MSForms.Control
  For Each C In Me.Controls
    If C.Tag <> "" Then
      C = Range(C.Tag & MyRowNumber)
    End If
  Next
And to clear the form is also the same:
  Dim C As MSForms.Control
  For Each C In Me.Controls
    If C.Tag <> "" Then
      C = ""
    End If
  Next
So we can remove over 150 lines and do the same with just the 18 lines above.
Isn't that a simplification?
Think about that for a while.
Ready for the next trick? ;-)
As the TAG property is readable and writeable we can use Sub UserForm_Initialize and save a lot of manual work:
Private Sub UserForm_Initialize()
  Me.txtBoxA.Tag = "A"
  Me.txtBoxB.Tag = "B"
  'etc. till
  Me.txtBoxWhatEver.Tag = "BD"
End Sub
No time to waste,
here comes the next one. ;-)
In your file, you can have named ranges, but always have headings! And so we can get the column name e.g. from a named range:
  Me.txtBoxWhatEver.Tag = GetColumnName(Range("WhatEver"))
Function GetColumnName(ByVal R As Range) As String
Dim S As String
S = R.Address(1, 0)
GetColumnName = Left(S, InStr(S, "$") - 1)
End Function
Or you can use Range.Find and search for the header int the sheet and get the column name directly.
The benefit is that your form works even when the user change the layout of the sheet!
Simple
as it gets
(almost).
Andreas.