Performance issue in BI due to direct query on BKPF and BSEG tables

Question

Hi,
We had a requirement that FI document number fieldshould be extracted in BI.
Following code was written which has the correct logic but performance is bad.
It fetched just 100 records in more than 4-5 hrs.
The reason is there was a direct qury written on BSEG and BKPF tables(without WHERE clause).
Is there any way to improve this code like adding GJAHR field  in where clause? I dont want to change the logic.
Following is the code:
WHEN '0CO_OM_CCA_9'." Data Source
    TYPES:BEGIN OF ty_bkpf,
    belnr TYPE bkpf-belnr,
    xblnr TYPE bkpf-xblnr,
    bktxt TYPE bkpf-bktxt,
    awkey TYPE bkpf-awkey,
    bukrs TYPE bkpf-bukrs,
    gjahr TYPE bkpf-gjahr,
    AWTYP TYPE bkpf-AWTYP,
    END OF ty_bkpf.
    TYPES : BEGIN OF ty_bseg1,
    lifnr TYPE bseg-lifnr,
    belnr TYPE bseg-belnr,
    bukrs TYPE bseg-bukrs,
    gjahr TYPE bseg-gjahr,
    END OF ty_bseg1.
    DATA: it_bkpf TYPE STANDARD TABLE OF ty_bkpf,
    wa_bkpf TYPE ty_bkpf,
    it_bseg1 TYPE STANDARD TABLE OF ty_bseg1,
    wa_bseg1 TYPE ty_bseg1,
    l_s_icctrcsta1 TYPE icctrcsta1.
    "Extract structure for Datasoure 0co_om_cca_9.
    DATA: l_awkey TYPE bkpf-awkey.
    DATA: l_gjahr1 TYPE gjahr.
    DATA: len TYPE i,
    l_cnt TYPE i.
    l_cnt = 10.
    tables : covp.
    data : ref_no(20).
    SELECT lifnr
    belnr
    bukrs
    gjahr
    FROM bseg
    INTO TABLE it_bseg1.
    DELETE ADJACENT DUPLICATES FROM it_bseg1 COMPARING belnr gjahr .
    SELECT belnr
    xblnr
    bktxt
    awkey
    bukrs
    gjahr
    AWTYP
    FROM bkpf
    INTO TABLE it_bkpf.
    IF sy-subrc EQ 0.
      CLEAR: l_s_icctrcsta1,
      wa_bkpf,
      l_awkey,
      wa_bseg1.
      LOOP AT c_t_data INTO l_s_icctrcsta1.
        MOVE l_s_icctrcsta1-fiscper(4) TO l_gjahr1.
      select single AWORG AWTYP INTO CORRESPONDING FIELDS OF COVP FROM COVP
      WHERE belnr = l_s_icctrcsta1-belnr.
      if sy-subrc = 0.
          if COVP-AWORG is initial.
       concatenate l_s_icctrcsta1-refbn '%' into ref_no.
              READ TABLE it_bkpf INTO wa_bkpf WITH KEY awkey(10) =
              l_s_icctrcsta1-refbn
              awtyp = COVP-AWTYP
              gjahr = l_gjahr1.
        IF sy-subrc EQ 0.
          MOVE wa_bkpf-belnr TO l_s_icctrcsta1-zzbelnr.
          MOVE wa_bkpf-xblnr TO l_s_icctrcsta1-zzxblnr.
          MOVE wa_bkpf-bktxt TO l_s_icctrcsta1-zzbktxt.
          MODIFY c_t_data FROM l_s_icctrcsta1.
          READ TABLE it_bseg1 INTO wa_bseg1
          WITH KEY
          belnr = wa_bkpf-belnr
          bukrs = wa_bkpf-bukrs
          gjahr = wa_bkpf-gjahr.
          IF sy-subrc EQ 0.
            MOVE wa_bseg1-lifnr TO l_s_icctrcsta1-lifnr.
            MODIFY c_t_data FROM l_s_icctrcsta1.
            CLEAR: l_s_icctrcsta1,
            wa_bseg1,
            l_gjahr1.
          ENDIF.
        ENDIF.
            ELSE. " IF AWORG IS NOT BLANK -
            concatenate l_s_icctrcsta1-refbn COVP-AWORG into ref_no.
            READ TABLE it_bkpf INTO wa_bkpf WITH KEY awkey(20) =
            ref_no
            awtyp = COVP-AWTYP
            gjahr = l_gjahr1.
        IF sy-subrc EQ 0.
          MOVE wa_bkpf-belnr TO l_s_icctrcsta1-zzbelnr.
          MOVE wa_bkpf-xblnr TO l_s_icctrcsta1-zzxblnr.
          MOVE wa_bkpf-bktxt TO l_s_icctrcsta1-zzbktxt.
          MODIFY c_t_data FROM l_s_icctrcsta1.
          READ TABLE it_bseg1 INTO wa_bseg1
          WITH KEY
          belnr = wa_bkpf-belnr
          bukrs = wa_bkpf-bukrs
          gjahr = wa_bkpf-gjahr.
          IF sy-subrc EQ 0.
            MOVE wa_bseg1-lifnr TO l_s_icctrcsta1-lifnr.
            MODIFY c_t_data FROM l_s_icctrcsta1.
            CLEAR: l_s_icctrcsta1,
            wa_bseg1,
            l_gjahr1.
          ENDIF.
        ENDIF.
           endif.
      endif.
        CLEAR: l_s_icctrcsta1.
        CLEAR: COVP, REF_NO.
      ENDLOOP.
    ENDIF.

