Applescript Mail.app to add attachment to a reply

Question

I am writing some scripts to automate my e-mail workflow, and part of it relies on replying to a message with some revised files attached.
Problem is, Mail.app doesn't seem to allow Applescript to include attachments to replies, only to new outgoing messages.
So, this works:
set mailAttach to alias "somefile"
tell application "Mail"
          set listSelectedMail to selection
          set selectedMail to last item of listSelectedMail
          set replyMail to make new outgoing message
  activate
          tell replyMail
                    set visible to true
  make new attachment with properties {file name:mailAttach} at after the last paragraph
          end tell
end tell
...while this doesn't:
set mailAttach to alias "somefile"
tell application "Mail"
          set listSelectedMail to selection
          set selectedMail to last item of listSelectedMail
          set replyMail to reply selectedMail with reply to all
  activate
          tell replyMail
                    set visible to true
  make new attachment with properties {file name:mailAttach} at after the last paragraph
          end tell
end tell
Is it really the case that Applescript can't add attachments to replies, or am I overlooking something?
Of course I could just make a new message adding "Re:" to the subject, but I want to keep the quoted contents of the message I am replying to.
Does anyone have any suggestion?
Cheers,
Jeff

Answer 1

Hi Jeff,
The following script seems to work pretty well (at least with the default preferences of Mail):
set mailAttach to POSIX file "some POSIX path" as alias
tell application "Mail"
    set listSelectedMail to selection
    set selectedMail to last item of listSelectedMail
    set replyMail to reply selectedMail with opening window and reply to all
    tell replyMail
        set theTO to {name, address} of to recipients
        set theCC to {name, address} of cc recipients
        set theBCC to {name, address} of bcc recipients
        set theSubject to subject
    end tell
    activate
    tell application "System Events" to keystroke "acw" using command down
    set theMessage to make new outgoing message
    tell theMessage
        make new attachment with properties {file name:mailAttach} at the end
        set {theNames, theAddresses} to {item 1, item 2} of theTO
        repeat with k from 1 to (count theAddresses)
            set {theName, theAddress} to {item k of theNames, item k of theAddresses}
            if theName is missing value then set theName to ""
            make new to recipient with properties {name:theName, address:theAddress}
        end repeat
        set {theNames, theAddresses} to {item 1, item 2} of theCC
        repeat with k from 1 to (count theAddresses)
            set {theName, theAddress} to {item k of theNames, item k of theAddresses}
            if theName is missing value then set theName to ""
            make new cc recipient with properties {name:theName, address:theAddress}
        end repeat
        set {theNames, theAddresses} to {item 1, item 2} of theBCC
        repeat with k from 1 to (count theAddresses)
            set {theName, theAddress} to {item k of theNames, item k of theAddresses}
            if theName is missing value then set theName to ""
            make new bcc recipient with properties {name:theName, address:theAddress}
        end repeat
        set the subject to theSubject
        set visible to true
    end tell
    delay 1 -- adjust if necessary
    tell application "System Events"
        key code 124 using {command down} -- ⌘→
        keystroke return
        keystroke "v" using command down -- ⌘V
        key code 126 using {command down} -- ⌘↑
    end tell
end tell