Need Suggestion for the Recurrence appointment design

Question

Hello All, 
We are planning to design  a feature where doctor can create appointment  with the patients on the recurrence basis like Daily, Weekly,yearly etc. 
Following features also needs to be present 
1. User can edit the recurrence appointment and that changes must apply to all 
2. user can go and change the details for the single appointment 
We had a discussion  for this and  identified the below schema to store the details..
TABLE  Appointment                   
AppointmentID,                         
DocID, 
PatientID, 
FromTime,
ToTime, 
IsRecurrence, 
RecurrenceID
TABLE RECURRENCE
SeqID,
RecurrenceID, 
FromTIme, 
ToTime
So the logic is for each recurrence we will create a entry in table recurrence and will store the details accordingly 
Let me know if there is any flaw in this or a better design to achieve this .
Regards,
Rajesh

Answer 1

I'd do it something like this...
These would be my tables...
CREATE TABLE Appointments (
AppointmentID INT NOT NULL IDENTITY(1,1) Primary Key,
DoctorID INT NOT NULL,
PatientID INT NOT NULL,
AppointmentTypeID INT NOT NULL,
StartDateTime DATETIME NOT NULL,
DurationUnits INT NOT NULL, -- Let's say 15 min blocks...
Frequency VarChar(10) NOT NULL CHECK (Frequency IN ('Daily','Weekly','Monthly','Quartly','Annually')),
NumOfOccurrences INT NOT NULL)
CREATE TABLE Schedules ( AppointmentID INT NOT NULL,
DoctorID INT NOT NULL,
PatientID INT NOT NULL,
BegDateTime DATETIME NOT NULL,
EndDateTime DATETIME NOT NULL)
Then I'd create a stored procedure similar to the following (not I didn't code this as a stored proc so that it would be easier to test)
I've added in-line comments to make it easier to understand...
IF OBJECT_ID ('tempdb..#TempAppt') IS NOT NULL DROP TABLE #TempAppt
CREATE TABLE #TempAppt (
AppointmentID INT NOT NULL Primary Key,
DoctorID INT NOT NULL,
PatientID INT NOT NULL,
AppointmentTypeID INT NOT NULL,
StartDateTime DATETIME NOT NULL,
DurationUnits INT NOT NULL, -- Let's say 15 min blocks...
Frequency VarChar(10) NOT NULL CHECK (Frequency IN ('Daily','Weekly','Monthly','Quartly','Annually')),
NumOfOccurrences INT NOT NULL)
IF OBJECT_ID ('tempdb..#TempSched') IS NOT NULL DROP TABLE #TempSched
CREATE TABLE #TempSched (
DoctorID INT NOT NULL,
PatientID INT NOT NULL,
BegDateTime DATETIME NOT NULL,
EndDateTime DATETIME NOT NULL)
IF OBJECT_ID ('tempdb..#edt') IS NOT NULL DROP TABLE #edt
CREATE TABLE #edt (edt DATETIME)
-- This is the appointment data that you want to add to the database
INSERT INTO #TempAppt VALUES (1,5,5,5,'20120703 17:15:00',3,'Weekly',20)
--Declare the necessary variables andset their values
DECLARE @aid INT, @did INT, @pid INT, @sdt DATETIME, @f CHAR(2), @du INT, @edt DATETIME, @noc INT, @sql VARCHAR(MAX)
SELECT TOP 1
@aid = AppointmentID,
@did = DoctorID,
@pid = PatientID,
@sdt = StartDateTime,
@du = DurationUnits * 15, -- 15 mins per unit
@f = CASE
WHEN Frequency = 'Daily' THEN 'dd'
WHEN Frequency = 'Weekly' THEN 'wk'
WHEN Frequency = 'Monthly' THEN 'mm'
WHEN Frequency = 'Quartly' THEN 'qq'
WHEN Frequency = 'Annually' THEN 'yy'
END,
@noc = NumOfOccurrences
FROM #TempAppt
ORDER BY AppointmentID
-- A little dynamic SQL allows to dynamically create a DATADD function
SET @sql = 'INSERT INTO #edt VALUES (DATEADD(' +@f + ', ' + CAST(@noc AS VARCHAR(5)) + ', ''' + CONVERT(VARCHAR(30), @sdt, 121)+ '''))'
EXEC (@sql)
--select @sql
SELECT @edt = edt FROM #edt
UPDATE #edt SET edt = @sdt
-- Creats a loop that creates the seporate schedule occurances required by the "appointment" data
WHILE @sdt < @edt
BEGIN
INSERT INTO #TempSched VALUES (@did, @pid, @sdt, DATEADD(mi, @du, @sdt))
SET @sql = 'UPDATE #edt SET edt = (DATEADD(' +@f + ', 1, ''' + CONVERT(VARCHAR(30), (SELECT edt FROM #edt), 121)+ '''))'
EXEC(@sql)
SELECT @sdt = edt FROM #edt
END
-- Checks to seeis the newly created schedul conflicts with any pre-existing schedules.
-- If there is a conflict a warning will be displayed and the new data will not be added to the physical tables.
-- If there is no conflict exists, both the Appointments and Schedules tables will be updated.
IF EXISTS (
SELECT 1
FROM Schedules s
INNER JOIN #TempSched ts
ON s.DoctorID = ts.DoctorID
AND (ts.BegDateTime BETWEEN s.BegDateTime AND s.EndDateTime OR
ts.EndDateTime BETWEEN s.BegDateTime AND s.EndDateTime))
BEGIN
SELECT 'There is a conflict with a pre-existing schedule for the doctor'
END
ELSE
IF EXISTS (
SELECT 1
FROM Schedules s
INNER JOIN #TempSched ts
ON s.PatientID = ts.PatientID
AND (ts.BegDateTime BETWEEN s.BegDateTime AND s.EndDateTime OR
ts.EndDateTime BETWEEN s.BegDateTime AND s.EndDateTime))
BEGIN
SELECT 'There is a conflict with a pre-existing schedule for the patient'
END
ELSE
BEGIN
INSERT INTO Appointments (DoctorID, PatientID, AppointmentTypeID, StartDateTime, DurationUnits, Frequency, NumOfOccurrences)
SELECT DoctorID, PatientID, AppointmentTypeID, StartDateTime, DurationUnits, Frequency, NumOfOccurances
FROM #TempAppt
INSERT INTO Schedules ( AppointmentID, DoctorID, PatientID, BegDateTime, EndDateTime)
SELECT
(SELECT MAX(AppointmentID) FROM Appointments WHERE DoctorID = @did AND PatientID = @pid) AS AppointmentID,
DoctorID, PatientID, BegDateTime, EndDateTime
FROM #TempSched
SELECT * FROM Appointments WHERE AppointmentID = @aid
SELECT * FROM Schedules WHERE AppointmentID = @aid
END
Basically it simply takes the appointment info, throws into a temp table, creates a schedule based on that info, validates the schedule based on existing schedules to avoid conflicts.
If there is a conflict you get a warning. If not the appointment gets added along with the schedule.
Once the schedule is created it's a simple matter to go in and manually edit individual occurrences.
If you want to change and entire series, simply delete everything WHERE AppointmentID = ??? AND BegDateTime > CURRENT_TIMESTAMP and create a new appointment.
HTH,
Jason
Jason Long