How to continue the running process behind the model dialogue box options ?

Question

How to continue the running process behind the model dialogue box options like this
In Updation of K7 user press the Cancel Button
New dialogue box appear with Yes/No options.
But the backend updation is going on... not Pause the updation.
Like this how to do ?
Please provide me code.

Answer 1

I don't know, if you mean you have done your form or you have solved the problem.
It's visible your code is only partly reflecting your screenshot, and that's okay to demonstrate the problem you have given a fine example.
As you marked my suggestion as solution this may not be needed anymore, but here's how I modified your code and used a self made QuestionBox instead of messagebox.
The essential part is defining a callback method and letting the QuestionBox call back there. It's not essential I used RAISEEVENT, but it's fine as it has all the behaviour and parameters needed to call back.
Public oTestFrm
oTestFrm=Createobject("MyForm_Model_to_NonModel")
oTestFrm.Show
Define Class MyForm_Model_to_NonModel As Form
onxx = 0
Add Object lbl_DispValue As Label With Top=90, Left = 120, Width = 50, Height=30, Caption=''
Add Object cmd_Start As CommandButton With Top=120, Left = 120, Width = 50, Height=30, Caption='Start'
Add Object cmd_Stop As CommandButton With Top=120, Left = 190, Width = 50, Height=30, Caption='Stop', Enabled =.F.
Procedure cmd_Start.Click
This.Enabled =.F.
Thisform.cmd_Stop.Enabled =.T.
Thisform.onxx = 0
Do While Thisform.onxx < 90000000
DoEvents
Thisform.onxx = Thisform.onxx +1
Thisform.lbl_DispValue.Caption = Transform(Thisform.onxx)
Enddo
This.Enabled =.T.
Thisform.cmd_Stop.Enabled =.F.
Thisform.lbl_DispValue.Caption = ''
Procedure cmd_Stop.Click
* Here, I want NO PAUSE -- (Show running numbers continuously...)
* how to control Model to NonModel in Messagebox.
QuestionBox('Really stop the process', Thisform, 'handleanswer')
Endproc
Procedure handleanswer
Lparameters tlYes
If tlYes && means Stop
Thisform.onxx = 99999999999999999
Endif
Endproc
Enddefine
Procedure QuestionBox()
Lparameters tcMessage, toCaller, tcCallback
If Not Pemstatus(_Screen,"oForms",5)
_Screen.AddObject("oForms","Collection")
Endif
oMsgBox = Createobject("QuestionBoxForm", tcMessage, toCaller, tcCallback)
_Screen.oForms.Add(oMsgBox)
oMsgBox.Show(2)
Endproc
Define Class QuestionBoxForm As Form
Autocenter = .T.
AlwaysonTop = .T.
Minwidth = 200
Add Object label1 As Label With AutoSize=.T., WordWrap =.T.
Add Object cmdYes As CommandButton With Caption = "Yes", Width=40
Add Object cmdNo As CommandButton With Caption = "No", Width=40
Procedure Init()
Lparameters tcQuestion, toCaller, tcCallback
Thisform.label1.Caption = tcQuestion+" ?"
This.AddProperty("oCaller",toCaller)
This.AddProperty("cCallback",tcCallback)
This.Width = Max(This.Minwidth, Thisform.label1.Width)
Thisform.label1.Left = (This.Width-Thisform.label1.Width)/2
This.Height = Thisform.label1.Height+48
This.cmdYes.Left = This.Width/2 - 10 - This.cmdYes.Width
This.cmdNo.Left = This.Width/2 + 10
This.cmdYes.top = Thisform.label1.Height+24
This.cmdNo.top = This.cmdYes.top
Endproc
Procedure cmdYes.Click
#Define clYes .T.
Raiseevent(Thisform.oCaller,Thisform.cCallback,clYes)
Thisform.Release()
Endproc
Procedure cmdNo.Click
#Define clNo .F.
Raiseevent(Thisform.oCaller,Thisform.cCallback,clNo)
Thisform.Release()
Endproc
Enddefine
I didn't yet introduced a timer for counter display updates. As you see the counter hangs a bit, if you mouse over your form, but it is a way of multithreading without using a separate thread and instead keep the rest of the application active by DOEVENTS
in the long running loop code.
Bye, Olaf.
Olaf Doschke - TMN Systemberatung GmbH http://www.tmn-systemberatung.de