How to create a draft to a stocktransfer

Question

Hi,
i want to creat a draf to a stock transfer.
I know how to create do a sales/purchase document. But i can i do it to a stock trasnfer.
Thanks in advance

Answer 1

Below is a sample showing how to create a draft stock transfer using the DI.  (You can create this and other types of drafts using the SDK V2004).
Private Sub CreateDraftTransfer()
    On Error GoTo ErrorHandler
    Dim sboTransfer     As SAPbobsCOM.Documents
    Dim lngRetVal       As Long
    Dim lngErrCode      As Long
    Dim strErrmsg       As String
    Dim strTransfer     As String
    Set sboTransfer = sboCompany.GetBusinessObject(oDrafts)
    sboTransfer.DocObjectCodeEx = "67"
    sboTransfer.DocDate = Date
    sboTransfer.DocDueDate = Date
    sboTransfer.Lines.SetCurrentLine 0
    sboTransfer.Lines.ItemCode = "BEETLE S"
    sboTransfer.Lines.Quantity = 2
    sboTransfer.Lines.Price = 10
    sboTransfer.Lines.WarehouseCode = "OT"
    lngRetVal = sboTransfer.Add
    If lngRetVal <> 0 Then
        sboCompany.GetLastError lngErrCode, strErrmsg
        MsgBox "Error: " & strErrmsg
    Else
        Call sboCompany.GetNewObjectCode(strTransfer)
        MsgBox "Draft Transfer Created"
    End If
    Exit Sub
ErrorHandler:
    MsgBox "Error has occured. " & Err.Number & " " & Err.Description
End Sub
John.