ADD A line in alv with values

Question

Hi Experts,
When clicking the button 'append row', I want to add a line filled with some values in selection screen.
I work with OO.
need help please.
Mohamed

Answer 1

Hello Mohamed
The logic is the same as before. Search for $MODFIED to detect the changes in the sample report.
However, I do not think that these requirements make any sense because if you re-implement the Copy function you obviously have to re-implement the Paste function (and perhaps Undo function as well), too.
So basically you reinvent the wheel again.
*& Report  ZUS_SDN_ALV_GRID_EDITABLE
*& Thread: ADD A line in alv with values
*& <a class="jive_macro jive_macro_thread" href="" __jive_macro_name="thread" modifiedtitle="true" __default_attr="974654"></a>
REPORT  zus_sdn_alv_grid_editable_1x.
TYPE-POOLS: abap.
DATA:
  gd_okcode        TYPE ui_func,
  gd_repid         TYPE syst-repid,
  gif_adapter      TYPE REF TO if_salv_adapter,
  go_docking       TYPE REF TO cl_gui_docking_container,
  go_grid1         TYPE REF TO cl_gui_alv_grid,
  gt_fcat          TYPE lvc_t_fcat,
  gs_layout        TYPE lvc_s_layo.
DATA:
  gt_outtab        TYPE STANDARD TABLE OF knb1.
*       CLASS lcl_eventhandler DEFINITION
CLASS lcl_eventhandler DEFINITION.
  PUBLIC SECTION.
    CLASS-DATA:
      md_function    TYPE ui_func   READ-ONLY,
      ms_row         TYPE lvc_s_row READ-ONLY,
      ms_outtab      LIKE LINE OF gt_outtab.  "$MODIFIED
    CLASS-METHODS:
      handle_double_click FOR EVENT double_click OF cl_gui_alv_grid
        IMPORTING
          e_row
          e_column
          es_row_no
          sender,
       handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid
         IMPORTING
           e_object
           sender,
       handle_user_command FOR EVENT user_command OF cl_gui_alv_grid
         IMPORTING
           e_ucomm
           sender,
       handle_data_changed FOR EVENT data_changed OF cl_gui_alv_grid
         IMPORTING
          er_data_changed
          e_onf4
          e_onf4_before
          e_onf4_after
          e_ucomm
          sender.
ENDCLASS.                    "lcl_eventhandler DEFINITION
*       CLASS lcl_eventhandler IMPLEMENTATION
CLASS lcl_eventhandler IMPLEMENTATION.
  METHOD handle_double_click.
  ENDMETHOD.                    "handle_double_click
  METHOD handle_toolbar.
    " define local data
    DATA: ls_button   TYPE stb_button.
    " Redefine toolbar button functions in order to be able to
    " handle them in event USER_COMMAND (standard toolbar functions
    " do NOT raise event USER_COMMAND !!!)
    LOOP AT e_object->mt_toolbar INTO ls_button.
      CASE ls_button-function.
        WHEN cl_gui_alv_grid=>mc_fc_loc_append_row.
          ls_button-function = 'APPEND_ROW'.
        WHEN cl_gui_alv_grid=>mc_fc_loc_insert_row.
          ls_button-function = 'INSERT_ROW'.
        WHEN cl_gui_alv_grid=>mc_fc_loc_copy.  "$MODIFIED
          ls_button-function = 'COPY'.
        WHEN OTHERS.
          CONTINUE.
      ENDCASE.
      MODIFY e_object->mt_toolbar FROM ls_button INDEX syst-tabix.
    ENDLOOP.
  ENDMETHOD.                    "handle_toolbar
  METHOD handle_user_command.
    " Get current row for function 'Insert Row'
    CALL METHOD sender->get_current_cell
      IMPORTING
*        e_row     =
*        e_value   =
*        e_col     =
        es_row_id = ms_row
*        es_col_id =
*        es_row_no =
    " Store redefined function code
    md_function = e_ucomm.
    CASE e_ucomm.
      WHEN 'APPEND_ROW'  OR
           'INSERT_ROW'.
        " Just trigger PAI
        CALL METHOD cl_gui_cfw=>set_new_ok_code
          EXPORTING
            new_code = 'NEW_ROW'
*          IMPORTING
*            rc       =
      WHEN 'COPY'.  "$MODIFIED
        READ TABLE gt_outtab INTO ms_outtab INDEX ms_row-index.
      WHEN OTHERS.
    ENDCASE.
  ENDMETHOD.                    "handle_user_command
  METHOD handle_data_changed.
*   define local data
    DATA: ls_outtab        LIKE LINE OF gt_outtab,
          ls_good          TYPE lvc_s_modi.
    BREAK-POINT.
    LOOP AT er_data_changed->mt_good_cells INTO ls_good
            WHERE ( fieldname = 'ERDAT' ).
**      CALL METHOD er_data_changed->get_cell_value
**        EXPORTING
**          i_row_id    = ls_good-row_id
**          i_fieldname = ls_good-fieldname
**        IMPORTING
**          e_value     = ls_outtab-erdat.
      ls_outtab-erdat = ls_good-value.
      IF ( ls_outtab-erdat < '20070101' ).
        CALL METHOD er_data_changed->add_protocol_entry
          EXPORTING
            i_msgid     = '00'
            i_msgty     = 'E'
            i_msgno     = '398'
            i_msgv1     = 'Date must be >= 01.01.2007'
