Apple script to search and replace in notes

Question

I'd much appreciate such script or any suggestions as how to achieve that. I have hundreds of notes and decided to change my tagging system.
Thanks a loT!

Answer 1

Well, color me confused.  But if you're just concerned about Mail notes, here's a script that uses the example you gave above.
if application "Mail" is running then
  -- mail should not be running when you use this script
          display alert "Whoops!" message "Please quit Mail.app before running this script" as critical
          return
end if
tell application "Finder"
  -- locate the correct mail folder for the given account
          try
                    set accountFolder to folder "[email protected]" of folder "V2" of folder "Mail" of folder "Library" of home
          on error
  -- folders changed from snow leopard to lion, check the folder hierarchy visually
                    display alert "Whoops!" message "something's wrong with the folder hierarchy." as critical
                    open folder "Mail" of folder "Library" of home
                    return
          end try
          tell accountFolder
                    with timeout of 600 seconds
  -- gather notes file references. set a long timeout because this can take a while if there are a large number of notes
                              set theNotes to (every file of (entire contents of folder "Notes.mbox") whose name extension is "emlx") as alias list
                    end timeout
          end tell
end tell
-- set up keywords to be swapped out here.
set swapPairs to {{"#essay", "kbEssay"}, {"#another key", "its replacement"}}
repeat with thisNote in theNotes
  -- open and read the emlx file into a variable
          set fp to open for access thisNote with write permission
          set noteHTMLText to read fp
  -- loop through the swap pairs making replacements
          repeat with thisPair in swapPairs
                    set noteParts to tid(noteHTMLText, first item of thisPair)
                    set noteHTMLText to tid(noteParts, second item of thisPair)
          end repeat
  -- zero out the file and replace with the revised text
          set eof fp to 0
          write noteHTMLText to fp
          close access fp
end repeat
on tid(input, delim)
  -- generic text items handler
          set {oldTID, my text item delimiters} to {my text item delimiters, delim}
          if class of input is list then
                    set output to input as text
          else
                    set output to text items of input
          end if
          set my text item delimiters to oldTID
          return output
end tid
I've tested this on my laptop and it works, but I STRONGLY suggest that you back up your mail folder before trying it yourself, and (if possible) that you set up a few notes in a little used or dummy account and test it before you run it on your actual notes. 
I also make no guarantees about what will happen if these notes are synched to other devices.  It probably won't explode your computer, but...