On-click on ALV sum line to raise an event

Question

Hello, ladies and gentlemen,
Happy New Year first of all.
I have a following problem: I have an ALV grid and in each line I have an icon, which one can on-click and something happens. That works fine. But now I was challenged to add a sum line which should support the same on-click event, but should process the data of all lines that belong to this SUM group in one batch.
Of course I can put in the "manual sum lines" - define groups that will support these sum lines and then add extra lines into the grid data. Unfortunatelly there is no way of telling which lines will belong to which group. I need the ALV standard summing so any user can define his own groups.
Has anybody ever tried such thing? I am using cl_gui_alv_grid OO ALV.
Thanks for any input,
cheers Otto

Answer 1

Hi Otto.
You can check the logic below. Please try to disable the sort functionality as done below in the ALV because the subtotals returned by the method get_subtotals is always sorted in ascending order.
report  z335_alv_sel.
class lcl definition deferred.
type-pools: slis.
types:begin of t_data,
      werks type werks_d,
      labst type mard-labst,
      end of t_data.
data :i_exclude type ui_functions,
      i_fcat type slis_t_fieldcat_alv ,
      i_sort type lvc_t_sort,
      i_data type table of t_data,
      i_cat type lvc_t_fcat,
      wa_sort like line of i_sort,
      wa_exclude type ui_func,
      wa type t_data,
      wa_cat type lvc_s_fcat,
      cont type ref to cl_gui_custom_container,
      grid  type ref to cl_gui_alv_grid,
      receiver type ref to lcl.
class lcl definition.
  public section.
    methods handle_click for event double_click of
               cl_gui_alv_grid importing e_row
                                         e_column.
endclass.                    "lcl DEFINITION
class lcl implementation.
  method handle_click.
    data:val(10) type n,
         it type ref to data.
    field-symbols: <ft_tab> type standard table,
                   <fs_tab> type any,
                   <ff_field> type any.
    if e_row+0(1) = 'S'.  "Subtotal
      val = e_row+23(10).
      call method grid->get_subtotals
          importing
            ep_collect01 = it.
      assign it->* to <ft_tab>.
      read table <ft_tab> assigning <fs_tab> index val.
      if sy-subrc = 0.
        assign component 1 of structure <fs_tab> to <ff_field>.
        if <ff_field> is assigned.
          loop at i_data into wa where werks = <ff_field>.
            "Process your block Here
          endloop.
        endif.
      endif.
    endif.
  endmethod.                    "handle_click
endclass.                    "lcl IMPLEMENTATION
start-of-selection.
  call screen 100.
module fill_data output.
  select werks labst from mard
         into corresponding fields of table i_data
         up to 1000 rows where labst > 0.
  if sy-subrc = 0.
    wa_cat-fieldname = 'WERKS'.
    append wa_cat to i_cat.
    clear wa_cat.
    wa_cat-fieldname = 'LABST'.
    wa_cat-do_sum = 'X'.
    append wa_cat to i_cat.
    clear wa_cat.
    wa_sort-fieldname = 'WERKS'.
    wa_sort-subtot = 'X'.
    wa_sort-group = 'X'.
    wa_sort-up = 'X'.
    append wa_sort to i_sort.
    wa_exclude = cl_gui_alv_grid=>mc_fc_sort .
    append wa_exclude to i_exclude.
    wa_exclude = cl_gui_alv_grid=>mc_fc_sort_asc .
    append wa_exclude to i_exclude.
    wa_exclude = cl_gui_alv_grid=>mc_fc_sort_dsc .
    append wa_exclude to i_exclude.
  endif.
endmodule.                 " fill_data  OUTPUT
module display output.
  if cont is initial .
    create object cont
      exporting
        container_name = 'CONT1'.
    create object grid
      exporting
        i_parent = cont.
    call method grid->set_table_for_first_display
      exporting
      it_toolbar_excluding = i_exclude
      changing
        it_outtab       = i_data[]
        it_sort         = i_sort[]
        it_fieldcatalog = i_cat[].
    create object receiver.
    set handler receiver->handle_click  for grid.
  endif.
endmodule.                    "DISPLAY OUTPUT