How to get the current schema name

Question

Hi,
Can anybody please tell me how to get the current schema name, there is some inbuilt function for this,but i am not getting that. Please help me.
Thanks
Jogesh

Answer 1

ok folks, I found the answer at Tom's as usual.
http://asktom.oracle.com/tkyte/who_called_me/index.html
I rewrote it into a function for kicks. just pass the results of DBMS_UTILITY.FORMAT_CALL_STACK to this function and you will get back the owner of the code making the call as well some extra goodies like the name of the code and the type of code depending on the parameter. This ignores the AUTHID CURRENT_USER issues which muddles the schemaid. Quick question, does the average user always have access to DBMS_UTILITY.FORMAT_CALL_STACK or does this get locked down on some systems?
cheers,
paul
create or replace
FUNCTION SELF_EXAM (
   p_call_stack VARCHAR2,
   p_type VARCHAR2 DEFAULT 'SCHEMA'
) RETURN VARCHAR2
AS
   str_stack   VARCHAR2(4000);
   int_n       PLS_INTEGER;
   str_line    VARCHAR2(255);
   found_stack BOOLEAN DEFAULT FALSE;
   int_cnt     PLS_INTEGER := 0;
   str_caller  VARCHAR2(30);
   str_name    VARCHAR2(30);
   str_owner   VARCHAR2(30);
   str_type    VARCHAR2(30);
BEGIN
   str_stack := p_call_stack;
   -- Loop through each line of the call stack
   LOOP
     int_n := INSTR( str_stack, chr(10) );
     EXIT WHEN int_cnt = 3 OR int_n IS NULL OR int_n = 0;
     -- get the line
     str_line := SUBSTR( str_stack, 1, int_n - 1 );
     -- remove the line from the stack str
     str_stack := substr( str_stack, int_n + 1 );
     IF NOT found_stack
     THEN
        IF str_line like '%handle%number%name%'
        THEN
           found_stack := TRUE;
        END IF;
     ELSE
        int_cnt := int_cnt + 1;
         -- cnt = 1 is ME
         -- cnt = 2 is MY Caller
         -- cnt = 3 is Their Caller
         IF int_cnt = 1
         THEN
            str_line := SUBSTR( str_line, 22 );
            dbms_output.put_line('->' || str_line);
            IF str_line LIKE 'pr%'
            THEN
               int_n := LENGTH('procedure ');
            ELSIF str_line LIKE 'fun%'
            THEN
               int_n := LENGTH('function ');
            ELSIF str_line LIKE 'package body%'
            THEN
               int_n := LENGTH('package body ');
            ELSIF str_line LIKE 'pack%'
            THEN
               int_n := LENGTH('package ');
            ELSIF str_line LIKE 'anonymous%'
            THEN
               int_n := LENGTH('anonymous block ');
            ELSE
               int_n := null;
            END IF;
            IF int_n IS NOT NULL
            THEN
               str_type := LTRIM(RTRIM(UPPER(SUBSTR( str_line, 1, int_n - 1 ))));
             ELSE
               str_type := 'TRIGGER';
             END IF;
             str_line  := SUBSTR( str_line, NVL(int_n,1) );
             int_n     := INSTR( str_line, '.' );
             str_owner := LTRIM(RTRIM(SUBSTR( str_line, 1, int_n - 1 )));
             str_name  := LTRIM(RTRIM(SUBSTR( str_line, int_n + 1 )));
          END IF;
       END IF;
   END LOOP;
   IF UPPER(p_type) = 'NAME'
   THEN
      RETURN str_name;
   ELSIF UPPER(p_type) = 'SCHEMA.NAME'
   OR    UPPER(p_type) = 'OWNER.NAME'
   THEN
      RETURN str_owner || '.' || str_name;
   ELSIF UPPER(p_type) = 'TYPE'
   THEN
      RETURN str_type;
   ELSE
      RETURN str_owner;
   END IF;
END SELF_EXAM;