Plsql object type polymorphism

Question

Hi everyone.
Is adhoc polymorphism possible in pl/sql using Oracle's object types? Here is some sample code that I tried on an Oracle 10.2.0.3 64-bit database running on Solaris.
Connected.
09:58:58 SQL> create type root_ty as object (
09:59:03   2    a1     varchar2(32 char)
09:59:03   3  ) not final
09:59:03   4  /
Type created.
Elapsed: 00:00:00.17
09:59:05 SQL> create type sub_ty under root_ty (
09:59:10   2    a2     varchar2(32 char)
09:59:10   3  , constructor function sub_ty(str in varchar2) return self as resul
09:59:10   4  , member procedure display_a2
09:59:10   5  ) final
09:59:10   6  /
Type created.
Elapsed: 00:00:00.06
09:59:12 SQL> create or replace type body sub_ty is
09:59:18   2    constructor function sub_ty(str in varchar2)
09:59:18   3      return self as result
09:59:18   4    is
09:59:18   5    begin
09:59:18   6      self.a2 := str;
09:59:18   7     
09:59:18   8      return;
09:59:18   9    end;
09:59:18  10   
09:59:18  11    member procedure display_a2
09:59:18  12    is
09:59:18  13    begin
09:59:18  14      dbms_output.put_line('a2 value is .... '||a2);
09:59:18  15    end;
09:59:18  16  end;
09:59:18  17  /
Type body created.
Elapsed: 00:00:00.04
09:59:20 SQL> set serveroutput on
10:00:31 SQL> declare
10:00:35   2    l_ty    root_ty;
10:00:35   3  begin
10:00:35   4    l_ty := new sub_ty('Woot!');
10:00:35   5   
10:00:35   6    l_ty.display_a2();
10:00:35   7  end;
10:00:35   8  /
  l_ty.display_a2();
ERROR at line 6:
ORA-06550: line 6, column 8:
PLS-00302: component 'DISPLAY_A2' must be declared
ORA-06550: line 6, column 3:
PL/SQL: Statement ignored
Elapsed: 00:00:00.06
10:00:37 SQL> declare
10:00:53   2    l_ty    root_ty;
10:00:53   3  begin
10:00:53   4    l_ty := new sub_ty('Woot!');
10:00:53   5   
10:00:53   6  --  l_ty.display_a2();
10:00:53   7  end;
10:00:53   8  /
PL/SQL procedure successfully completed.
Elapsed: 00:00:00.01
10:00:53 SQL> declare
10:01:30   2    l_ty    sub_ty;
10:01:30   3  begin
10:01:30   4    l_ty := new sub_ty('Woot!');
10:01:30   5   
10:01:30   6    l_ty.display_a2();
10:01:30   7  end;
10:01:30   8  /
a2 value is .... Woot!
PL/SQL procedure successfully completed.Certainly seems like this should be possible ... Am I missing something simple?
Thanks for any input.
- KR

Answer 1

Here is an example of what polymorphism is supposed to do:
SQL> create type bird as object
  2  (name varchar2 (30)
  3  , member function fly return varchar2
  4  , member function make_a_noise return varchar2)
  5  not final
  6  /
Type created.
SQL>
SQL> create type birds_nt as table of bird;
  2  /
Type created.
SQL>
SQL>
SQL> create or replace type body bird as
  2
  3      member function fly return varchar2
  4      is
  5      begin
  6          return 'my name is '||self.name;
  7      end;
  8
  9      member function make_a_noise return varchar2
10      is
11      begin
12          return 'generic twitter';
13      end;
14
15  end;
16  /
Type body created.
SQL>
SQL>
SQL> create type duck under bird (
  2  overriding member function make_a_noise return varchar2
  3  , member procedure waddle
  4  );
  5  /
Type created.
SQL>
SQL> create or replace type body duck as
  2
  3
  4      overriding member function make_a_noise return varchar2
  5      is
  6      begin
  7          return 'quack!';
  8      end;
  9
10      member procedure waddle
11      is
12      begin
13          null;
14      end;
15
16
17  end;
18  /
Type body created.
SQL>
SQL>
SQL>
SQL> create type chicken under bird (
  2  overriding member function make_a_noise return varchar2
  3  , member procedure peck
  4  )
  5  not final;
  6  /
Type created.
SQL>
SQL> create or replace type body chicken as
  2
  3
  4      overriding member function make_a_noise return varchar2
  5      is
  6      begin
  7          return 'cluck!';
  8      end;
  9
10      member procedure peck
11      is
12      begin
13          null;
14      end;
15
16
17  end;
18  /
Type body created.
SQL>
SQL> create type canary under bird (
  2  overriding member function make_a_noise return varchar2
  3  );
  4  /
Type created.
SQL>
SQL> create or replace type body canary as
  2
  3
  4      overriding member function make_a_noise return varchar2
  5      is
  6      begin
  7          return 'I taught I taw a puddy tat!!!';
  8      end;
  9
10
11  end;
12  /
Type body created.
SQL>
SQL> create type rooster  under chicken (
  2  overriding member function make_a_noise return varchar2
  3  )
  4  ;
  5  /
Type created.
SQL>
SQL> create or replace type body rooster as
  2
  3
  4      overriding member function make_a_noise return varchar2
  5      is
  6      begin
  7          return 'That''s a joke... I say, that''s a joke, son.';
  8      end;
  9
10
11  end;
12  /
Type body created.
SQL>
SQL>
SQL>
SQL>
SQL> declare
  2      my_aviary birds_nt := birds_nt();
  3  begin
  4      my_aviary.extend(5);
  5      my_aviary(1) := duck('Donald');
  6      my_aviary(2) := chicken('Chicken Little');
  7      my_aviary(3) := canary('Tweetie Pie');
  8      my_aviary(4) := rooster('Foghorn Leghorn');
  9      my_aviary(5) := bird('?');
10      for idx in my_aviary.first()..my_aviary.last()
11      loop
12          dbms_output.put_line( my_aviary(idx).fly() );
13          dbms_output.put_line( my_aviary(idx).make_a_noise() );
14      end loop;
15  end;
16  /
my name is Donald
quack!
my name is Chicken Little
cluck!
my name is Tweetie Pie
I taught I taw a puddy tat!!!
my name is Foghorn Leghorn
That's a joke... I say, that's a joke, son.
my name is ?
generic twitter
PL/SQL procedure successfully completed.
SQL>Now, in that loop woudl it make sense to execute a peck() on all of those entries? Nope. Furthermore as far as I can tell it is not possible to find out what sub-type an object is from with PL/SQL, so you couldn't even use Padders's TREAT ploy.
So: if you want to do something generic use a super-type. If you want to do something specific use a sub-type.
Cheers, APC
blog: http://radiofreetooting.blogspot.com