Retrieve multiple user's DisplayName values from LDAP server

Question

Hi,
I have a report in answers, which will show the UserIds information pulling from a database table. These users information is stored in the LDAP server and I want to retrieve the DisplayName or FirstName-LastName (if possible) of the userids that I have in the report.
Any pointers on how can I implement that in the repository by using IB, by defining variables etc?
Thanks in advance.
Rajesh Gurram

Answer 1

I created PL/SQL table function to get users from ldap and view based on it (Oracle database).
create or replace
type ldap_users_t as object(
  dn varchar2(200),
  full_name varchar2(200),
  user_name varchar2(200),
  reg_number number,
  email varchar2(200) 
create or replace
TYPE ldap_users_t_ct as table of ldap_users_t;
create or replace
function get_ldap_users return ldap_users_t_ct PIPELINED
is
   out_rec             ldap_users_t := ldap_users_t (null,null,null,null,null);
   retval              PLS_INTEGER;
   ldap_session    DBMS_LDAP.SESSION;
   ldap_attrs       DBMS_LDAP.string_collection;
   ldap_message  DBMS_LDAP.MESSAGE;
   ldap_entry      DBMS_LDAP.MESSAGE;
   ldap_dn          VARCHAR2 (256);
   ldap_attr_name   VARCHAR2 (256);
   i PLS_INTEGER;
   user_name           DBMS_LDAP.string_collection;
   full_name           DBMS_LDAP.string_collection;
   reg_number          DBMS_LDAP.string_collection;
   email               DBMS_LDAP.string_collection;
   ldap_host           VARCHAR2 (256);
   ldap_port           VARCHAR2 (256);
   ldap_user           VARCHAR2 (256);
   ldap_passwd         VARCHAR2 (256);
   ldap_base           VARCHAR2 (256);
BEGIN
   retval := -1;
   ldap_host :=       '********************';
   ldap_port :=       '********************';
   ldap_user :=       '********************';
   ldap_passwd := '********************';
   ldap_base :=   '********************';
   DBMS_LDAP.use_exception := TRUE;
   ldap_session := DBMS_LDAP.init (ldap_host, ldap_port);
   retval := DBMS_LDAP.simple_bind_s (ldap_session, ldap_user, ldap_passwd);
   ldap_attrs (1) := '*';
   retval :=DBMS_LDAP.search_s (ldap_session, ldap_base,DBMS_LDAP.scope_subtree,
          'objectclass=*',ldap_attrs,0,ldap_message);
   ldap_entry := DBMS_LDAP.first_entry (ldap_session, ldap_message);
   WHILE ldap_entry IS NOT NULL
   LOOP      
      ldap_dn := DBMS_LDAP.get_dn (ldap_session, ldap_entry);
      user_name := DBMS_LDAP.get_values (ldap_session, ldap_entry, 'uid');
      full_name := DBMS_LDAP.get_values (ldap_session, ldap_entry, 'cn');
      reg_number := DBMS_LDAP.get_values (ldap_session, ldap_entry, 'employeeNumber');
      email := DBMS_LDAP.get_values (ldap_session, ldap_entry, 'mail');
      out_rec.dn:=ldap_dn;
      out_rec.user_name:=null;
      out_rec.full_name:=null;
      out_rec.reg_number:=null;
      out_rec.email:=null;
      IF user_name.COUNT > 0
        THEN out_rec.user_name:=user_name(0);
      END IF;
      IF full_name.COUNT > 0
        THEN out_rec.full_name:=full_name(0);
      END IF;
      IF reg_number.COUNT > 0
        THEN out_rec.reg_number:=reg_number(0);
      END IF;
      IF email.COUNT > 0
        THEN out_rec.email:=email(0);
      END IF;
      ldap_entry := DBMS_LDAP.next_entry (ldap_session, ldap_entry);
      pipe row(out_rec);
   END LOOP;
   retval := DBMS_LDAP.msgfree (ldap_message);
   retval := DBMS_LDAP.unbind_s (ldap_session);
END;
create or replace view scr_ldap_users_v as select * from table(get_ldap_users);