Select a number of fields between one field and another

Question

Hello,
Is there any way to make a SELECT to show a number of fields between one field and another,
without writting all the fields one by one ?
For example, I have one table with these fields:
TABLE EMPLOYEE:
ID_EMPLOYEE NAME PHONE CAR AGE MARRIED
and I just want to make a SELECT who shows only fields from NAME to AGE, but i don't want to
write in the SELECT all the fields one by one.
Is this possible?
Thank you very much.
Sorry for my english it's not very good.

Answer 1

Swam wrote:
Hello,
Is there any way to make a SELECT to show a number of fields between one field and another,
without writting all the fields one by one ?
For example, I have one table with these fields:
TABLE EMPLOYEE:
ID_EMPLOYEE NAME PHONE CAR AGE MARRIED
and I just want to make a SELECT who shows only fields from NAME to AGE, but i don't want to
write in the SELECT all the fields one by one.
Is this possible?
Thank you very much.
Sorry for my english it's not very good.If you use the DBMS_SQL package to execute your query you can reference the columns by position rather than name.
One examples of using DBMS_SQL package:
SQL> ed
Wrote file afiedt.buf
  1  DECLARE
  2    cur       PLS_INTEGER := DBMS_SQL.OPEN_CURSOR;
  3    cols      DBMS_SQL.DESC_TAB;
  4    ncols     PLS_INTEGER;
  5    v_min_col NUMBER := 2;
  6    v_max_col NUMBER := 4;
  7    v_val     VARCHAR2(4000);
  8    v_bindval VARCHAR2(4000);
  9    v_ret     NUMBER;
10    d         NUMBER;
11  BEGIN
12    -- Parse the query.
13    DBMS_SQL.PARSE(cur, 'SELECT * FROM emp', DBMS_SQL.NATIVE);
14    -- Retrieve column information
15    DBMS_SQL.DESCRIBE_COLUMNS (cur, ncols, cols);
16    -- Display each of the column names and bind variables too
17    FOR colind IN v_min_col..v_max_col
18    LOOP
19      DBMS_OUTPUT.PUT_LINE ('Column:'||colind||' : '||cols(colind).col_name);
20      DBMS_SQL.DEFINE_COLUMN(cur,colind,v_bindval,4000);
21    END LOOP;
22    -- Display data for those columns
23    d := DBMS_SQL.EXECUTE(cur);
24    LOOP
25      v_ret := DBMS_SQL.FETCH_ROWS(cur);
26      v_val := NULL;
27      EXIT WHEN v_ret = 0;
28      FOR colind in v_min_col..v_max_col
29      LOOP
30        DBMS_SQL.COLUMN_VALUE(cur,colind,v_bindval);
31        v_val := LTRIM(v_val||','||v_bindval,',');
32      END LOOP;
33      DBMS_OUTPUT.PUT_LINE(v_val);
34    END LOOP;
35    DBMS_SQL.CLOSE_CURSOR (cur);
36* END;
SQL> /
Column:2 : ENAME
Column:3 : JOB
Column:4 : MGR
SMITH,CLERK,7902
ALLEN,SALESMAN,7698
WARD,SALESMAN,7698
JONES,MANAGER,7839
MARTIN,SALESMAN,7698
BLAKE,MANAGER,7839
CLARK,MANAGER,7839
SCOTT,ANALYST,7566
KING,PRESIDENT,
TURNER,SALESMAN,7698
ADAMS,CLERK,7788
JAMES,CLERK,7698
FORD,ANALYST,7566
MILLER,CLERK,7782
PL/SQL procedure successfully completed.
SQL>Of course, if you were going to do this properly you would bind the correct datatypes of variables based on the types of the columns (the type information is also available through the describe information)