Need BADI or user exit to check info record on MM41/MM42.

Question

System:  SAP ECC 6.0 Retail
Problem:  During article maintenance (MM41/MM42), we want to check certain fields on the info record (EINA) for only one valuation class.
Steps already taken: 
Checked the current BADi.  The current BADi, BADI_MATERIAL_CHECK, did not contain a parameter for EINA.  (It did contain parameters for MARA, MARC, MBEW, MKVE, etc.)
Searched for other user exits and/or BADiu2019s.  In SPRO/IMG under Logistics General, Material Master, Retail Specific Settings, Settings for Core Master Data and BADi: Additional Checks and Data Adjustment, I found u201CWRF_MAT_MAINTAINDATAu201D which contains a method u201CMODIFY_INFORECORD_DATAu201D.  This looked like it may be what I was looking for.
So I created an implementation ZWRF_MAT_MAINTAINDAT.  It insisted on defined filters.  So I set up the following filters:
01     Core Article  Master Data Maintenance
02     Article Copy Functions
03     Article Mass Maintenance
99     Not Specified
Then I activated it.
I put a break into the method, but the transaction MM42 (nor MM41) would stop at the break point.
Did I miss a step?  Is this the wrong BADi?  Are the filters wrong?
Can anyone help?

Answer 1

There is BAdI for this.
However, a SAP consultant provided the following:
In IF_EX_BADI_MATERIAL_CHECK~CHECK_DATA_RETAIL
METHOD if_ex_badi_material_check~check_data_retail.
* Implementation of BADI_MATERIAL_CHECK
* Author: Syama Srinivasan, SAP Retail
* Date:   December 17, 2008
* Description:
* Check EINA fields in Purchasing View of Article Master Create/Modify using MM41 & MM42.
* If "Valuation Class" in the "Basic View --> General Data" field is 3100, then ensure
* that the "Var. Order Unit" OR "Return Agmt" fields in "Purchasing Veiw --> General
* data for each vendor" are not blank.
* Work area declaration.
  DATA: l_eina  TYPE eina,    "Purchasing Info Record: General Data
        l_maw1  TYPE maw1.    "Article Master: Default Fields and Special Retail Fields
* Local variables
  DATA: lv_eina    TYPE char30 VALUE '(SAPLMGMW)EINA',      "EINA Work area
        lv_maw1    TYPE char30 VALUE '(SAPLMGMW)MAW1'.      "MAW1 Work
  DATA: ls_errdat  TYPE merrdat.
* Field symbols
  FIELD-SYMBOLS: <fs_xmaw1> TYPE maw1,
                 <fs_xeina> TYPE eina.
  ASSIGN: (lv_maw1) TO  <fs_xmaw1>,
          (lv_eina) TO  <fs_xeina>.
  IF sy-tcode = 'MM41'
  OR sy-tcode = 'MM42'.
* Perform the check only if "Valuation class" is 3100
    IF <fs_xeina> IS ASSIGNED AND
       <fs_xmaw1> IS ASSIGNED.
      IF <fs_xmaw1>-wbkla = '3100'
      AND <fs_xeina>-lifnr IS NOT INITIAL.
        IF <fs_xeina>-vabme IS INITIAL OR
           <fs_xeina>-rueck IS INITIAL.
*        MESSAGE e009(z1id) WITH <fs_xmaw1>-wbkla.
          ls_errdat-msgid = 'Z1ID'.
          ls_errdat-msgty = 'E'.
          ls_errdat-msgno = '009'.
          ls_errdat-msgv1 = <fs_xmaw1>-wbkla.
          APPEND ls_errdat TO rt_errdat.
          MESSAGE e009(z1id) WITH <fs_xmaw1>-wbkla.
        ENDIF.
      ENDIF.
    ENDIF.
* Perform the check only if "Valuation class" is 3100
    IF <fs_xeina> IS ASSIGNED AND
       <fs_xmaw1> IS ASSIGNED.
      IF <fs_xmaw1>-wbkla = '3100'
      AND <fs_xeina>-lifnr IS NOT INITIAL.
        IF <fs_xeina>-vabme NE '2'.
*        <fs_xeina>-vabme = '2'.   This doesn't work
          ls_errdat-msgid = 'Z1ID'.
          ls_errdat-msgty = 'E'.
          ls_errdat-msgno = '010'.
          ls_errdat-msgv1 = <fs_xmaw1>-wbkla.
          APPEND ls_errdat TO rt_errdat.
          MESSAGE e010(z1id) WITH <fs_xmaw1>-wbkla.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.
ENDMETHOD.