ALV OO: how to change layout more than once using custom pushbuttons?

Question

Hello,
I'm developing a report using ALV Class CL_GUI_ALV_GRID.
It's nearly complete. but I need to add some little feature.
I create pushbuttons on GUI Status in order to show/hide totals and to group/ungroup fields according.
I have already created and I added them into PAI of corresponding dynpro, as follows.
GROUP/UNGROUP FIELDS:
DATA: g_editable_alv1        TYPE REF TO cl_gui_alv_grid.
DATA: tb_fieldcat_1          TYPE lvc_t_fcat.
DATA: tb_sort_1              TYPE lvc_t_sort.
FIELD-SYMBOLS: <fs_fieldcat> TYPE lvc_s_fcat.
CALL METHOD g_editable_alv1->set_sort_criteria
  EXPORTING
    it_sort                   = tb_sort_1
  EXCEPTIONS
    no_fieldcatalog_available = 1
    OTHERS                    = 2.
CALL METHOD g_editable_alv1->refresh_table_display
  EXPORTING
    i_soft_refresh = 'X'
  EXCEPTIONS
    finished       = 1
    OTHERS         = 2.
When I wanto to sort and group using fields CID and PSPID_VDATU, table TB_SORT_1 is filled as follows:
SPOS FIELDNAME                      UP DOWN GROUP SUBTOT COMP EXPA SELTEXT
01  |CID                           |X |    |     |X     |    |X   |      
02  |PSPID_VDATU                   |X |    |     |X     |    |X   |      
SHOW/HIDE TOTALS:
I have to show/hide totals for all fields with domain name ARBEIT. In this sample I copy code to be run when I want to show totals:
LOOP AT tb_fieldcat_1 ASSIGNING <fs_fieldcat>
                          WHERE domname = 'ARBEIT'.
  <fs_fieldcat>-do_sum    = 'X'.
ENDLOOP.
CALL METHOD g_editable_alv1->set_frontend_fieldcatalog
  EXPORTING
    it_fieldcatalog = tb_fieldcat_1.
CALL METHOD g_editable_alv1->refresh_table_display
  EXPORTING
    i_soft_refresh = 'X'
  EXCEPTIONS
    finished       = 1
    OTHERS         = 2.
OK, both features (and their opposite ones) works *only once*.
I mean: first time ALV is displayed according standard layout. Then I click on one of my new pusbutton and it works (ALV layouts is changed). If I click again one of my pushbutton, nothng happens.
Edit: I tried also to use CALL METHOD g_editable_alv1->refresh_table_display. (without any parameter), but nothing changed.
What should I modify in order to be able to use my pushbuttons as many times as I want?
Thank you and best regards
Guido

Answer 1

Your approach is ok. I think you are missing MODIFY statement when setting new fieldcatalog. Please follow my code, it works fine.
DATA: r_cust TYPE REF TO cl_gui_custom_container,
      r_alv TYPE REF TO cl_gui_alv_grid.
DATA: it_fcat TYPE lvc_t_fcat WITH HEADER LINE.
DATA: it_sflight TYPE TABLE OF sflight.
DATA: it_sort              TYPE lvc_t_sort WITH HEADER LINE.
"event handler class
CLASS lcl_handler DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS:
          handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid
                         IMPORTING e_object e_interactive,
          handle_user_command FOR EVENT user_command OF cl_gui_alv_grid
                              IMPORTING e_ucomm sender.
ENDCLASS.                    "lcl DEFINITION
CLASS lcl_handler IMPLEMENTATION.
  METHOD handle_toolbar.
    DATA: ls_toolbar TYPE stb_button.
    MOVE:
       0 TO ls_toolbar-butn_type,
       'FC_BTN' TO ls_toolbar-function,
       'Show/hide totals' TO ls_toolbar-text.
    APPEND ls_toolbar TO e_object->mt_toolbar.
  ENDMETHOD .                    "handle_toolbar
  METHOD handle_user_command.
    DATA it_fcat TYPE lvc_t_fcat.
    DATA wa_fcat TYPE lvc_s_fcat.
    IF e_ucomm = 'FC_BTN'.
      sender->get_frontend_fieldcatalog( IMPORTING et_fieldcatalog = it_fcat ).
      LOOP AT it_fcat INTO wa_fcat WHERE fieldname = 'PRICE' .
        IF wa_fcat-do_sum = 'X'.
          wa_fcat-do_sum = space.
        ELSE.
          wa_fcat-do_sum = 'X'.
        ENDIF.
        MODIFY it_fcat FROM wa_fcat.
      ENDLOOP.
      sender->set_frontend_fieldcatalog( it_fcat ).
      CALL METHOD sender->refresh_table_display
        EXPORTING
          i_soft_refresh = 'X'.
    ENDIF.
  ENDMETHOD.                    "handle_user_command
ENDCLASS.                    "lcl IMPLEMENTATION
INITIALIZATION.
  SELECT * FROM sflight INTO TABLE it_sflight UP TO 20 ROWS.
START-OF-SELECTION.
  CALL SCREEN 100.
MODULE pbo OUTPUT.
  IF r_cust IS NOT BOUND.
    CREATE OBJECT r_cust
      EXPORTING
        container_name              = 'CUSTOM_CONTAINER'      .
    CREATE OBJECT r_alv
      EXPORTING
        i_parent          = r_cust.
    it_sort-fieldname = 'CONNID'.
    it_sort-up = 'X'.
    APPEND it_sort.
    CALL METHOD r_alv->set_table_for_first_display
      EXPORTING
        i_structure_name = 'SFLIGHT'
      CHANGING
        it_outtab        = it_sflight.
    SET HANDLER: lcl_handler=>handle_user_command FOR r_alv,
                 lcl_handler=>handle_toolbar FOR r_alv.
    CALL METHOD r_alv->set_toolbar_interactive.
  ENDIF.
ENDMODULE.                    "pbo OUTPUT
Regards
Marcin