Is therr any way to drag one line in ALV to a new postion in the ALV list?

Question

Dear All,
Is there any way to drag one line of ALV and drop it to  a new position ?
Woud you please show me some simple code?

Answer 1

Hi Edwards,
Drag and drop can be achived using the events in the class.
TABLES:
  SSCRFIELDS.
PARAMETERS:
  P_TABLE TYPE DD02L-TABNAME OBLIGATORY.
DATA:
  W_DYNTABLE TYPE REF TO DATA,
  W_DYSTABLE TYPE REF TO DATA,
  W_STRUC    TYPE REF TO DATA.
FIELD-SYMBOLS:
  <T_TABLE>  TYPE STANDARD TABLE,
  <FS_TABLE> TYPE ANY,
  <T_STABLE> TYPE STANDARD TABLE,
  <FS_STABLE> TYPE ANY.
DATA:
  EFFECT TYPE I,
  HANDLE_ALV TYPE I.
DATA:
  GRID TYPE REF TO CL_GUI_ALV_GRID,
  CONT TYPE REF TO CL_GUI_DOCKING_CONTAINER,
  C_DRAGDROPALV TYPE REF TO CL_DRAGDROP,
  T_STBL TYPE LVC_S_STBL,
  T_LAYO TYPE LVC_S_LAYO.
AT SELECTION-SCREEN.
  SELECT TABNAME
    FROM DD02L
   UP TO 1 ROWS
    INTO P_TABLE
   WHERE TABNAME = P_TABLE AND TABCLASS = 'TRANSP'.
  ENDSELECT.
  IF SY-SUBRC NE 0.
    CLEAR SSCRFIELDS-UCOMM.
    MESSAGE 'Invalid Table Name'(001) TYPE 'E'.
  ENDIF.
START-OF-SELECTION.
  CREATE DATA W_DYNTABLE TYPE STANDARD TABLE OF (P_TABLE)
                                      WITH NON-UNIQUE DEFAULT KEY.
  CREATE DATA W_DYSTABLE TYPE STANDARD TABLE OF (P_TABLE)
                                      WITH NON-UNIQUE DEFAULT KEY.
  CREATE DATA W_STRUC TYPE (P_TABLE).
  ASSIGN W_DYNTABLE->* TO <T_TABLE>.
  ASSIGN W_DYSTABLE->* TO <T_STABLE>.
  ASSIGN W_STRUC->* TO <FS_TABLE>.
  ASSIGN W_STRUC->* TO <FS_STABLE>.
  SELECT * FROM (P_TABLE) INTO CORRESPONDING FIELDS OF TABLE
  <T_TABLE>.
  CALL SCREEN 100.
      CLASS lcl_dataobject DEFINITION
CLASS LCL_DATAOBJECT DEFINITION.
  PUBLIC SECTION.
    DATA:
        INDEX TYPE I.
ENDCLASS.                    "lcl_dataobject DEFINITION
DATA:
  L_OBJ TYPE REF TO LCL_DATAOBJECT.
      CLASS lcl_event_handler DEFINITION
CLASS LCL_EVENT_HANDLER DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS:
          DRAG FOR EVENT
                       ONDRAG OF CL_GUI_ALV_GRID
                       IMPORTING ES_ROW_NO E_DRAGDROPOBJ E_ROW,
          DROP FOR EVENT
                       ONDROP OF CL_GUI_ALV_GRID
                       IMPORTING ES_ROW_NO E_DRAGDROPOBJ E_ROW.
ENDCLASS.                    "lcl_event_handler DEFINITION
      CLASS lcl_event_handler  IMPLEMENTAION
CLASS LCL_EVENT_HANDLER IMPLEMENTATION.
  METHOD DRAG .
    CREATE OBJECT L_OBJ.
    READ TABLE <T_TABLE> INDEX ES_ROW_NO-ROW_ID ASSIGNING <FS_TABLE> .
    IF SY-SUBRC EQ 0.
      L_OBJ->INDEX = E_ROW-INDEX.
      ASSIGN <FS_TABLE> TO <FS_STABLE>.
      APPEND <FS_STABLE> TO <T_STABLE>.
      E_DRAGDROPOBJ->OBJECT = L_OBJ.
    ENDIF.
  ENDMETHOD.                    "lcl_event_handler
  METHOD DROP.
    DELETE <T_TABLE> INDEX L_OBJ->INDEX.
    LOOP AT <T_STABLE> ASSIGNING <FS_STABLE>.
      INSERT <FS_STABLE> INTO <T_TABLE> INDEX E_ROW-INDEX.
    ENDLOOP.
    PERFORM REFRESH_TABLE.
    CLEAR <FS_STABLE>.
    REFRESH <T_STABLE>.
  ENDMETHOD.                    "drop
ENDCLASS.                    "lcl_event_handler  IMPLEMENTAION
*&      Module  STATUS_0100  OUTPUT
      text
MODULE STATUS_0100 OUTPUT.
  SET PF-STATUS 'ALV'.
  SET TITLEBAR 'TITLE' WITH P_TABLE.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Module  USER_COMMAND_0100  INPUT
      text
MODULE USER_COMMAND_0100 INPUT.
  CASE SY-UCOMM.
    WHEN 'BACK'.
      LEAVE TO SCREEN 0.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&      Module  display  OUTPUT
      text
MODULE DISPLAY OUTPUT.
  CREATE OBJECT CONT
     EXPORTING
       DYNNR             = '100'
       SIDE              = CL_GUI_DOCKING_CONTAINER=>DOCK_AT_TOP
       EXTENSION         = 350.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  CREATE OBJECT GRID
    EXPORTING
      I_PARENT          = CONT.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  CREATE OBJECT C_DRAGDROPALV.
  EFFECT = CL_DRAGDROP=>MOVE + CL_DRAGDROP=>COPY.
  CALL METHOD C_DRAGDROPALV->ADD
    EXPORTING
      FLAVOR     = 'Line'(002)
      DRAGSRC    = 'X'
      DROPTARGET = 'X'
      EFFECT     = EFFECT.
  CALL METHOD C_DRAGDROPALV->GET_HANDLE
    IMPORTING
      HANDLE = HANDLE_ALV.
  T_LAYO-S_DRAGDROP-ROW_DDID = HANDLE_ALV.
  CALL METHOD GRID->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      I_STRUCTURE_NAME = P_TABLE
      IS_LAYOUT        = T_LAYO
    CHANGING
      IT_OUTTAB        = <T_TABLE>.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  SET HANDLER LCL_EVENT_HANDLER=>DRAG FOR GRID.
  SET HANDLER LCL_EVENT_HANDLER=>DROP FOR GRID.
ENDMODULE.                 " display  OUTPUT
*&      Form  refresh_table
      text
-->  p1        text
<--  p2        text
FORM REFRESH_TABLE .
  CALL METHOD GRID->REFRESH_TABLE_DISPLAY
    EXPORTING
      IS_STABLE      = T_STBL
      I_SOFT_REFRESH = 'X'
    EXCEPTIONS
      FINISHED       = 1
      OTHERS         = 2.
  IF SY-SUBRC <> 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
               WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " refresh_table
Edited by: Kumar M on Jun 29, 2009 8:02 AM