Composite Element in Tableview Iterator

Question

I want to use a <phtmlb:matrix> element in a tableview iterator to arrange the content of a cell.
I tried to follow Brians Weblog on composite elements.
In my test example, I just want to combine two fields of t000 into one cell. Of course I know, that concatenation would be more easy here, but that would not answer my questions.
Thought it could look like this:
METHOD render_cell_start.
  DATA:
    l_o_matrix             TYPE REF TO cl_phtmlb_matrix,
    l_o_bsp_element        TYPE REF TO cl_bsp_element,
    l_string               TYPE STRING.
  CASE p_tableview_id.
    WHEN 'TABLE_T000'.
    l_o_matrix = cl_phtmlb_matrix=>factory( ).
    WHILE o_page_context->element_process( element = l_o_matrix )
      = cl_bsp_element=>co_element_continue.
Cell 1
      CLEAR: l_o_matrix->mc_backgrounddesign,
             l_o_matrix->mc_design,
             l_o_matrix->mc_separation.
      l_o_matrix->do_set_data( element_name = 'matrixCell' ).
      l_string = me->t000-mandt.
      l_o_bsp_element = cl_htmlb_textview=>factory( text = l_string ).
      WHILE o_page_context->element_process( element = l_o_bsp_element )
       = cl_bsp_element=>co_element_continue.
      ENDWHILE.
Cell 2
      CLEAR: l_o_matrix->mc_backgrounddesign,
             l_o_matrix->mc_design,
             l_o_matrix->mc_separation.
      l_o_matrix->mc_halign = 'LEFT'.
      l_o_matrix->mc_valign = 'TOP'.
      l_o_matrix->do_set_data( element_name = 'matrixCell' ).
      l_string = me->t000-mtext.
      l_o_bsp_element = cl_htmlb_textview=>factory( text = l_string ).
      WHILE o_page_context->element_process( element = l_o_bsp_element )
       = cl_bsp_element=>co_element_continue.
      ENDWHILE.
    ENDWHILE.
    p_replacement_bee = l_o_matrix.
  ENDCASE.
ENDMETHOD.
However, that does not work.
First, the list of T000-MANDT fields is rendered twice:
into the tableview and into a list before the tableview.
Second:  T000-MTEXT does not show up at all.
What do I do wrong?
I feel that I do not completely understand how the rendering is processed.
Thanks for our help.
Juergen

Answer 1

The following is the example from Brian's weblog, updated for design2003.  It doesn't use the Matrix however.  Perhaps it will help.
It still doesn't render quite like it did under design2002.  I'm not sure if there is a good way to combine multiple input fields into one cell any longer.  I know others have had a problem with this as well.  I will have to look closer at your matrix attempt.
when 'SEATS'.
      if p_edit_mode is initial.
        data: max type string, occ type string,
              value type string.
        max = m_row_ref->seatsmax + m_row_ref->seatsmax_b
            + m_row_ref->seatsmax_f.
        occ = m_row_ref->seatsocc + m_row_ref->seatsocc_b
            + m_row_ref->seatsocc_f.
        condense: max, occ.
        concatenate occ ` / ` max into value.
        p_replacement_bee = cl_htmlb_textview=>factory(
            text = value ).
      else.
        data: icon_plane2 type string.
        icon_plane2 = cl_bsp_mimes=>sap_icon(
             id = 'ICON_WS_PLANE' ).
        data: image type ref to cl_htmlb_image.
        image = cl_htmlb_image=>factory(
             id = p_cell_id
             src = icon_plane2 ).
        data: if_first type ref to cl_htmlb_inputfield.
        if_first = cl_htmlb_inputfield=>factory( id = p_cell_id
            id_postfix = '_first'
            type = 'INTEGER' size = '4' ).
        if_first->value = m_row_ref->seatsocc_f.
        data: if_bus   type ref to cl_htmlb_inputfield.
        if_bus   = cl_htmlb_inputfield=>factory( id = p_cell_id
            id_postfix = '_bus'
            type = 'INTEGER' size = '4' ).
        if_bus->value = m_row_ref->seatsocc_b.
        data: if_econ  type ref to cl_htmlb_inputfield.
        if_econ = cl_htmlb_inputfield=>factory( id = p_cell_id
            id_postfix = '_econ'
            type = 'INTEGER' size = '4'  ).
        if_econ->value = m_row_ref->seatsocc.
        data: tag_gl       type ref to cl_htmlb_gridlayout,
              tag_glc_if1  type ref to cl_htmlb_gridlayoutcell,
              tag_glc_if2  type ref to cl_htmlb_gridlayoutcell,
              tag_glc_if3  type ref to cl_htmlb_gridlayoutcell.
        tag_gl       = cl_htmlb_gridlayout=>factory(
                    columnsize  = '3' rowsize  = '1' ).
        tag_glc_if1 = cl_htmlb_gridlayoutcell=>factory(
                    columnindex = '1' rowindex = '1' ).
        tag_glc_if2  = cl_htmlb_gridlayoutcell=>factory(
                    columnindex = '2' rowindex = '1' ).
        tag_glc_if3  = cl_htmlb_gridlayoutcell=>factory(
                    columnindex = '3' rowindex = '1' ).
        data: seats_bee type ref to cl_bsp_bee_table.
        create object seats_bee.
        seats_bee->add( level = 1 element = tag_gl ).
        seats_bee->add( level = 2 element = tag_glc_if1 ).
        seats_bee->add( level = 3 element = if_first ).
        seats_bee->add( level = 2 element = tag_glc_if2 ).
        seats_bee->add( level = 3 element = if_bus ).
        seats_bee->add( level = 2 element = tag_glc_if3 ).
        seats_bee->add( level = 3 element = if_econ ).
        p_replacement_bee = seats_bee.
      endif.
Message was edited by: Thomas Jung