Length of record 2000,after 991 char remaining data appears in next line

Question

Length of the record is 2000,but after 991 character the remaining data is placed in next line.the file is received in mail as attachment.
mail informations - MIME setting available is 1.0 version and encoding is 7 bit
File is opend and reads a line, while writing using utl_smtp.write_data writes 991 character and places a new line character chr(13) || chr(10).
problem is in utl_smtp.write_data
Can any one help ,who faced this issue and got rectified
Edited by: 796208 on Sep 22, 2010 4:51 AM

Answer 1

I still do not see a problem using attachments with long lines and mixing that with a mail body using long lines.
SQL> declare
  2          type TStrings is table of varchar2(1000);
  3 
  4          smtpSender      varchar2(100)   := '[email protected]';
  5          smtpRecipient   varchar2(100)   := '[email protected]';
  6          mailSubject     varchar2(100)   := 'Sample Mail';
  7          mimeBoundary    varchar2(100)   := 'CutHere';
  8          smtpConn        UTL_SMTP.connection;
  9 
10  BEGIN
11          smtpConn := UTL_SMTP.open_connection( 'mail.domain.com', 25);
12 
13          UTL_SMTP.helo( smtpConn, '[email protected]' );
14          UTL_SMTP.mail( smtpConn, smtpSender );
15          UTL_SMTP.rcpt( smtpConn, smtpRecipient );
16 
17          -- start sending mail body using the data command
18          UTL_SMTP.open_data( smtpConn );
19 
20          -- write header
21          UTL_SMTP.write_data( smtpConn, 'MIME-Version: 1.0'||utl_tcp.CRLF );
22          UTL_SMTP.write_data( smtpConn, 'Content-Type: multipart/related; type="text/plain"; boundary="'||
23                                  mimeBoundary||'"'|| utl_tcp.CRLF );
24          UTL_SMTP.write_data( smtpConn, 'From: '||smtpSender||utl_tcp.CRLF );
25          UTL_SMTP.write_data( smtpConn, 'To: '||smtpRecipient||utl_tcp.CRLF );
26          UTL_SMTP.write_data( smtpConn, 'Subject: '||mailSubject||utl_tcp.CRLF );
27 
28          -- empty line between header and rest of mail body
29          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
30          UTL_SMTP.write_data( smtpConn, 'This is a multi-part message in MIME format.'|| utl_tcp.CRLF );
31          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
32 
33          -- now write the mail body
34          UTL_SMTP.write_data( smtpConn, '--'||mimeBoundary || utl_tcp.CRLF );
35          UTL_SMTP.write_data( smtpConn, 'Content-Type: text/plain; charset="us-ascii"'|| utl_tcp.CRLF );
36          UTL_SMTP.write_data( smtpConn, 'Content-Transfer-Encoding: quoted-printable'|| utl_tcp.CRLF );
37          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
38          UTL_SMTP.write_data( smtpConn, 'start of mail message:'|| utl_tcp.CRLF );
39          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'1') );
40          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'2') );
41          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'3') );
42          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
43          UTL_SMTP.write_data( smtpConn, 'end of mail message' );
44          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
45 
46          -- add an attachhment
47          UTL_SMTP.write_data( smtpConn, '--'||mimeBoundary || utl_tcp.CRLF );
48          UTL_SMTP.write_data( smtpConn, 'Content-Type: text/csv'|| utl_tcp.CRLF );
49          UTL_SMTP.write_data( smtpConn, 'Content-Disposition: attachment; filename="test.csv"'|| utl_tcp.CRLF );
50          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
51          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'1')|| ',' );
52          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'2')|| ',' );
53          UTL_SMTP.write_data( smtpConn, lpad('x',1000,'3')|| utl_tcp.CRLF );
54          UTL_SMTP.write_data( smtpConn, utl_tcp.CRLF );
55 
56          -- close the data command
57          UTL_SMTP.close_data( smtpConn );
58 
59          -- terminate connection
60          UTL_SMTP.quit( smtpConn );
61  end;
62  /
PL/SQL procedure successfully completed.
SQL> The mail shows correctly in my mail reader - both body and attachment contains lines that exceed a the 998(?) character limit you said results in a CRLF to be inserted.
Make sure you know how your SMTP server deals with longs lines ito RFC compliance. Use telnet, from the Oracle db server platform, and connect to the SMTP server and manually send an e-mail with long lines. Determine what the end-result is (viewing raw mail contents) in the mail reader.
Or post a (easily executed) test case here that demonstrates the specific problem.