How to reduce Parse time in dynamic SQL

Question

I'm using for a part of my code dynamic SQL with DBMS_SQL Package, this dynamic SQL code is located in a loop with say 1000 repeatations, if we trace the code we see that this sql statement is parsed 1000 times and this causes
a serios performance issue. If i convert this part of code into static PLSQL code , the statement is parsed only one time as expected. i would like
to know how i can resolve this problem in the dynamic SQL code.
Why in case of static SQL, despite it is inside the loop, it is parsed
only one time by ORACLE and in case of dynamic SQL as many as the upper limit of counter.
Why the ORACLE has different behaviour to parse them? Is there any way or trick
to force ORACLE to parse it only one time like static SQL?

Answer 1

despite the open cursor is also inside the loop but oracle parse it only one time.That is because PL/SQL is caching your cursor and resuing it. With DBMS_SQL you are opening a new cursor area in the loop for each iteration (DBMS_SQL.OPEN_CURSOR).
what you need to do is open/parse once and bind the value each time through the loop:
DECLARE
    expr      VARCHAR2(1000);
    check_cur PLS_INTEGER;
    nDummy    PLS_INTEGER;
    nFetched  PLS_INTEGER;
BEGIN
    -- Open Cursor
    check_cur := dbms_sql.open_cursor;
    expr      := 'select 1 from dual where ' || ':bindvar1 ' || '=' ||
                 ' ''bindvar1'' ';
    -- Parse Cursor
    dbms_sql.parse(check_cur,
                   expr,
                   1);
    FOR counter IN 1 .. 1000
    LOOP
        -- Define Column
        DBMS_SQL.define_column(check_cur,
                               1,
                               1);
        -- Do Binding
        dbms_sql.bind_variable(check_cur,
                               ':bindvar1',
                               'bindname1');
        -- Execute Cursor
        nDummy := DBMS_SQL.EXECUTE(check_cur);
        -- Fetch Rows
        nFetched := DBMS_SQL.fetch_rows(check_cur);
    END LOOP;
    -- Close Cursor
    dbms_sql.close_cursor(check_cur);
END;
call     count       cpu    elapsed       disk      query    current        rows
Parse        1      0.21       0.23          0          0          0           0
Execute   1000      0.11       0.10          0          0          0           0
Fetch     1000      0.03       0.01          0          0          0           0
total     2001      0.35       0.35          0          0          0           0