Answer 1

Hello Amruta,
I was just looking at your coding:
LOOP AT c_t_data INTO l_s_icctrcsta1.
MOVE l_s_icctrcsta1-fiscper(4) TO l_gjahr1.
select single AWORG AWTYP INTO CORRESPONDING FIELDS OF COVP FROM COVP
WHERE belnr = l_s_icctrcsta1-belnr.
if sy-subrc = 0.
if COVP-AWORG is initial.
concatenate l_s_icctrcsta1-refbn '%' into ref_no.
READ TABLE it_bkpf INTO wa_bkpf WITH KEY awkey(10) =
l_s_icctrcsta1-refbn
awtyp = COVP-AWTYP
gjahr = l_gjahr1.
Here you are interested in those BKPF records that are related to the contents of c_t_data internal table.
I guess that this table does not contain millions of entries. Am I right?
If yes, the the first step would be to pre-select COVP entries:
select BELNR AWORG AWTYP into lt_covp from COVP
for all entries in c_t_data
where belnr = c_t_data-belnr.
sort lt_covp by belnr.
Once having this data ready, you build an internal table for BKPF selection:
LOOP AT c_t_data INTO l_s_icctrcsta1.
  clear ls_bkpf_sel.
  ls_bkpf_sel-awkey(10) = l_s_icctrcsta1-refbn.
  read table lt_covp with key belnr = l_s_icctrcsta1-belnr binary search.
  if sy-subrc = 0.
    ls_bkpf_sel-awtyp = lt_covp-awtyp.
  endif.
  ls_bkpf_sel-gjahr = l_s_icctrcsta1-fiscper(4).
  insert ls_bkpf_sel into table lt_bkpf_sel.
ENDLOOP.
Now you have all necessary info to read BKPF:
SELECT
belnr
xblnr
bktxt
awkey
bukrs
gjahr
AWTYP
FROM bkpf
INTO TABLE it_bkpf
for all entries in lt_bkpf_sel
WHERE
  awkey = lt_bkpf_sel-awkey and
  awtyp = lt_bkpf_sel-awtype and
  gjahr = lt_bkpf_sel-gjahr.
Then you can access BSEG with the bukrs, belnr and gjahr from the selected BKPF entries. This will be fast.
Moreover I would even try to make a join on DB level. But first try this solution.
Regards,
  Yuri