How to get PL/SQL output in Excelsheet & preserve trailing zero for VARCHAR

Question

Hi All,
I am trying to get the PL/SQL procedure out put to Excel sheet, I have wrote below code and it worked fine.
CREATE OR REPLACE PROCEDURE plsql_to_excel_demo IS
CURSOR cur_stock_details
IS
SELECT *
FROM stocks;
outfile UTL_FILE.file_type;
l_chr_string VARCHAR2(100);
l_chr_col_header VARCHAR2(100);
l_chr_file VARCHAR2(100);
l_chr_date VARCHAR2(20);
BEGIN
SELECT TO_CHAR(sysdate,'DD_MON_YYYY')
INTO l_chr_date
FROM dual;
l_chr_col_header :='SYMBOL'||CHR(9)||'COMPANY'||CHR(9)||'CURRENT_PRICE'||CHR(9)||'TRADE_DATE'||CHR(9)||'NUMBER_TRADED_TODAY'
||CHR(9)||'TODAYS_HIGH'||CHR(9)||'TODAYS_LOW';
l_chr_file := 'STOCK_REPORTS_'||l_chr_date||'.xls';
outfile := UTL_FILE.FOPEN ('/u01/app/UTL/out',l_chr_file, 'W');
UTL_FILE.PUT_LINE(outfile,l_chr_col_header);
FOR rec_stock_details IN cur_stock_details LOOP
/*l_chr_string := rec_stock_details.symbol||CHR(9)||''''||rec_stock_details.company||''''||CHR(9)
||rec_stock_details.current_price||CHR(9)||
TO_CHAR(rec_stock_details.trade_date,'DD/MM/YYYY')||CHR(9)||rec_stock_details.number_traded_today||CHR(9)||
rec_stock_details.todays_high||CHR(9)||rec_stock_details.todays_low;
l_chr_string := rec_stock_details.symbol||CHR(9)||rec_stock_details.company||CHR(9)||rec_stock_details.current_price||CHR(9)||
TO_CHAR(rec_stock_details.trade_date,'DD/MM/YYYY')||CHR(9)||rec_stock_details.number_traded_today||CHR(9)||
rec_stock_details.todays_high||CHR(9)||rec_stock_details.todays_low;
UTL_FILE.PUT_LINE(outfile,l_chr_string);
END LOOP;
UTL_FILE.FCLOSE (outfile);
EXCEPTION
WHEN OTHERS THEN
dbms_output.put_line ('Error in main '||SQLERRM);
END plsql_to_excel_demo;
I am facing the issue when I have VARCHAR2 column say Company in stocks table with value as 0000234. When I get the data Excel
sheet I can only see 234
for company name. I want to preserve the trailing zeros while getting the output in Excel sheet.
I have tried with adding single quote (') please see the commented part in the above code, but it will give me output in company
column in excel '0000234' which i don't want.
Is there any way I can make this work and only get 0000234 as company name in Excel.
Thanks for reading the post..
regards,
Shyam.
Edited by: Suryawanshi on Mar 22, 2010 5:40 PM

Answer 1

Yes, that should be a client (excel, or open office in my case) issue.
I stole some code from http://asktom.oracle.com/pls/asktom/f?p=100:11:0::::P11_QUESTION_ID:95212348059 to test this out.
Adding a single quote to the beginning of the string worked fine with my version of Open Office, should work for your Excel as well.
create table varchar2_test(col1 varchar2(10), col2 number(10));
insert into varchar2_test values ('000189', 10);
create or replace function  dump_csv( p_query     in varchar2,
                                      p_separator in varchar2 default ',',
                                      p_dir       in varchar2 ,
                                      p_filename  in varchar2 )
return number
is
    l_output        utl_file.file_type;
    l_theCursor     integer default dbms_sql.open_cursor;
    l_columnValue   varchar2(2000);
    l_status        integer;
    l_colCnt        number default 0;
    l_separator     varchar2(10) default '';
    l_cnt           number default 0;
begin
    l_output := utl_file.fopen( p_dir, p_filename, 'w' );
    dbms_sql.parse(  l_theCursor,  p_query, dbms_sql.native );
    for i in 1 .. 255 loop
        begin
            dbms_sql.define_column( l_theCursor, i, l_columnValue, 2000 );
            l_colCnt := i;
        exception
            when others then
                if ( sqlcode = -1007 ) then exit;
                else
                    raise;
                end if;
        end;
    end loop;
    dbms_sql.define_column( l_theCursor, 1, l_columnValue, 2000 );
    l_status := dbms_sql.execute(l_theCursor);
    loop
        exit when ( dbms_sql.fetch_rows(l_theCursor) <= 0 );
        l_separator := '';
        for i in 1 .. l_colCnt loop
            dbms_sql.column_value( l_theCursor, i, l_columnValue );
            utl_file.put( l_output, l_separator || l_columnValue );
            l_separator := p_separator;
        end loop;
        utl_file.new_line( l_output );
        l_cnt := l_cnt+1;
    end loop;
    dbms_sql.close_cursor(l_theCursor);
    utl_file.fclose( l_output );
    return l_cnt;
end dump_csv;
variable x number;
begin
   :x :=    dump_csv
               p_query     => 'select '''' || col1, col2 from varchar2_test',
               p_separator => ',',
               p_dir       => 'TEST_DIR',
               p_filename  => 'test_output.xls'
end;
print :x