Hierarchy Function Modules (or Methods)?

Question

I am trying to retrieve all hierarchies, and their children nodes, below a main node. Is there a function module in SEM/BCS for doing this?
Are there other function modules that come in handy with hierarchies?
      Thank-You.

Answer 1

There isn't a single FM that I'm aware of.  You can piggy back the standard BCS functionality and acheive something similar.
You need to know period, year, version and fiscal year variant. 
Then...for this structure:
CG1
- CG2
- CG3
- - CG4
you can pass CG1 as your "parent" and retreive CG2, CG3, and CG4 as selections (according to date-from date-to in your CG master data).
I'll try to include the relevant section for this (it's from a number of methods in a class I created for an outbound interface)....I'm sure I don't have all the data declarations, and I might have a few unnecessary sections.
global variables
  data DO_AREA type ref to IF_UC_AREA .
  data DO_MODEL type ref to IF_UC_MODEL .
  data DO_MD_FACTORY type ref to IF_UG_MD_FACTORY .
initialize objects
*** method for initialize objects
  DATA:
  lo_factory        TYPE REF TO if_ug_md_factory,
  lo_char           TYPE REF TO if_ug_md_char,
  lo_value          TYPE REF TO if_ug_md_char_value,
  lt_field_val      TYPE ugmd_ts_field_val,
  ls_field_val      TYPE ugmd_s_field_val.
* Initialize master data factory
  CALL METHOD cl_uc_area=>if_uc_area~get_md_factory
    EXPORTING
      i_area        = c_cons_area
    IMPORTING
      eo_md_factory = lo_factory.
  do_md_factory = lo_factory.
* get area object, if it's not set
  IF do_area IS NOT BOUND.
    lo_char = do_md_factory->get_char_instance(
        i_fieldname = uc00_cs_fld-area ).
    ls_field_val-fieldname = uc00_cs_fld-area.
    ls_field_val-value     = c_cons_area.
    INSERT ls_field_val INTO TABLE lt_field_val.
    lo_value = lo_char->get_value_instance(
       it_value = lt_field_val ).
    do_area   ?= lo_value.
*   get data model
    IF do_model IS NOT BOUND.
      CALL METHOD do_area->get_model
        IMPORTING
          eo_model = do_model.
    ENDIF.
  ENDIF.
determine lower level consolidation groups
**Include lower level consolidation group nodes in cube selection.
  DATA:
  lo_context           TYPE REF TO if_uc_context,
  lt_value             TYPE uc0_ts_value,
  ls_value             TYPE uc0_s_value,
  ls_o_sel             TYPE uct_sx_sel,
  lt_sel               TYPE uc0_ts_sel,
  ls_sel               TYPE uc0_s_sel,
  ls_sid               TYPE ucd_s_sid,
  ls_sel_node          TYPE uc0_s_sel_node_sid,
  lt_sel_node          TYPE uc0_ts_sel_node_sid,
  lt_o_sel             TYPE uct_t_sel.
  CLEAR lt_value.
  ls_value-fieldname = c_cgcomp_fieldname. ' /1FB/SEM_CGCOMP
  ls_value-value = i_sem_cgcomp.           ' "parent" consolidation group
  APPEND ls_value TO lt_value.
  CALL METHOD do_model->do_sidmap->convert_value_to_sid
    EXPORTING
      i_fieldname = c_cgcomp_fieldname
      it_value    = lt_value
    IMPORTING
      es_sid      = ls_sid
    EXCEPTIONS
      not_found   = 1
      OTHERS      = 2.
  CLEAR lt_sel_node.
  ls_sel_node-fieldname =  c_cgcomp_fieldname.
  ls_sel_node-sign      = uc00_cs_ra-sign_i.
  ls_sel_node-s_node    = ls_sid.
  INSERT ls_sel_node INTO TABLE lt_sel_node.
  CLEAR lt_sel.
  CLEAR lt_value.
  CALL METHOD do_model->do_data_factory->create_sel
    EXPORTING
      it_node_sid = lt_sel_node
    RECEIVING
      eo_sel      = ls_o_sel-o_sel.
  APPEND ls_o_sel TO lt_o_sel.
  CLEAR ls_value.
  ls_value-fieldname = '/1FB/CS_VERSION'.     " CS Version
  ls_value-value = g_cs_version.
  APPEND ls_value TO lt_value.
  CLEAR ls_value.
  ls_value-fieldname = '/BIC/BCS_VERS'.          " Custom Version
  ls_value-value = g_bcs_vers.
  APPEND ls_value TO lt_value.
  CLEAR ls_value.
  ls_value-fieldname = 'FISCPERIOD'.
  ls_value-value = g_fiscperiod.
  APPEND ls_value TO lt_value.
  CLEAR ls_value.
  ls_value-fieldname = 'FISCVARNT'.
  ls_value-value = g_fiscvarnt.
  APPEND ls_value TO lt_value.
  CLEAR ls_value.
  ls_value-fieldname = 'FISCYEAR'.
  ls_value-value = g_fiscyear.
  APPEND ls_value TO lt_value.
  CALL METHOD do_model->derive_context
    EXPORTING
      it_value     = lt_value
    IMPORTING
      eo_context   = lo_context
    EXCEPTIONS
      info_missing = 1
      OTHERS       = 2.
  CALL METHOD ls_o_sel-o_sel->set_context
    EXPORTING
      io_context = lo_context.
  CALL METHOD ls_o_sel-o_sel->get_sel
    IMPORTING
      et_sel = lt_sel.
* lt_sel will contain the lower-level consolidation groups, beneath the "parent" consolidation group (i_sem_cgcomp)
* Add cons groups to selection criteria
  DELETE gt_range WHERE chanm = c_objnm_cgcomp.   ' 0SEM_CGCOMP
  LOOP AT lt_sel INTO ls_sel.
    CLEAR  gs_range.
    gs_range-chanm  = c_objnm_cgcomp.   ' 0SEM_CGCOMP
    gs_range-sign   = ls_sel-sign.
    gs_range-compop = ls_sel-option.
    gs_range-low    = ls_sel-low.
    gs_range-high   = ls_sel-high.
    APPEND gs_range TO gt_range.
  ENDLOOP.
Hope that helps...if not, you might be able to do a find for some of the sections of the code to find exactly how SAP is doing (I can only say that this functionality worked in my situation, not sure it works in all consolidation scenarios).  FYI - I was using this to read from the virtual cube in a custom task in order to outbound consolidated results.
- Chris