How can we place a F4 help in a parameter in selection screen

Question

Hi,
How can we place a F4 help in a parameter in selection screen. Can we do add a  Process 0n Value request similar to a module pool prg in stadard report program.
saji

Answer 1

Hello Saji,
Try below attached report.
Regards,
Naimesh.
Reward, if it is useful..!
REPORT ZTEST_NP_1.
DATA: HELPVAL1 LIKE HELP_VALUE OCCURS 0 WITH HEADER LINE .
DATA: VALUE_TAB     LIKE PDTASK-OTEXT OCCURS 2 WITH HEADER LINE.
DATA: VALUE         LIKE FEBMKA-BANKN,
      GIVEN_VALUE   LIKE HELP_INFO-FLDVALUE.
DATA: IT_T005T LIKE T005T OCCURS 0 WITH HEADER LINE,
      IT_T002T LIKE T002T OCCURS 0 WITH HEADER LINE.
SELECTION-SCREEN: BEGIN OF BLOCK BLK1 WITH FRAME TITLE ABC.
PARAMETERS:       P_SPRAS  LIKE  T002T-SPRAS,
                  P_LAND1  LIKE  T005T-LAND1.
SELECTION-SCREEN: END   OF BLOCK BLK1.
INITIALIZATION.
  ABC = 'Selection Criteria:'.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_LAND1.
  PERFORM VALUE_REQUEST_LAND1.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR P_SPRAS.
  PERFORM VALUE_REQUEST_SPRAS.
*&      Form  VALUE_REQUEST_land1
FORM VALUE_REQUEST_LAND1.
*---- Reading the Screen values.
  DATA: LT_DYNPFIELDS LIKE DYNPREAD OCCURS 0 WITH HEADER LINE,
        LV_DYNAME     LIKE D020S-PROG,
        LV_DYNUMB     LIKE D020S-DNUM.
*-------Append field which you want to read from the screen
  LV_DYNAME = SY-REPID.
  LV_DYNUMB = SY-DYNNR.
  LT_DYNPFIELDS-FIELDNAME = 'P_SPRAS'.
  APPEND LT_DYNPFIELDS.
  CALL FUNCTION 'DYNP_VALUES_READ'
       EXPORTING
            DYNAME     = LV_DYNAME
            DYNUMB     = LV_DYNUMB
       TABLES
            DYNPFIELDS = LT_DYNPFIELDS.
  SELECT * FROM T005T
         INTO  TABLE IT_T005T
         WHERE SPRAS = P_SPRAS.
    REFRESH: HELPVAL1, VALUE_TAB.
    CLEAR:   HELPVAL1, VALUE_TAB, GIVEN_VALUE, VALUE.
*---- Append field name for the columns in the help popup
    HELPVAL1-TABNAME    = 'T005T' .
    HELPVAL1-FIELDNAME  = 'LAND1' .
    HELPVAL1-SELECTFLAG = 'X' . " will return the value on the screen
    APPEND HELPVAL1 .
    CLEAR  HELPVAL1 .
    HELPVAL1-TABNAME    = 'T005T' .
    HELPVAL1-FIELDNAME  = 'LANDX' .
    HELPVAL1-SELECTFLAG = ' ' .
    APPEND HELPVAL1 .
    CLEAR  HELPVAL1 .
    LOOP AT IT_T005T.
      VALUE_TAB = IT_T005T-LAND1.
      APPEND VALUE_TAB.
      VALUE_TAB = IT_T005T-LANDX.
      APPEND VALUE_TAB.
    ENDLOOP.
    GIVEN_VALUE    = P_LAND1.
    CALL FUNCTION 'HELP_VALUES_GET_WITH_VALUE'
       EXPORTING
            DISPLAY      = SPACE
            GIVEN_VALUE  = GIVEN_VALUE
       IMPORTING
            SELECT_VALUE = VALUE
       TABLES
            FIELDS       = HELPVAL1
            VALUETAB     = VALUE_TAB.
    IF NOT VALUE IS INITIAL.
      P_LAND1 = VALUE. " Assing value to the parameter
    ENDIF.
ENDFORM.                    " VALUE_REQUEST_land1
*&      Form  VALUE_REQUEST_SPRAS
FORM VALUE_REQUEST_SPRAS.
  REFRESH: HELPVAL1, VALUE_TAB.
  CLEAR:   HELPVAL1, VALUE_TAB, GIVEN_VALUE, VALUE.
  HELPVAL1-TABNAME    = 'T002T' .
  HELPVAL1-FIELDNAME  = 'SPRSL' .
  HELPVAL1-SELECTFLAG = 'X' .
  APPEND HELPVAL1 .
  CLEAR  HELPVAL1 .
  HELPVAL1-TABNAME    = 'T002T' .
  HELPVAL1-FIELDNAME  = 'SPTXT' .
  HELPVAL1-SELECTFLAG = ' ' .
  APPEND HELPVAL1 .
  CLEAR  HELPVAL1 .
  SELECT * FROM T002T
         INTO   TABLE IT_T002T
         WHERE  SPRAS = SY-LANGU.
  LOOP AT IT_T002T.
    VALUE_TAB = IT_T002T-SPRSL.
    APPEND VALUE_TAB.
    VALUE_TAB = IT_T002T-SPTXT.
    APPEND VALUE_TAB.
  ENDLOOP.
  GIVEN_VALUE    = P_SPRAS.
  CALL FUNCTION 'HELP_VALUES_GET_WITH_VALUE'
       EXPORTING
          DISPLAY      = SPACE
          GIVEN_VALUE  = GIVEN_VALUE
       IMPORTING
          SELECT_VALUE = VALUE
       TABLES
          FIELDS       = HELPVAL1
          VALUETAB     = VALUE_TAB.
  IF NOT VALUE IS INITIAL.
    P_SPRAS = VALUE.
  ENDIF.
ENDFORM.                    " VALUE_REQUEST_SPRAS