Please help me debug this program unit!!!!!

Question

dear sir,
i tried diligently to find and to debug this tiny program unit,although my observation to the coding rules of the packages ,compilation error still occur.
therefore,kindly i'm asking you sir to learn me how to correct it.
thank you.
create or replace package test_pack is
type emp_table_type is table of emp.sal%type
index by binary_integer;
emp_list emp_table_type;
function test_sal
(v_sal in emp.sal%type)
return emp_table_type;
end test_pack;
create or replace package body test_pack is
temp emp.sal%type;
cursor emp_cursor is
select sal from emp;
i number :=1;
j number :=1;
function test_sal
(v_sal in emp.sal%type)
return emp_table_type
is
open emp_cursor;
loop
fetch emp_cursor into temp;
if temp < v_sal then
emp_list(i):=temp;
bms_output.put_line('rowcount i='||emp_cursor%rowcount);
dbms_output.put_line('iterator i='||i);
i:=i+1;
else
dbms_output.put_line('rowcount j='||emp_cursor%rowcount);
dbms_output.put_line('iterator j='||j);
j:=j+1;
end if;
if emp_cursor%notfound then
dbms_output.put_line('cursor closed...');
close emp_cursor;
return emp_list;
exit;
end if;
end loop;
end test_pack;

Answer 1

You can use "show err" to show the errors after compilation errors occur:
SQL> create or replace package test_pack is
  2    type emp_table_type is table of emp.sal%type index by binary_integer;
  3    emp_list emp_table_type;
  4    function test_sal(v_sal in emp.sal%type) return emp_table_type;
  5  end test_pack;
  6  /
Package is aangemaakt.
SQL> create or replace package body test_pack is
  2    temp emp.sal%type;
  3    cursor emp_cursor is
  4    select sal from emp;
  5    i number :=1;
  6    j number :=1;
  7
  8    function test_sal
  9    (v_sal in emp.sal%type)
10    return emp_table_type
11    is
12      open emp_cursor;
13      loop
14        fetch emp_cursor into temp;
15        if temp < v_sal then
16          emp_list(i):=temp;
17          bms_output.put_line('rowcount i='||emp_cursor%rowcount);
18          dbms_output.put_line('iterator i='||i);
19          i:=i+1;
20        else
21          dbms_output.put_line('rowcount j='||emp_cursor%rowcount);
22          dbms_output.put_line('iterator j='||j);
23          j:=j+1;
24        end if;
25        if emp_cursor%notfound then
26          dbms_output.put_line('cursor closed...');
27          close emp_cursor;
28          return emp_list;
29          exit;
30        end if;
31      end loop;
32  end test_pack;
33  /
Waarschuwing: package-body is aangemaakt met compilatiefouten.
SQL> show err
Fouten voor PACKAGE BODY TEST_PACK:
LINE/COL ERROR
14/7     PLS-00103: Symbool "FETCH" aangetroffen terwijl een van de
         volgende werd verwacht:
         constant exception <een ID>
         <een scheidingsteken-ID tussen dubbele aanhalingstekens>
         table LONG_ double ref char time timestamp interval date
         binary national character nchar
32/5     PLS-00103: Symbool "TEST_PACK" aangetroffen terwijl een van de
         volgende werd verwacht:
         ;To make your program compile, add a begin and end and fix the typo (in bold):
SQL> create or replace package body test_pack is
  2    temp emp.sal%type;
  3    cursor emp_cursor is
  4    select sal from emp;
  5    i number :=1;
  6    j number :=1;
  7
  8    function test_sal
  9    (v_sal in emp.sal%type)
10    return emp_table_type
11    is
12    begin
13      open emp_cursor;
14      loop
15        fetch emp_cursor into temp;
16        if temp < v_sal then
17          emp_list(i):=temp;
18          dbms_output.put_line('rowcount i='||emp_cursor%rowcount);
19          dbms_output.put_line('iterator i='||i);
20          i:=i+1;
21        else
22          dbms_output.put_line('rowcount j='||emp_cursor%rowcount);
23          dbms_output.put_line('iterator j='||j);
24          j:=j+1;
25        end if;
26        if emp_cursor%notfound then
27          dbms_output.put_line('cursor closed...');
28          close emp_cursor;
29          return emp_list;
30          exit;
31        end if;
32      end loop;
33    end;
34  end test_pack;
35  /
Package-body is aangemaakt.
SQL> declare
  2    t test_pack.emp_table_type;
  3  begin
  4    t := test_pack.test_sal(2000);
  5    for i in 1..t.count
  6    loop
  7      dbms_output.put_line(t(i));
  8    end loop;
  9  end;