*          i_msgv2     =
*          i_msgv3     =
*          i_msgv4     =
            i_fieldname = ls_good-fieldname
            i_row_id    = ls_good-row_id
            i_tabix     = ls_good-tabix.
      ENDIF.
    ENDLOOP.
    er_data_changed->display_protocol( ).
    " Not really required (only for validations)
  ENDMETHOD.                    "handle_data_changed
ENDCLASS.                    "lcl_eventhandler IMPLEMENTATION
START-OF-SELECTION.
  SELECT * FROM  knb1 INTO TABLE gt_outtab UP TO 10 ROWS.
  PERFORM init_controls.
* Link the docking container to the target dynpro
  gd_repid = syst-repid.
  CALL METHOD go_docking->link
    EXPORTING
      repid                       = gd_repid
      dynnr                       = '0100'
*      CONTAINER                   =
    EXCEPTIONS
      OTHERS                      = 4.
  IF sy-subrc NE 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
* NOTE: dynpro does not contain any elements
  CALL SCREEN '0100'.
* Flow logic of dynpro (does not contain any dynpro elements):
*PROCESS BEFORE OUTPUT.
*  MODULE STATUS_0100.
*PROCESS AFTER INPUT.
*  MODULE USER_COMMAND_0100.
END-OF-SELECTION.
*&      Module  STATUS_0100  OUTPUT
*       text
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'STATUS_0100'.  " contains push button "DETAIL"
*  SET TITLEBAR 'xxx'.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&      Module  USER_COMMAND_0100  INPUT
*       text
MODULE user_command_0100 INPUT.
  CASE gd_okcode.
    WHEN 'BACK'  OR
         'EXIT'  OR
         'CANC'.
      SET SCREEN 0. LEAVE SCREEN.
    WHEN 'NEW_ROW'.
      PERFORM add_new_row.
    WHEN OTHERS.
  ENDCASE.
  CLEAR: gd_okcode.
ENDMODULE.                 " USER_COMMAND_0100  INPUT
*&      Form  ADD_NEW_ROW
*       text
*  -->  p1        text
*  <--  p2        text
FORM add_new_row .
* define local data
  DATA: ls_outtab   LIKE LINE OF gt_outtab,
        ls_stable   TYPE lvc_s_stbl,
        ld_idx      TYPE i.
  ls_outtab-bukrs = '1000'.
  ls_outtab-ernam = syst-uname.
  CASE lcl_eventhandler=>md_function.
    WHEN 'APPEND_ROW'.
      APPEND ls_outtab TO gt_outtab.
    WHEN 'INSERT_ROW'.
      ld_idx = lcl_eventhandler=>ms_row-index + 1.
      INSERT ls_outtab INTO gt_outtab INDEX ld_idx.
    WHEN OTHERS.
  ENDCASE.
  " Refresh ALV list display
  ls_stable-row = abap_true.
  ls_stable-col = abap_true.
  CALL METHOD go_grid1->refresh_table_display
     EXPORTING
       is_stable      = ls_stable
*      i_soft_refresh =
     EXCEPTIONS
       finished       = 1
       OTHERS         = 2.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " ADD_NEW_ROW
*&      Form  INIT_CONTROLS
*       text
*  -->  p1        text
*  <--  p2        text
FORM init_controls .
* Create docking container
  CREATE OBJECT go_docking
    EXPORTING
      parent = cl_gui_container=>screen0
      ratio  = 90
    EXCEPTIONS
      OTHERS = 6.
  IF sy-subrc NE 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
* Create ALV grids
  CREATE OBJECT go_grid1
    EXPORTING
      i_parent = go_docking  " go_cell_top
    EXCEPTIONS
      OTHERS   = 5.
  IF sy-subrc NE 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  " ENTER trigger event DATA_CHANGED
  CALL METHOD go_grid1->register_edit_event
    EXPORTING
      i_event_id = cl_gui_alv_grid=>mc_evt_enter
    EXCEPTIONS
      error      = 1
      OTHERS     = 2.
  IF sy-subrc <> 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
* Set event handler
  SET HANDLER:
    lcl_eventhandler=>handle_double_click FOR go_grid1,
    lcl_eventhandler=>handle_toolbar      FOR go_grid1,
    lcl_eventhandler=>handle_user_command FOR go_grid1,
    lcl_eventhandler=>handle_data_changed FOR go_grid1.
  PERFORM build_fieldcatalog.
* Display data
  gs_layout-grid_title = 'Customers'.
  gs_layout-smalltitle = abap_true.
  CALL METHOD go_grid1->set_table_for_first_display
    EXPORTING
**      i_structure_name = 'KNB1'
      is_layout        = gs_layout
      ir_salv_adapter  = gif_adapter
    CHANGING
      it_outtab        = gt_outtab
      it_fieldcatalog  = gt_fcat
    EXCEPTIONS
      OTHERS           = 4.
  IF sy-subrc NE 0.
*   MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*              WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " INIT_CONTROLS
*&      Form  BUILD_FIELDCATALOG
*       text
*  -->  p1        text
*  <--  p2        text
FORM build_fieldcatalog .
* define local data
  DATA: ls_fcat   TYPE lvc_s_fcat.
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
      i_structure_name       = 'KNB1'
    CHANGING
      ct_fieldcat            = gt_fcat
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.
  ls_fcat-edit = abap_true.
  MODIFY gt_fcat FROM ls_fcat
    TRANSPORTING edit
    WHERE ( key NE abap_true ).
ENDFORM.                    " BUILD_FIELDCATALOG
Regards
  Uwe