AppleScript watched folder

Question

I need of a "watched folder" that will email a URL of any new files for me automatically. I have a folder on a Snow Leopard server that is in the Web Server’s Document’s folder. People drop QuickTime Movie files in this folder and then I send out an email with the URL to the file. Do you know of a way to automate this process for each new file dropped into the folder? The email would have this link: http://3.156.4.93/len/filename. The people would recieve the email and click on the link and the QuickTime movie opens up in their web browser.

Answer 1

This sounds like a simple Folder Action script. Indeed, Apple provide several samples that trigger on a file being added to a folder - check /Library/Scripts/Folder Action Scripts for starters.
One trickier element is that most AppleScript examples of sending emails usually hinge around Mail.app, but if this is running on a server then Mail.app might not be running, so you may have to look at alternative options, such as generating mail via a command line:
on adding folder items to my_folder after receiving the_files
          repeat with each_file in the_files
  -- work out the file name
                    set filename to name of (info for each_file)
  -- build the URL
                    set fileURL to "http://3.156.4.93/len/" & filename
  -- here's your message text
                    set msg to "A new movie has been uploaded, click " & fileURL & " to view it."
  -- save that to a temp file
                    do shell script "/bin/echo '" & msg & "' > /var/tmp/msgTxt"
  -- setup the recipient
                    set rcpt to "[email protected]"
  -- send it via the command line
                    do shell script "/usr/bin/mail -s 'New Movie' " & rcpt & " < /var/tmp/msgTxt"
          end repeat
end adding folder items to
Save this as a folder action script, then you can assign it to your upload directory via the Finder on the server.
The alternative, non-AppleScript option, is to use Launchd with a WatchPath defined. This will trigger a shell script whenever a directory changes. Without a GUI running on the server, though, you're still restricted to command-line driven mail.