Applescript Open PDF save as JPG

Question

I can do a batch process in Photoshop pretty easily, but I need it be a little more robust.
I want to grab a folder full of PDFs then open each PDF in Photoshop. Then check to the width and height of the document. If the file is wider than it is tall it runs one Photoshop action. If it is taller than it is wide, it runs another action.
Thoughts on how to accomplish this?
-Kirk

Answer 1

Kirk, have a very brief look at fit image. I must say I've never used this feature before and Im a long time user of PS. I've coded what I think it does you will have to test and see for yourself. I have also moved a few things about as they did not need to be part of the repeat loop in PS. Also included convert to RGB color space as files are to be for web. Can you also check PS's pref's file handling set append file extension to always and lower case if it is not already.
property fitImage : 1280 / 854 -- Your fit image scale.
set tempFolderName to "Converted to RGB JPEG"
set inputFolder to choose folder
tell application "Finder"
set filesList to (files of inputFolder whose file type is "PDF " or name extension is "pdf")
if (not (exists folder ((inputFolder as string) & tempFolderName))) then
set outputFolder to make new folder at inputFolder with properties {name:tempFolderName}
else
set outputFolder to folder ((inputFolder as string) & tempFolderName)
end if
end tell
tell application "Adobe Photoshop CS" -- Moved out of repeat loop only need to do this once.
set UserPrefs to properties of settings -- Record user settings
set ruler units of settings to pixel units -- Easier to use for web stuff
set background color to {class:RGB color, red:255, green:255, blue:255}
end tell
repeat with aFile in filesList
set fileIndex to 0
tell application "Finder"
set theFile to aFile as alias
set theFileName to name of theFile
end tell
tell application "Adobe Photoshop CS"
activate
set display dialogs to never
open theFile as PDF with options {class:PDF open options, mode:CMYK, resolution:300, use antialias:true, constrain proportions:true}
set docRef to the current document
tell docRef
if (mode of docRef is not RGB) then
change mode docRef to RGB
end if
set docHeight to height of docRef
set docWidth to width of docRef
flatten
if (docHeight > docWidth) then -- This is what I think fit image does.
set imagePro to (docHeight / docWidth)
if imagePro < fitImage then
resize image width 854 resolution 72
else
resize image height 1280 resolution 72
end if
end if
if (docWidth > docHeight) then
set imagePro to (docWidth / docHeight)
if imagePro < fitImage then
resize image height 854 resolution 72
else
resize image width 1280 resolution 72
end if
end if
set docName to name of docRef
set docBaseName to getBaseName(docName) of me
set newFileName to (outputFolder as string) & docBaseName
end tell
save docRef in file newFileName as JPEG with options ¬
{class:JPEG save options, embed color profile:true, format options:optimized, matte:background color matte, quality:9} ¬
appending lowercase extension with copying
close current document without saving
end tell
end repeat
tell application "Adobe Photoshop CS" -- Reset changed user settings after repeat loop.
set ruler units of settings to ruler units of UserPrefs
end tell
on getBaseName(fName)
set baseName to fName
repeat with idx from 1 to (length of fName)
if (item idx of fName = ".") then
set baseName to (items 1 thru (idx - 1) of fName) as string
exit repeat
end if
end repeat
return baseName
end getBaseName
--