Applescript problems with character offsets and embedded objects in Pages

Question

https://discussions.apple.com/thread/2550810?start=0&tstart=0
The above discussion is archived, but I've noticed a problem witht he solution it proposes.
Essentially, the problem seems to be that the character offset of a selection becomes either inaccessible or out of sync when embedded objects are present in the file.
The following document can be used to demonstrate:
http://images.apple.com/support/pages/docs/ePub_Best_Practices_EN.zip
I've slightly modified the script fromt he previous thread, so here's my own script:
tell front document of application "Pages"
          set C to character offset of (get selection)
          set N to 0
          repeat with P in (get character offset of paragraphs)
                    if P > C then exit repeat
                    set N to N + 1
  select paragraph (N + 1)
          end repeat
          N
end tell
This script is supposed to select the next paragraph in a document, when given a selection. The intention is to call it recursively to get each paragraph of the document in turn.
At the start of the document, it functions correctly, however when it gets to the embedded pictures, lines and table of contents, things start to break. This wouldn't be so bad, because I could simply ignore paragraphs that contains those embedded objects, but the real problems arise in the normal text below these objects.
If you place the cursor on the 3rd page of that document, in an ordinary paragraph, for example, this script will simply return the same paragraph over and over. The reason for this is that the character offset of the paragraphs is being thrown off, so the if statement gets hit too early. You can also see this if you look at the character offsets of the word "Introduction" in the heading at the top of the 3rd page. You'll notice that the character offset is duplicated for a couple of letters, and is out of sync with the index of the character itself.
What I need is a script that will take a selection (of any type), and simply return the correct index of the paragraph containing it every time. It doesn't seem like a difficult thing to do, and since the paragraphs are accessible by index, they should be able to return their index to the user. I have a feeling Apple need to add this functionality to the Pages Applescript dictionary, and they definitely need to fix the bug where the character offsets go out of sync after embedded objects. These are really quite bad problems.

Answer 1

Hi,
Pierre L. wrote:
I have tested it with the document referred to by andyboyd. When the first word (“Introduction”) of the first paragraph of page 3 is selected, your script returns {10}, while it returns {12} when the second word (“to”) of the same paragraph is selected.
Message was edited by: Pierre L.
Thanks Pierre.
Ok, the error is that I mixed the variable N and N1, during the renaming of variables
return N - 1  must be return N1 - 1 -- return the index
Here the corrected script :
set indexList to my getIndexOfLinesInSelection()
on getIndexOfLinesInSelection()
   script o
      property parOffsetList : {}
      on getIndex(C)
         tell application "Pages" to tell front document
            set parOffsetList to character offset of paragraphs
            set tc to count parOffsetList
            repeat with N from 1 to tc
               if N = tc then return tc -- it's the last paragraph
               if (item N of parOffsetList) > C then
                  set N1 to N
                  repeat -- check the  character offset of the selected line
                     if N1 = tc then return tc -- it's the last paragraph
                     select paragraph N1 -- select next paragraph
                     set sel to (get selection)
                     if class of sel is list then
                        repeat with aItem in sel --  this line contains text and object
                           try
                              if character offset of first character of aItem > C then return N1 - 1 -- return the index
                              exit repeat -- else  character offset of the selection <= C , exit the repeat
                           end try -- error,aItem is not valid, continue the repeat
                        end repeat
                     else
                        try
                           if (character offset of first character of sel) > C then return N1 - 1 -- return the index
                        end try
                     end if
                     set N1 to N1 + 1
                  end repeat
               end if
            end repeat
         end tell
      end getIndex
   end script
   tell application "Pages" to tell front document
      set sel to (get selection)
      if class of sel is list then -- selection contains object or  (Non-Continuous selection in the same line or in  différents lines).
         set charOffsetList to {}
         repeat with aItem in sel
            try
               set end of charOffsetList to (character offset of aItem) -- get character offset of  the  valid item
            end try
         end repeat
      else -- insertion point or  the first line in continous text selection
         set charOffsetList to {character offset of sel}
      end if
      if charOffsetList is {} then return {} --  no valid item in the selection
      set indexList to {}
      repeat with C in charOffsetList
         set r to o's getIndex(C)
         if r is not in indexList then set end of indexList to r
      end repeat
      return indexList
   end tell
end getIndexOfLinesInSelection