Is it possible that my update stats used only correct tables?

Question

Whenever there is a schedule maintenance run I receive a error:
Executing the query "UPDATE STATISTICS [Perf].[PerfHourly_F65954CD35A54..." failed with the following error: "Table 'PerfHourly_F65954CD35A549E886A48E53F148F277' does not exist.". Possible failure reasons: Problems with the query, "ResultSet"
property not set correctly, parameters not set correctly, or connection not established correctly.
Is it possible that my update stats used only correct  tables?
Thanks

Answer 1

Use below script ...(change if required)
USE [dbname]
go
DECLARE @mytable_id INT
DECLARE @mytable VARCHAR(100)
DECLARE @owner VARCHAR(128)
DECLARE @SQL VARCHAR(256)
SELECT @mytable_id = MIN(object_id)
FROM sys.tables WITH(NOLOCK)
WHERE is_ms_shipped = 0
WHILE @mytable_id IS NOT NULL
BEGIN
 SELECT @owner = SCHEMA_NAME(schema_id), @mytable = name
 FROM sys.tables
 WHERE object_id = @mytable_id
 SELECT @SQL = 'UPDATE STATISTICS '+ QUOTENAME(@owner) +'.' + QUOTENAME(@mytable) +' WITH ALL, FULLSCAN;'
 Print @SQL
 EXEC (@SQL)
 SELECT @mytable_id = MIN(object_id)
 FROM sys.tables WITH(NOLOCK)
 WHERE object_id > @mytable_id
  AND is_ms_shipped = 0
END
Or use below for required table only but it will not execute only generate script, make change as per ur requirements:
SELECT X.*,
  ISNULL(CASE
    WHEN X.[Total Rows]<=1000
    THEN
      CASE
        WHEN [Percent Modified] >=20.0
        THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name] + ' WITH ALL, FULLSCAN  --20% Small Table Rule'
      END
    WHEN [Percent Modified] = 100.00
    THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  --100% No real Stats Rule'
    --WHEN X.[Rows Modified] > 1000
    --THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  --1000 Rows Modified Rule'
    ELSE
      CASE
        WHEN X.[Total Rows] > 1000000000 --billion rows
        THEN CASE
               WHEN [Percent Modified] > 0.1
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 1B Big Table Rule'
             END
        WHEN X.[Total Rows] > 100000000  --hundred million rows
        THEN CASE
               WHEN [Percent Modified] > 1.0
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 100M Big Table Rule'
             END
        WHEN X.[Total Rows] > 10000000   --ten million rows
        THEN CASE
               WHEN [Percent Modified] > 2.0
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 10M Big Table Rule'
             END
        WHEN X.[Total Rows] > 1000000    --million rows
        THEN CASE
               WHEN [Percent Modified] > 5.0
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 1M Big Table Rule'
             END
        WHEN X.[Total Rows] > 100000     --hundred thousand rows
        THEN CASE
               WHEN [Percent Modified] > 10.0
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 100K Big Table Rule'
             END
        WHEN X.[Total Rows] > 10000      --ten thousand rows
        THEN CASE
               WHEN [Percent Modified] > 20.0
               THEN 'UPDATE STATISTICS ' + [Schema Name] + '.' + [Table Name]     + ' WITH ALL, FULLSCAN  -- 10K Big Table Rule'
             END
        END
  END,'') AS [Statistics SQL]
FROM (
SELECT  DISTINCT
        DB_NAME()   AS [Database],
        S.name      AS [Schema Name],
        T.name      AS [Table Name],
        I.rowmodctr AS [Rows Modified],
        P.rows      AS [Total Rows],
        CASE
          WHEN I.rowmodctr > P.rows
          THEN 100
          ELSE CONVERT(decimal(8,2),((I.rowmodctr * 1.0) / P.rows * 1.) * 100.0)
        END AS [Percent Modified]
FROM
        sys.partitions P
        INNER JOIN sys.tables  T ON P.object_Id = T.object_id
        INNER JOIN sys.schemas S ON T.schema_id = S.schema_id
        INNER JOIN sysindexes  I ON P.object_id = I.id
WHERE P.index_id in (0,1)
  AND I.rowmodctr > 0
) X
WHERE [Rows Modified] > 1000
ORDER BY [Rows Modified] DESC
Please click "Propose As Answer"
if a post solves your problem, or "Vote As Helpful" if a post has been useful
to you