Prob in Submit Report via Selection screen.

Question

Hi,
I have to submit a report via selection screen.
The report name is detemined at run time.
This i am able to handle easily as we can use SUBMIT (V_PROG)...
                               WHERE V_PROG contains the name of the report that i get at runtime...
Now the issue :::::::
I have to also populate a select-options on the called report on submit.
usually this is done by :
                                            SUBMIT (V_PROG)
                                            name of select-option in itab...
However in my case the name of the <name of select-option> is also detemined at runtime say PNPPERNR.
Now if i use any variable / field symbol for the name of the select - option (like for the called program), it does not work (the called report does not have the values i populate in ITAB for the particular select-option)
I have also tried Macro but cant find solution...
ANY IDEAS ??

Answer 1

Hi Anuj,
When you are getting the report name in runtime, you can also get the report selection screen information during runtime.
Now how are you going to decide which values you will move to which selection screen variables of which report? If you have a way to determine this, then here is a program that works on that assumption.
REPORT ztest1 .
DATA: i_seltab          TYPE TABLE OF rsparams WITH HEADER LINE,
      i_selections_info TYPE TABLE OF selinfo WITH HEADER LINE.
DATA: v_report LIKE sy-repid,
      v_matnr  LIKE mara-matnr.
PARAMETERS: p_rep1 RADIOBUTTON GROUP rad DEFAULT 'X',
            p_rep2 RADIOBUTTON GROUP rad.
SELECT-OPTIONS: s_matnr FOR v_matnr.
START-OF-SELECTION.
  IF p_rep1 = 'X'.
*-- some criteria to determine the name of the report
    v_report = 'ZTEST2'.
  ELSE.
    v_report = 'ZTEST4'.
  ENDIF.
*-- get the parameters for the report
  CALL FUNCTION 'RS_SELECTIONS_DESCRIPTION'
       EXPORTING
            report              = v_report
       TABLES
            selections_info     = i_selections_info
       EXCEPTIONS
            no_selections       = 1
            report_not_existent = 2
            subroutine_pool     = 3
            OTHERS              = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
  LOOP AT i_selections_info WHERE name = 'S_MATNR'.
*-- some criteria based on which, move the values from this program
*   to the called program
    CLEAR i_seltab.
    i_seltab-selname = i_selections_info-name.
    i_seltab-kind    = i_selections_info-kind.
    i_seltab-sign    = 'I'.
    i_seltab-option  = 'EQ'.
    i_seltab-low     = s_matnr-low.
    i_seltab-high    = s_matnr-high.
    APPEND i_seltab.
  ENDLOOP.
  IF NOT i_seltab[] IS INITIAL.
    SUBMIT (v_report) VIA SELECTION-SCREEN
            WITH SELECTION-TABLE i_seltab .
  ENDIF.
If this works for you, please reward and close the post.
Regards,
Srinivas