Export from Crystal Reports 2008 viewer fails if run on separate thread

Question

I have a windows desktop application written in Visual Basic using Visual Studio 2008.  I have installed and am trying Crystal Reports 2008 to run a report.  Everything seems to work well except that when I preview a report (using the viewer control) and click the export button found in the upper left corner of that control, I get the following message:
Error 5: Current thread must be set to single thread apartment (STA) mode before OLE calls can be made.  Ensure that your Main function has STAThreadAttribute marked on it.  This exception is only raised if a debugger is attached to the process.
I am a little confused on what to do exactly.  Is the problem because I am running in the Visual Studio 2008 IDE?  It says this exception is only raise if a debugger is attached to the process.  No, I tried running it outside the IDE.  The exception wasn't generated but the application hung when the button was clicked.
It says the current thread must be set to single thread apartment (STA) mode.  If the report is run on its own thread, is the "current" thread the thread the report is running on or is the main application's UI thread?  I don't think I want to set my main application to single thread apartment mode because it is a multi-threaded application (although I really don't know for sure because I am new to multi-threaded programming). 
My objective is to allow reports to run asynchronously so that the user can do other things while it is being generated.  Here is the code I use to do this:
    ' Previews the report using a new thread (asynchronously)
    Public Sub PreviewReportAsynch(ByVal sourceDatabase As clsMainApplicationDatabase)
        Dim backgroundProcess As System.ComponentModel.BackgroundWorker
        ' Start a new thread to run this report.
        backgroundProcess = New System.ComponentModel.BackgroundWorker
        Using (backgroundProcess)
            ' Wire the function we want to run to the 'do work' event.
            AddHandler backgroundProcess.DoWork, AddressOf PreviewReportAsynch_Start
            ' Kick off the report asynchronously and return control to the calling process
            backgroundProcess.RunWorkerAsync(sourceDatabase)
        End Using
    End Sub
    Private Sub PreviewReportAsynch_Start(ByVal sender As Object, ByVal e As System.ComponentModel.DoWorkEventArgs)
        ' The source database needed to call preview report was passed as the only argument
        Call PreviewReport(CType(e.Argument, clsMainApplicationDatabase))
    End Sub
    ' Previews the report.  From the preview window, the user can print it.
    Public Function PreviewReport(ByVal sourceDatabase As clsMainApplicationDatabase) As FunctionEndedResult
        Dim errorBoxTitle As String
        Dim frmPreview As frmReportPreview
        ' Setup error handling
        errorBoxTitle = "Preview " & Name & " Report"
        PreviewReport = FunctionEndedResult.FAILURE
        On Error GoTo PreviewError
        ' Set up the crxReport object
        If InitializeReportProcess(sourceDatabase) <> FunctionEndedResult.SUCCESS Then
            GoTo PreviewExit
        End If
        ' Use the preview form to preview the report
        frmPreview = New frmReportPreview
        frmPreview.Report = crxReport
        frmPreview.ShowDialog()
        ' Save any settings that should persist from one run to the next
        Call SavePersistentSettings()
        ' If we got this far everything is OK.
        PreviewReport = FunctionEndedResult.SUCCESS
PreviewExit:
        ' Do any cleanup work
        Call CleanupReportProcess(sourceDatabase)
        Exit Function
PreviewError:
        ' Report error then exit gracefully
        ErrorBox(errorBoxTitle)
        Resume PreviewExit
    End Function
The variable crxReport is of type ReportDocument and the windows form called 'frmPreview' has only 1 control, the crystal reports viewer. 
The print button on the viewer works fine.  Just the export button is failing.  Any ideas?

Answer 1

Hi Trevor.
Thank you for the reply.  The report document is create on the main UI thread of my application.  The preview form is created and destroyed on the separate thread.  For reasons I won't get into, restructuring the code to move all the initialization stuff inside the preview form is not an option (OK, if you a really curious, I don't always preview a report, sometimes I print and/or export it directly which means the preview form isn't used).
What I learned through some other research is that there are some things (like COM calls and evidently some OLE automation stuff) that cannot be run on a thread that uses the MTA threading model.   The export button probably uses some of this technology, thus the message stating that an STA threading model is required.  I restructured the code as follows to accomodate this requirement.  Here is a sample:
' Previews the report using a new thread (asynchronously)
    Public Sub PreviewReportAsynch(ByVal sourceDatabase As clsMainApplicationDatabase)
        Dim staThread As System.Threading.Thread
        ' Start the preview report function on a new thread
        staThread = New System.Threading.Thread(AddressOf PreviewReportAsynchStep1)
        staThread.SetApartmentState(System.Threading.ApartmentState.MTA)
        staThread.Start(sourceDatabase)
    End Sub
    Private Sub PreviewReportAsynchStep1(ByVal sourceDatabase As Object)
        Dim staThread As System.Threading.Thread
        ' Initialize report preview.  This includes staging any data and configuring the
        ' crystal report document object for use by the crystal report viewer control.
        If InitializeReportProcess(DirectCast(sourceDatabase, clsMainApplicationDatabase)) = FunctionEndedResult.SUCCESS Then
            ' Show the report to the user.  This must be done on an STA thread so we will
            ' start another of that type.  See description of PreviewReportAsynchStep2()
            staThread = New System.Threading.Thread(AddressOf PreviewReportAsynchStep2)
            staThread.SetApartmentState(System.Threading.ApartmentState.STA)
            staThread.Start(mcrxReport)
            ' Wait for step 2 to finish.  This blocks the current thread, but this thread
            ' isn't the main UI thread and this thread has no UI anymore (the progress
            ' form was closed) so it won't matter that is it blocked.
            staThread.Join()
            ' Save any settings that should persist from one successful run to the next
            Call SavePersistentSettings()
        End If
        ' Release the crystal report
        Call CleanupReportProcess(DirectCast(sourceDatabase, clsMainApplicationDatabase))
    End Sub
    ' The preview form must be launched on a thread that use the single-threaded apartment (STA) model.
    ' Threads use the multi-threaded apartment (MTA) model by default.  This is necessary to make the
    ' export and print buttons on the preview form work.  They do not work when running on a
    ' thread using MTA.
    Public Sub PreviewReportAsynchStep2(ByVal crxInitializedReport As Object)
        Dim frmPreview As frmReportPreview
        ' Use the preview form to preview the report.  The preview form contains the crystal reports viewer control.
        frmPreview = New frmReportPreview
        frmPreview.Report = DirectCast(crxInitializedReport, ReportDocument)
        frmPreview.ShowDialog()
    End Sub
Thanks for your help!
Andy