Printing all error messages in the out put report

Question

Hi all,
I have MATNR and WERKS data in final internal table now my requirement is ineed to print all the error messages for all the materials (where sy-subrc ne 0) in the out put report. how can i do it for multiple error records will anybody tell me with coding
The Requirement is like bellow:
Take material number(s) (MARC-MATNR) from selection screen then check to see if any plants have that material setup as QM active (MARC-QMATV).  If no, then issue message on report.
Thanks,

Answer 1

Hi Mythili,
Hope the attached code helps you...
TABLES marc.
TYPE-POOLS: slis.
TYPES : BEGIN OF g_ty_msg,
        type LIKE sy-msgty,
        msg(120),
       END OF g_ty_msg.
TYPES: BEGIN OF g_ty_marc,
        matnr TYPE matnr,
        werks TYPE werks_d,
        qmatv TYPE qmatv,
      END OF g_ty_marc.
DATA: g_t_msg TYPE TABLE OF g_ty_msg,
      g_r_msg TYPE g_ty_msg.
DATA: g_t_marc TYPE TABLE OF g_ty_marc.
FIELD-SYMBOLS <fs_marc> TYPE g_ty_marc.
SELECT-OPTIONS: s_matnr FOR marc-matnr,
                s_werks FOR marc-werks.
START-OF-SELECTION.
  SELECT matnr werks qmatv FROM marc
    INTO TABLE g_t_marc
    WHERE matnr IN s_matnr AND
          werks IN s_werks.
  IF g_t_marc IS NOT INITIAL.
    LOOP AT g_t_marc ASSIGNING <fs_marc>.
      IF <fs_marc>-qmatv IS INITIAL.
        g_r_msg-type = 'E'.
        CONCATENATE <fs_marc>-matnr <fs_marc>-werks
          INTO g_r_msg-msg SEPARATED BY space.
        APPEND g_r_msg TO g_t_msg.
        CLEAR g_r_msg.
      ENDIF.
    ENDLOOP.
  ENDIF.
END-OF-SELECTION.
  PERFORM display_log.
*&      Form  display_log
      To display error log as an ALV Popup
FORM display_log .
  CONSTANTS: l_c_type(4)    TYPE c VALUE 'TYPE',
             l_c_msg(3)     TYPE c VALUE 'MSG'.
  DATA :  l_t_fieldcat TYPE TABLE OF slis_fieldcat_alv,
          l_r_fieldcat TYPE slis_fieldcat_alv.
  DATA :  l_f_line TYPE i.
  CLEAR l_r_fieldcat.
  l_f_line = l_f_line + 1.
  l_r_fieldcat-col_pos    = l_f_line.
  l_r_fieldcat-fieldname  = l_c_type.
  l_r_fieldcat-seltext_m  = 'Type'.
  APPEND l_r_fieldcat TO l_t_fieldcat.
  CLEAR l_r_fieldcat.
  l_f_line = l_f_line + 1.
  l_r_fieldcat-col_pos = l_f_line.
  l_r_fieldcat-fieldname = l_c_msg.
  l_r_fieldcat-seltext_m = 'Message'.
  l_r_fieldcat-outputlen = 120.
  APPEND l_r_fieldcat TO l_t_fieldcat.
To display the message log as a Popup in the form of ALV List
  CALL FUNCTION 'REUSE_ALV_POPUP_TO_SELECT'
    EXPORTING
      i_title       = 'Message Log'
      i_tabname     = 'G_TY_MSG'
      it_fieldcat   = l_t_fieldcat[]
    TABLES
      t_outtab      = g_t_msg
    EXCEPTIONS
      program_error = 1
      OTHERS        = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
ENDFORM.                    " display_log
Best Regards,
Suresh