Pages '09: Can't use AppleScript for selected text inside tables?

Question

When I run get selection on selected text in a Pages document, I get something like this:
<pre>text from character 1 to character 4 of body text of document id 9943974 of application "Pages"</pre>
When I run get selection on selected text inside a table cell in a table in a Pages document, I get something like this:
<pre>text from character 1 to character 4 of some table of document id 3539679 of application "Pages"</pre>
When I run get selection on selected text inside a table cell in ANOTHER table in the same Pages document, I get the exact same thing. It still says "some" table. So there is no way to distinguish between tables if there are more than one table in the same Pages document.
Am I correct in understanding that this means that most AppleScript commands for manipulating text are unusable inside table cells?
For example, it seems impossible to get the properties of the selection when the selection is selected text inside "some" table. So it's impossible do anything about text styles, etc.
Is AppleScript support in Pages ’09 really that limited, or am I missing something?

Answer 1

The first script below should return the character style of any selection made in Pages ’09, whereas the second script should apply the "XXX" character style to any selection:
--BEGINNING OF SCRIPT 1
tell application "Pages"
activate
tell application "System Events" to tell process "Pages"
-- Show the format bar:
if not (pop up button 1 of window 1 exists) then
click menu item "Show Format Bar" of menu 1 of menu bar item "View" of menu bar 1
end if
-- Show the styles drawer and character styles:
if menu item "Show Styles Drawer" of menu 1 of menu bar item "View" of menu bar 1 exists then
keystroke "t" using {shift down, command down}
end if
tell front window
tell checkbox 1 of group 1 of drawer 1 -- “Show or hide character styles.” checkbox
repeat until it exists
delay 0.1 -- wait until the styles drawer is open
end repeat
if description is "show character style" then click
end tell
-- Get the row index (although it is not a property) of the character style:
tell menu button 2 -- “Choose a character style.” menu button
click
set k to 0
repeat
set k to k + 1
if value of attribute "AXMenuItemMarkChar" of menu item k of menu 1 exists then exit repeat
end repeat
keystroke return -- hide the menu
end tell
-- Get the character style name:
if k > 1 then set k to k + 1
value of static text 1 of row k of outline 1 of scroll area 2 of splitter group 1 of group 1 of drawer 1
end tell
end tell
end tell
--END OF SCRIPT 1
--BEGINNING OF SCRIPT 2
set myStyle to "XXX" -- the name of the character style you want to apply
tell application "Pages"
activate
tell application "System Events" to tell process "Pages"
-- Show the format bar:
if not (pop up button 1 of window 1 exists) then
click menu item "Show Format Bar" of menu 1 of menu bar item "View" of menu bar 1
end if
-- Show the styles drawer and character styles:
if menu item "Show Styles Drawer" of menu 1 of menu bar item "View" of menu bar 1 exists then
keystroke "t" using {shift down, command down}
end if
tell front window
tell checkbox 1 of group 1 of drawer 1 -- “Show or hide character styles.” checkbox
repeat until it exists
delay 0.1 -- wait until the styles drawer is open
end repeat
if description is "show character style" then click
end tell
set characterStyles to value of static text 1 of rows of outline 1 of scroll area 2 of splitter group 1 of group 1 of drawer 1
set k to 0
repeat with thisStyle in the characterStyles
set k to k + 1
if thisStyle as text is myStyle then exit repeat
end repeat
-- Apply the character style:
if k > 1 then set k to k - 1
click menu button 2 -- “Choose a character style.” menu button
click menu item k of menu 1 of menu button 2
end tell
end tell
end tell
--END OF SCRIPT 2
I suppose that +paragraph styles+ should work the same.
I'm beginning to know Pages ’09 a little better now.
Message was edited by: Pierre L. (show format bar)