Global Exception Class

Question

Hi,
I have a global exception class which is inherited from already existing exception class.
I would like to use this class to raise different exceptions.
How to use this global exception class to raise exceptions with different descriptions?
can anybody explain or send a material on this?
Thanks in advance...
Sreenivas Reddy

Answer 1

I guess you have little misunderstanding of the Exception concept.
You have to RAISE the exception from any processing block (Subroutine, Method etc.) and CATCH the exception in where you call the subroutine.
Check this example. In this example, I am raising the exception from the method DEVIDE of the class LCL_TEST. Now, I call this method DEVIDE in the START-OF-SELECTION block. So, here I need to catch this raised exception by the DEVIDE method. In my example I have used the exception class ZCX_GEN_EXC, you may have to replace it with your exception class ZCX_SAMPLE_EXCEPTION.
CLASS lcl_test DEFINITION.
  PUBLIC SECTION.
    METHODS devide
      IMPORTING
        n1 TYPE i
      CHANGING
        n2 TYPE i
      RAISING
        zcx_gen_exc.
ENDCLASS.                    "lcl_test DEFINITION
START-OF-SELECTION.
  DATA: lo_test TYPE REF TO lcl_test,
        lo_exc  TYPE REF TO zcx_gen_exc,
        lf_n1   TYPE i,
        lf_n2   TYPE i.
  CREATE OBJECT lo_test.
  lf_n1 = 0.
  lf_n2 = 10.
  TRY.
      CALL METHOD lo_test->devide
        EXPORTING
          n1 = lf_n1
        CHANGING
          n2 = lf_n2.
* catching the exception
    CATCH zcx_gen_exc INTO lo_exc.
      MESSAGE lo_exc->wf_etext TYPE 'I'.
  ENDTRY.
CLASS lcl_test IMPLEMENTATION.
  METHOD devide.
    IF n1 = 0.
      RAISE EXCEPTION TYPE zcx_gen_exc
        EXPORTING
          wf_etext = 'Exception occured'
          wf_mtype = 'E'.
    ELSE.
      n2 = n2 / n1.
    ENDIF.
  ENDMETHOD.                    "devide
ENDCLASS.                    "lcl_Test IMPLEMENTATION
Regards,
Naimesh Patel