How to get selection screen elements and its table reference of a report ?

Question

halo experts
How can I get selection screen elements and its table reference of a report ? . I tried rs_refresh_from_select_options. But I am unable to get the table and field it is referring to
For eg if my selection screen 1000 is
parameters: p_carrid type spfli-carrid,
select-options :s-_connid type sflight-connid.
is there any Fm or method which gives me what are the screen elements( p_carrid and s_connid ) and what table( splfi and sflight ) and field ( carrid and conid )it is referring to ?

Answer 1

The following code is an example of how you might dynamically determine all your PARAMETERS and SELECT-OPTIONS variables at run time.  The PARAMETERS and SELECT-OPTIONS only point to a dictionary element--not a specific table.  Even though you may say "spfli-carrid" or "sflight-connid", the data type really references the dictionary type and not a specific table/structure.
REPORT  ZTEST_PROG.
TABLES sflight.
DATA:
       screen_tab TYPE STANDARD TABLE OF screen,
       wa_screen TYPE screen,
       scrn_nm TYPE string,
       scrn_leftover TYPE string,
       l_type TYPE REF TO cl_abap_typedescr,
       typ_nm TYPE string,
       typ_pre TYPE string.
FIELD-SYMBOLS <fs_data> TYPE ANY.
PARAMETERS p_carrid TYPE spfli-carrid.
SELECT-OPTIONS s_connid FOR sflight-connid.
INITIALIZATION.
  LOOP AT SCREEN.
    IF screen-group3 = 'PAR'
      OR screen-group3 = 'LOW'.
        APPEND screen TO screen_tab.
    ENDIF.
  ENDLOOP.
START-OF-SELECTION.
  LOOP AT screen_tab INTO wa_screen.
    ASSIGN (wa_screen-name) TO <fs_data>.
    l_type = cl_abap_typedescr=>describe_by_data( <fs_data> ).
    IF wa_screen-group3 = 'LOW'.
      SPLIT wa_screen-name AT '-' INTO scrn_nm scrn_leftover.
      TRANSLATE scrn_nm TO UPPER CASE.
    ELSE.
      scrn_nm = wa_screen-name.
    ENDIF.
    SPLIT l_type->absolute_name AT '=' INTO typ_pre typ_nm.
    WRITE:
             / 'Screen Name:  ', scrn_nm,
             / 'DDIC Type:    ', typ_nm.
  ENDLOOP.
When you get into defining internal tables you can determine those at run time with cl_abap_structdescr.  The following is an example of how you might do that.  You can loop through the "components_table" and evaluate each field of the structure in this way.
DATA: structure_reference TYPE REF TO cl_abap_structdescr,
      components_table TYPE abap_compdescr_tab,
      components_structure LIKE LINE OF components_table.
structure_reference ?= cl_abap_structdescr=>describe_by_data( any_structure ).
components_table = structure_reference->components.
I don't know if this answers any of your questions but I hope that some of it is useful.