10  /
rowcount i=1
iterator i=1
rowcount i=2
iterator i=2
rowcount i=3
iterator i=3
rowcount j=4
iterator j=1
rowcount i=5
iterator i=4
rowcount j=6
iterator j=2
rowcount j=7
iterator j=3
rowcount j=8
iterator j=4
rowcount j=9
iterator j=5
rowcount i=10
iterator i=5
rowcount i=11
iterator i=6
rowcount i=12
iterator i=7
rowcount j=13
iterator j=6
rowcount i=14
iterator i=8
rowcount i=14
iterator i=9
cursor closed...
800
1600
1250
1250
1500
1100
950
1300
1300
PL/SQL-procedure is geslaagd.To fix the bug of the last iteration and put the variables in the sections they belong:
SQL> create or replace package test_pack is
  2    type emp_table_type is table of emp.sal%type index by binary_integer;
  3    function test_sal(v_sal in emp.sal%type) return emp_table_type;
  4  end test_pack;
  5  /
Package is aangemaakt.
SQL> create or replace package body test_pack
  2  is
  3    function test_sal(v_sal in emp.sal%type) return emp_table_type
  4    is
  5      emp_list emp_table_type;
  6      temp emp.sal%type;
  7      cursor emp_cursor is select sal from emp;
  8      i number :=1;
  9      j number :=1;
10    begin
11      open emp_cursor;
12      loop
13        fetch emp_cursor into temp;
14        if emp_cursor%notfound then
15          dbms_output.put_line('cursor closed...');
16          exit;
17        end if;
18        if temp < v_sal then
19          emp_list(i):=temp;
20          dbms_output.put_line('rowcount i='||emp_cursor%rowcount);
21          dbms_output.put_line('iterator i='||i);
22          i:=i+1;
23        else
24          dbms_output.put_line('rowcount j='||emp_cursor%rowcount);
25          dbms_output.put_line('iterator j='||j);
26          j:=j+1;
27        end if;
28      end loop;
29      close emp_cursor;
30      return emp_list;
31    end;
32  end test_pack;
33  /
Package-body is aangemaakt.
SQL> declare
  2    t test_pack.emp_table_type;
  3  begin
  4    t := test_pack.test_sal(2000);
  5    for i in 1..t.count
  6    loop
  7      dbms_output.put_line(t(i));
  8    end loop;
  9  end;
10  /
rowcount i=1
iterator i=1
rowcount i=2
iterator i=2
rowcount i=3
iterator i=3
rowcount j=4
iterator j=1
rowcount i=5
iterator i=4
rowcount j=6
iterator j=2
rowcount j=7
iterator j=3
rowcount j=8
iterator j=4
rowcount j=9
iterator j=5
rowcount i=10
iterator i=5
rowcount i=11
iterator i=6
rowcount i=12
iterator i=7
rowcount j=13
iterator j=6
rowcount i=14
iterator i=8
cursor closed...
800
1600
1250
1250
1500
1100
950
1300
PL/SQL-procedure is geslaagd.To be really efficient and not care about looping, using counters and dbms_output, and assuming the emp table won't ever be a big table (else use the LIMIT clause):
SQL> create or replace package body test_pack
  2  is
  3    function test_sal(v_sal in emp.sal%type) return emp_table_type
  4    is
  5      emp_list emp_table_type;
  6    begin
  7      select sal bulk collect into emp_list
  8        from emp
  9       where sal < v_sal
10      ;
11      return emp_list;
12    end;
13  end;
14  /
Package-body is aangemaakt.
SQL> declare
  2    t test_pack.emp_table_type;
  3  begin
  4    t := test_pack.test_sal(2000);
  5    for i in 1..t.count
  6    loop
  7      dbms_output.put_line(t(i));
  8    end loop;
  9  end;
10  /
800
1600
1250
1250
1500
1100
950
1300
PL/SQL-procedure is geslaagd.Hope it helps.
Regards,
Rob.