Convert from feet to inches?

Question

Can numbers convert imported data from feet notation (i.e. 3' 6 1/2") to decimal inches (i.e. 42.5)? I'd like to be able to import rough opening dimensions from my internal CAD (Vectorworks 2008) spreadsheet to generate cut lists with numbers. I can manually type in the info, but that is prone to errors. I'm also looking into whether Vectorworks can export the data I want in the proper format.
Thanks for any help
- Tobias

Answer 1

Hello
Assuming that the values are entered in a column,
select a group of the cells containing them
copy to the clipboard
call the passed script
paste the result where you want.
If I forget nothing, it take cares of all combinations:
3’ 6 1/2
3’ 6
3’ 3/4
6 3/4
3'
6
1/2
3' 6 1/2
even blank rows are correctly treated.
Of course, if the source of the datas give you the same kind of list, you may call the script directly.
It only requires that Numbers is the frontmost application.
save the script as an Application or an Application Bundle.
store it in the folder <yourStartupDisk>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Doing so you will be able to run the script from the System's scripts menu.
Select the block of feets values
Copy to clipboard
Call the script
Paste the block of converted values where you want.
Yvan KOENIG
25 février 2008
--(SCRIPT feets2inches.app]
property passed : {}
set passed to the clipboard
if passed contains return then
set my passed to my decoupe(passed, return)
else
set my passed to {passed}
end if
set tt to ""
repeat with vv in my passed
set vv to vv as text
if vv is "" then
set tt to tt & return
else
set l to my decoupe(vv, " ")
if (count of l) = 1 then (* 3' or 6 or 1/2 *)
set l1 to item 1 of l
if character -1 of l1 is in {"'", "’"} then
set nn to ((text 1 thru -2 of l1) as integer) * 12
else if l1 does not contain "/" then
set nn to l1 as integer
else
set {c, d} to my decoupe(l1, "/")
set nn to c / d
end if
else if (count of l) = 2 then (* 3' 6 or 3' 1/2 or 6 1/2 *)
set {l1, l2} to l
if (character -1 of l1) is in {"'", "’"} then
if l2 does not contain "/" then
set nn to (((text 1 thru -2 of l1) as integer) * 12) + (l2 as integer)
else
set {c, d} to my decoupe(l2, "/")
set nn to (((text 1 thru -2 of l1) as integer) * 12) + (c / d)
end if
else
set {c, d} to my decoupe(l2, "/")
set nn to (l1 as integer) + (c / d)
end if
else (* 3' 6 1/2 *)
set {c, d} to my decoupe(item 3 of l, "/")
set nn to (((text 1 thru -2 of item 1 of l) as integer) * 12) + (item 2 of l as integer) + (c / d)
end if
set tt to tt & nn & return
end if
end repeat
set the clipboard to tt
set passed to {}
on decoupe(t, d)
local l
set AppleScript's text item delimiters to d
set l to text items of t
set AppleScript's text item delimiters to ""
return l
end decoupe
--[/SCRIPT]
If it works as you wish, I will put it in my idisk.
Yvan KOENIG (from FRANCE lundi 25 février 2008 15:57:4)