Can somebody please guide me?

Question

The driver program will have a selection screen with three radiobuttons and seven checkboxes. Based on the user selection, the report should display details.Let's say the user selected first radiobutton and one or more  checkboxes, and when exucute it..it should display corresponding ALV report(s). The report ouput should also have different expand/collapse icons ( in this case 7 expand/collapse icons) to display different reports for the selected radiobutton. That means if the user chooses to view details for seventh checkbox report, he can click on the expand button.( Just like ME23N screen, where you can view Item details).I don't know how to develop this program. Can you suggest me some ideas? or please send me any sample programs if any of you have which I can refer to. Any kind of help is really appreciated and rewarded.
Thanks,
Chandu

Answer 1

Ok, check out this program.  You will have to create screen 100.  Create two custom containers on that screen.  Also create two pushbuttons on that screen.  One PB for the first control, the second PB for the second control.  Make the function codes for the pushbuttons "T1" and "T2".   Make the names of the containers  "ALV_CONTAINER" and "ALV_CONTAINER2".  This program should give you some ideas.
report zrich_0002 .
tables: mara.
type-pools: slis, icon.
* Internal Tables
data: begin of ialv occurs 0,
      matnr type mara-matnr,
      maktx type makt-maktx,
      end of ialv .
data: begin of ialv2 occurs 0,
      matnr type mara-matnr,
      werks type marc-werks,
      end of ialv2 .
data: alv_container type ref to cl_gui_custom_container,
      alv_grid type ref to cl_gui_alv_grid,
      ok_code like sy-ucomm,
      fieldcat type lvc_t_fcat.
data: alv_container2 type ref to cl_gui_custom_container,
      alv_grid2 type ref to cl_gui_alv_grid,
      fieldcat2 type lvc_t_fcat.
data: alv1_flag type c,
      alv2_flag type c.
select-options: s_matnr for mara-matnr.
parameters: p_rad1 radiobutton group grp1,
           p_rad2 radiobutton group grp1,
           p_rad3 radiobutton group grp1,
           p_chk1 as checkbox,
           p_chk2 as checkbox.
start-of-selection.
  perform get_data.
  alv1_flag = p_chk1.
  alv2_flag = p_chk2.
  call screen 100.
*      Module  status_0100  OUTPUT
module status_0100 output.
  set pf-status '0100'.
  set titlebar '0100'.
  if alv_container is initial.
* Create Controls
    create object alv_container
           exporting container_name = 'ALV_CONTAINER'.
    create object alv_grid
           exporting  i_parent =  alv_container.
*  Populate Field Catalog
    perform get_fieldcatalog.
    call method alv_grid->set_table_for_first_display
        changing
             it_outtab       = ialv[]
             it_fieldcatalog = fieldcat[].
      if alv1_flag = 'X'.
        call method alv_container->set_visible( '1' ).
      else.
        call method alv_container->set_visible( '0' ).
      endif.
  endif.
  if  alv_container2 is initial.
* Create Controls
    create object alv_container2
           exporting container_name = 'ALV_CONTAINER2'.
    create object alv_grid2
           exporting  i_parent =  alv_container2.
*  Populate Field Catalog
    perform get_fieldcatalog2.
    call method alv_grid2->set_table_for_first_display
        changing
             it_outtab       = ialv2[]
             it_fieldcatalog = fieldcat2[].
      if alv2_flag = 'X'.
        call method alv_container2->set_visible( '1' ).
      else.
        call method alv_container2->set_visible( '0' ).
      endif.
  endif.
endmodule.
*      Module  USER_COMMAND_0100  INPUT
module user_command_0100 input.
  case ok_code.
    when 'BACK' or 'CANCEL'.
      clear ok_code.
      perform free_containers.
      if sy-subrc = 0.
        set screen 0.
        leave screen.
      else.
        leave program.
      endif.
    when 'EXIT'.
      clear ok_code.
      perform free_containers.
      leave program.
    when 'T1'.         " Toggle expand/collapse
      clear ok_code.
      if alv1_flag = 'X'.
        alv1_flag = space.
      else.
        alv1_flag = 'X'.
      endif.
     if alv1_flag = 'X'.
        call method alv_container->set_visible( '1' ).
      else.
        call method alv_container->set_visible( '0' ).
      endif.
    when 'T2'.         " Toggle expand/collapse
      clear ok_code.
      if alv2_flag = 'X'.
        alv2_flag = space.
      else.
        alv2_flag = 'X'.
      endif.
     if alv2_flag = 'X'.
        call method alv_container2->set_visible( '1' ).
      else.
        call method alv_container2->set_visible( '0' ).
      endif.
  endcase.
endmodule.
*       FORM GET_DATA.
form get_data.
  select mara~matnr makt~maktx
             into corresponding fields of table ialv
                 from mara
                      inner join makt
                         on mara~matnr = makt~matnr
                                where mara~matnr in s_matnr
                                  and makt~spras = sy-langu.
  sort ialv ascending by matnr.
  select mara~matnr marc~werks
             into corresponding fields of table ialv2
                 from mara
                      inner join marc
                         on mara~matnr = marc~matnr
                                where mara~matnr in s_matnr.
  sort ialv2 ascending by matnr werks.
endform.
*      Form  FREE_CONTAINERS
form free_containers.
  if not alv_container is initial.
    call method alv_container->free.
    clear: alv_container.
    free : alv_container.
  endif.
  if not alv_container2 is initial.
    call method alv_container2->free.
    clear: alv_container2.
    free : alv_container2.
  endif.
endform.
*      Form  Get_Fieldcatalog - Set Up Columns/Headers
form get_fieldcatalog.
  data: ls_fcat type lvc_s_fcat.
  data: columnno(3) type n value '0'.
  refresh: fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Number'.
  ls_fcat-coltext    = 'Material Number'.
  ls_fcat-fieldname  = 'MATNR'.
  ls_fcat-ref_table  = 'IALV'.
  ls_fcat-outputlen  = '18'.
  ls_fcat-col_pos    = 1.
  append ls_fcat to fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Description'.
  ls_fcat-coltext    = 'Material Description'.
  ls_fcat-fieldname  = 'MATKX'.
  ls_fcat-ref_table  = 'IALV'.
  ls_fcat-outputlen  = '40'.
  ls_fcat-col_pos    = 2.
  append ls_fcat to fieldcat.
endform.
*      Form  Get_Fieldcatalog2 - Set Up Columns/Headers
form get_fieldcatalog2.
  data: ls_fcat type lvc_s_fcat.
  data: columnno(3) type n value '0'.
  refresh: fieldcat2.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Number'.
  ls_fcat-coltext    = 'Material Number'.
  ls_fcat-fieldname  = 'MATNR'.
  ls_fcat-ref_table  = 'IALV2'.
  ls_fcat-outputlen  = '18'.
  ls_fcat-col_pos    = 1.
  append ls_fcat to fieldcat2.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Plant'.
  ls_fcat-coltext    = 'Plant'.
  ls_fcat-fieldname  = 'WERKS'.
  ls_fcat-ref_table  = 'IALV2'.
  ls_fcat-outputlen  = '4'.
  ls_fcat-col_pos    = 2.
  append ls_fcat to fieldcat2.
endform.
Regards,
Rich Heilman