Batch convert of old eps files

Question

Hi,
at first sorry for my english. It is not very well, but I try.
We have many eps file, which are created with older illustrator versions.
At this time we change to cs3.
How can I batch convert all the old eps files to the new "standard".
eps options are shown in the attachment.
Thanks.

Answer 1

This is my (hopefully) corrected CS4 version:
-- Call the Process
try
     tell application "System Events" to set processName to (first item of (every process whose name contains "Illustrator"))
     processName
on error
     display alert "Warning" as warning message "Adobe Illustrator is not open. Please open."
     return
end try
-- Search for eps files
set allFiles to paragraphs in (do shell script "find " & quoted form of POSIX path of (choose folder) & " -iname \"*.eps\"")
-- Files found?
if ((count of allFiles) is 0) then
     display alert "Warning" as warning message "No .eps files found."
     return
end if
-- Process files
repeat with nFile in allFiles
     my runConvertEPS(nFile)
end repeat
-- Sub-Functions
-- Convert
on runConvertEPS(nFile)
     tell application "Adobe Illustrator"
          try
               activate
               set theCurrentFileLocation to (nFile as POSIX file)
               -- Open File
               open file theCurrentFileLocation with options {update legacy text:true ¬
                    , update legacy gradient mesh:true} without dialogs
               -- Select the file
               set theCurrentFile to the current document
               -- Save and overwrite
               save theCurrentFile in file theCurrentFileLocation with options {class:EPS save options ¬
                    , artboard range:default ¬
                    , CMYK PostScript:true ¬
                    , compatibility:default ¬
                    , compressed:true ¬
                    , embed ICC profile:false ¬
                    , embed linked files:true ¬
                    , font subset threshold:default ¬
                    , PDF compatible:true ¬
                    , save multiple artboards:true ¬
                    , overprint:preserve}
               -- Close
               close theCurrentFile
          on error
               -- Close all windows
               try
                    close every document without saving
               end try
               -- Write the error to log
               tell me to my logErrorByFile(nFile)
          end try
     end tell
end runConvertEPS
-- Save Format
on logErrorByFile(nFile)
     try
          set writeContents to ((current date) as string) & ": " & nFile & return
          set pathToFile to (path to desktop folder as string) & "EPS Log.txt"
          set the pathToFile to the pathToFile as text
          set the openFile to open for access file pathToFile with write permission
          write writeContents to the openFile starting at eof
          close access the openFile
     on error errorReport number errorNo
          try
               close access file pathToFile
          end try
     end try
end logErrorByFile