How can I make iTunes sort on the first word by default, even though that word is "The" or "A"?

Question

How can I make iTunes sort on the first word by default, even though that word is "The" or "A"?
I myself think that (for instance) "A tribe called Quest" should be sorted under "A", not "T".
Now I can edit the sort options manually per track and/or per selection, but I would really like to just kill this "iTunes-knows-how-you-should-sort"-feature in iTunes.
Anyone any suggestion on how to do that?
Thanks

Answer 1

Here is a modified version of one of Doug's Scripts. My modification was to add Sort Name to the list of tags that could be changed. I tried it on a single track and it worked. I recommend backing up your library first. Select the tracks you want to change (or all tracks) and run the script from the Applescript Editor.  If it works as intended, save it so you can apply it to newly imported tracks.  And, yes, I know this isn't the exact answer to your question, you want to change a preference setting in iTunes (if there is such a setting).
Original script can be forund at http://dougscripts.com/itunes/scripts/ss.php?sp=thistagthattag
Modified script is below. Start up Applescript Editor, paste it into a new window.  Start up iTunes and select the tracks to modify.  Click Run in the Applescript Editor.  Follow the instructions.
(* Put This In That
v2.0 april 22 2008
- runs as universal binary
- adds "Show" tag
- consolidated code
- saved as script bundle
v1.7 October 3, 2006
- adds "Album Artist" as option
v1.6 October 28, 2004
- works around iTunes 4.7 selection bug
v1.5 ('04/1)-- adds "grouping" tag
Get more free AppleScripts and info on writing your own
at Doug's AppleScripts for iTunes
http://dougscripts.com/itunes/
This program is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation; either version 2 of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
Get a copy of the GNU General Public License by writing to the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.
or visit http://www.gnu.org/copyleft/gpl.html
-- CONSTANTS
property allOptions : {"Song Name", "Artist", "Album", "Album Artist", "Composer", "Genre", "Comments", "Show", "Grouping", "Sort Name"}
property my_title : "Put This In That"
global thisTag, thatTag, theNewTags, theOriginalTags, yn
tell application "iTunes"
          if selection is not {} then -- if tracks are selected...
                    set sel to selection
                    set numTracks to (length of sel)
                    set s to "s"
                    if numTracks is 1 then set s to ""
                    display dialog "The data from one tag REPLACES the data in another tag in all the selected tracks, with option to delete data in first tag." & return & return & (numTracks & " track" & s & " selected.") buttons {"Cancel", "Continue"} default button 2 with title my_title giving up after 30
                    if gave up of result is true then return
                    my choose_this_tag()
                    my choose_that_tag()
                    set yn to (button returned of (display dialog "Delete data in " & thisTag & " afterwards?" buttons {"Yes", "No"} default button 2 with title my_title giving up after 45) is "Yes")
                    set oldfi to fixed indexing
                    set fixed indexing to true
                    repeat with t from 1 to numTracks
                              tell contents of item t of sel
                                        set theOriginalTags to {get name, get artist, get album, get album artist, get composer, get genre, get comment, get show, get grouping, get sort name}
                                        set theNewTags to theOriginalTags
                                        my do_put()
                                        set {name, artist, album, album artist, composer, genre, comment, show, grouping, sort name} to theNewTags
                              end tell
                    end repeat
                    set fixed indexing to oldfi
          else
  display dialog "No tracks have been selected." buttons {"Cancel"} default button 1 with icon 0 giving up after 30
          end if -- no selection
end tell
to choose_this_tag()
          tell application "iTunes"
                    set n to (choose from list allOptions with prompt ("Select a tag to get data from:") with title my_title)
                    if n is false then error number -128
                    set thisTag to (n as text)
          end tell
end choose_this_tag
to choose_that_tag()
          set o to {}
          repeat with t in allOptions
                    if (t as text) is not thisTag then copy t to end of o
          end repeat
          tell application "iTunes"
                    set n to choose from list o with prompt ("Use data from the " & thisTag & " tag to REPLACE data in...") with title my_title
                    if n is false then error number -128
                    set thatTag to n as text
          end tell
end choose_that_tag
to do_put()
          try
                    repeat with i from 1 to (length of allOptions)
                              if thisTag is (item i of allOptions) then
                                        set thisTag_sto to (item i of theOriginalTags)
                                        exit repeat
                              end if
                    end repeat
                    repeat with i from 1 to (length of allOptions)
                              if thatTag is (item i of allOptions) then
                                        set (item i of theNewTags) to thisTag_sto
                                        exit repeat
                              end if
                    end repeat
                    if yn then
                              repeat with i from 1 to (length of allOptions)
                                        if thisTag is (item i of allOptions) then
                                                  set (item i of theNewTags) to ""
                                                  exit repeat
                                        end if
                              end repeat
                    end if
          end try
end do_put