WD ABAP @ Access mime html object

Question

Hello All,
Need help in understanding how do I get the URL of a mime HTML object in WD ABAP application.
I need this URL of the mime object so that I can fire exit plug with this URL at runtime in the applicaiton.
Please assist.
Thanks and Regards,
Samta

Answer 1

Use method CONSTRUCT_MIME_URL of class CL_WDR_UTILITIES. Remember to take the value against E_ABSOLUTE_PATH, as the URL supplied in the method FIRE_PLUG of interface IF_WD_VIEW_CONTROLLER needs absolute URL.
Sample:
DATA: lo_viwcon TYPE REF TO if_wd_view_controller,
         lo_wincon TYPE REF TO if_wd_window_controller,
         lo_aprvwin TYPE REF TO ig_approverequest_wndw.
   DATA: lt_params  TYPE wdr_event_parameter_list,
         ls_param   TYPE wdr_event_parameter.
   DATA: d_cmd TYPE REF TO data,
         d_url TYPE REF TO data.
   FIELD-SYMBOLS: <v_cmd> TYPE ANY,
                  <v_url> TYPE ANY.
   CREATE DATA d_cmd TYPE string.
   CREATE DATA d_url TYPE string.
   ASSIGN d_cmd->* TO <v_cmd>.
   ASSIGN d_url->* TO <v_url>.
   <v_cmd> = 'X'.
   cl_wdr_utilities=>construct_mime_url(
    EXPORTING
       i_component_name = '<COMPONENT_NAME>'
       i_mime_source    = '<MIME_FILE_NAME>'
     IMPORTING
       e_absolute_path  = <v_url> ).
   ls_param-name  = 'CloseWindow'.
   ls_param-value = d_cmd.
   INSERT ls_param INTO TABLE lt_params.
   ls_param-name = 'URL'.
   ls_param-value = d_url.
   INSERT ls_param INTO TABLE lt_params.
   lo_viwcon = wd_this->wd_get_api( ).
   lo_wincon = lo_viwcon->get_embedding_window_ctlr( ).
   lo_wincon->if_wd_view_controller~fire_plug( parameters = lt_params
                                               plug_name  = 'EXIT_PLUG' ).