How to fetch the customer debit balances form the KNC1 database table

Question

Hi Experts,
I am creating a ABAP report which would dispaly the customer credit balances for the currenct fiscal year.
I am fetching the values form KNC1 database table.....But in this table values are stored year wise.
But I want to display for the current fiscal year that means if teh user selects the 07/2011 as the month on the sleection screen then the debit balances from 072010 to 062011 should be dispalyed.
Could anyone please help me out to fetch this the debit balaces form KNC1 database table in the above format.
Or is there any other way to solve this problem?
Awating your urgent reply.
Many Thanks,
Komal.

Answer 1

Hi Komal,
First, you have to compute the initial period and the final period.
Next, you must read table KNC1 for the years comprised between these two periods.
Last, you must read the fields of table KNC1. For that, you should compose dynamically the name of the field, and then ASSIGN it to a FIELD-SYMBOL.
Now, just add up the values!
Please try the following code:
FIELD-SYMBOLS: <fs>.
DATA: t_knc1 TYPE TABLE OF knc1 WITH HEADER LINE.
DATA: d_debits LIKE knc1-um01s.
PARAMETERS: p_kunnr LIKE knc1-kunnr,
            p_bukrs LIKE knc1-bukrs,
            p_spmon TYPE spmon.
DATA: l_fieldname(20) TYPE c.
DATA: l_date LIKE sy-datum,
      l_date_from LIKE sy-datum,
      l_date_to LIKE sy-datum.
DATA: l_period(2) TYPE n.
DATA: l_num_times TYPE i.
START-OF-SELECTION.
"Compute the initial and final periods
  CONCATENATE p_spmon '01' INTO l_date.
  CALL FUNCTION 'RE_ADD_MONTH_TO_DATE'
    EXPORTING
      months  = '-1'
      olddate = l_date
    IMPORTING
      newdate = l_date_to.
  CALL FUNCTION 'RE_ADD_MONTH_TO_DATE'
    EXPORTING
      months  = '-12'
      olddate = l_date
    IMPORTING
      newdate = l_date_from.
"Read table KNC1
  SELECT *
    INTO CORRESPONDING FIELDS OF TABLE t_knc1
    FROM knc1
    WHERE kunnr = p_kunnr
      AND bukrs = p_bukrs
      AND gjahr BETWEEN l_date_from(4) AND l_date_to(4).
"this will yield at most 2 records, one for present year, and another one for the previous year.
"but if you select i.e. period '01.2012', initial_date = '01.01.2011' and final_date = '31.12.2011'
" --> thus only one year --> one record
  CLEAR: d_debits.
  LOOP AT t_knc1.
" If there's no year change
    IF l_date_from(4) = l_date_to(4).
      DO 16 TIMES.
        l_period = sy-index.
        CONCATENATE 'UM'      "compute dynamically the field name
                    l_period
                    'S'
          INTO l_fieldname.
        ASSIGN COMPONENT l_fieldname OF STRUCTURE t_knc1 TO <fs>.   "assign
        ADD <fs> TO d_debits.                  "and add up
      ENDDO.
    ELSE.
" If there IS a year change
      IF t_knc1-gjahr = l_date_from+0(4).
        l_num_times = 16 - l_date_from+4(2) + 1.    "you must loop 16 - initial_period + 1 times for the first year
        DO l_num_times TIMES.
          l_period = sy-index + l_date_from+4(2) - 1.
          CONCATENATE 'UM'                "compute dynamically the field name
                      l_period
                      'S'
            INTO l_fieldname.
          ASSIGN COMPONENT l_fieldname OF STRUCTURE t_knc1 TO <fs>.    "assign
          ADD <fs> TO d_debits.              "and add up
        ENDDO.
      ELSE.
        l_num_times = l_date_to+4(2).            "you must loop final_period times for the second year
        DO l_num_times TIMES.
          l_period = sy-index.
          CONCATENATE 'UM'               "compute dynamically the field name
                      l_period
                      'S'
            INTO l_fieldname.
          ASSIGN COMPONENT l_fieldname OF STRUCTURE t_knc1 TO <fs>.     "assign
          ADD <fs> TO d_debits.        "and add up
        ENDDO.
      ENDIF.
    ENDIF.
  ENDLOOP.
You'll have the result on variable 'd_debits'.
I hope this helps. Kind regards,
Alvaro