Trying to send email with contents in the body of the message

Question

Hi,
Has anyone been successful in modifying the RW_EMAIL_NOTIFICATION script in such a way that allows the contents of the email "body" to be sent as a parameter from a calling script? Thanks.
Regards,
David Carr

Answer 1

David,
Here is the solution I use which hopefully will suit your requirements and is a little more elegant than the workarounds for using rwmail.  Oracle has the ability to send SMTP emails once you enable the UTL_SMTP package. 
Log in to Oracle as the SYS user and run the Oracle supplied script to create the UTL_SMTP package - utlsmtp.sql in the Oracle rdbms/admin directory.
Now create a procedure that you can call subsequently in your scripts to send emails using the UTL_SMTP package.  I created this script under the SYSJCS schema as I'm only going to call it from there, but you could create it as SYS and then create a public synonym for it.
I called my procedure send_mail (see below).  The enabling of the UTL_SMTP and the creation of the send_mail procedures are one-offs and don't have to be repeated (unless you want to change something about send_mail).  Just change the name of the mailhost in the procedure to one appropriate for your  company.
NB: I have had to substitute the "at symbol" with *at* otherwise the forum wouldn't accept the post.
CREATE OR REPLACE PROCEDURE send_mail (
pSender    VARCHAR2,
pRecipient VARCHAR2,
pSubject   VARCHAR2,
pMessage   VARCHAR2) IS
mailhost  CONSTANT VARCHAR2(30) := 'yoursmtpcapable.mailserver.corp';
crlf      CONSTANT VARCHAR2(2):= CHR(13) || CHR(10);
mesg      VARCHAR2(1000);
mail_conn utl_smtp.connection;
BEGIN
   mail_conn := utl_smtp.open_connection(mailhost, 25);
   mesg := 'Date: ' ||
        TO_CHAR( SYSDATE, 'dd Mon yy hh24:mi:ss') || crlf ||
           'From: <'|| pSender ||'>' || crlf ||
           'Subject: '|| pSubject || crlf ||
           'To: '||pRecipient || crlf || '' || crlf || pMessage;
   utl_smtp.helo(mail_conn, mailhost);
   utl_smtp.mail(mail_conn, pSender);
   utl_smtp.rcpt(mail_conn, pRecipient);
   utl_smtp.data(mail_conn, mesg);
   utl_smtp.quit(mail_conn);
END send_mail;
Now you can call the send_mail procedure with, e.g.
send_mail(pSender=>'redwood**at**mycompany.com',pRecipient=>'basisteam**at**mycompany.com',pSubject=>'Alert: Redwood job failure',pMessage=>'There has been a job failure that should be addressed a.s.a.p.');
Here is a practical application of this email facility.  I created a trigger for ON_JOB_STATUS_CHANGE called _ERROR and here is the code that is executed.  We store contact details for business users that need to be notified of a job failure in the Comment field of the script definition, so for a failed job we grab that info and email it to a power user dlist which includes 24/7 Ops that will call-out the contacts specified.
Any Comment field that starts with the text CRITICAL_JOB results in an email to the Ops that will perform the call-out, otherwise the email goes to a less critical dlist.
procedure SYSJCS.ON_JOB_STATUS_CHANGE_ERROR (
  p_job_id     in integer
, p_old_status in varchar2
, p_new_status in varchar2
is   
    v_script       varchar2(30);                                   
    v_step_id      varchar2(9);
    v_description  VARCHAR2(80);
    v_comment_text VARCHAR2(4000);
begin
    if p_new_status in ('E', 'O') -- Error or Console
    then
        select script_name, decode(step_id, null,'JOB/CHAIN','STEP')
        into v_script, v_step_id
        from jcs_jobs
        where job_id = p_job_id;                              
        select description, comment_text
        into v_description, v_comment_text     
        from jcs_scripts
        where name = v_script;                              
        if ( SUBSTR(v_comment_text,1,12) = 'CRITICAL_JOB' )
        then    
           send_mail(pSender=>'redwood**at**mycompany.com',
                     pRecipient=>'criticaljobalerts**at**mycompany.com',
                     pSubject=>'CRITICAL ALERT: Job failure in '||v_script||' ('||p_job_id||')',
                     pMessage=>'Job Description: '||v_description||chr(13)||chr(13)||'Operations Team please ensure you contact one of the following people via telephone a.s.a.p.'||chr(13)||chr(13)||'Comments: '||chr(13)||v_comment_text);
        else
           send_mail(pSender=>'redwood**at**mycompany.com',
                     pRecipient=>'basisteam**at**mycompany.com',
                     pSubject=>'Alert: Job failure in '||v_script||' ('||p_job_id||')',
                     pMessage=>'Job Description: '||v_description||chr(13)||'Comments: '||chr(13)||v_comment_text);
        end if;
    end if;
end;
Hope this was useful.
Regards
Guy